[net-next-2.6.git] / arch / mips / kernel / mcount.S

/*
 * MIPS specific _mcount support
 *
 * This file is subject to the terms and conditions of the GNU General Public
 * License.  See the file "COPYING" in the main directory of this archive for
 * more details.
 *
 * Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
 * Copyright (C) 2010 DSLab, Lanzhou University, China
 * Author: Wu Zhangjin <wuzhangjin@gmail.com>
 */

#include <asm/regdef.h>
#include <asm/stackframe.h>
#include <asm/ftrace.h>

	.text
	.set noreorder
	.set noat

	.macro MCOUNT_SAVE_REGS
	PTR_SUBU	sp, PT_SIZE
	PTR_S	ra, PT_R31(sp)
	PTR_S	AT, PT_R1(sp)
	PTR_S	a0, PT_R4(sp)
	PTR_S	a1, PT_R5(sp)
	PTR_S	a2, PT_R6(sp)
	PTR_S	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_S	a4, PT_R8(sp)
	PTR_S	a5, PT_R9(sp)
	PTR_S	a6, PT_R10(sp)
	PTR_S	a7, PT_R11(sp)
#endif
	.endm

	.macro MCOUNT_RESTORE_REGS
	PTR_L	ra, PT_R31(sp)
	PTR_L	AT, PT_R1(sp)
	PTR_L	a0, PT_R4(sp)
	PTR_L	a1, PT_R5(sp)
	PTR_L	a2, PT_R6(sp)
	PTR_L	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_L	a4, PT_R8(sp)
	PTR_L	a5, PT_R9(sp)
	PTR_L	a6, PT_R10(sp)
	PTR_L	a7, PT_R11(sp)
	PTR_ADDIU	sp, PT_SIZE
#else
	PTR_ADDIU	sp, (PT_SIZE + 8)
#endif
.endm

	.macro RETURN_BACK
	jr ra
	 move ra, AT
	.endm

/*
 * The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
 * the location of the parent's return address.
 */
#define MCOUNT_RA_ADDRESS_REG	$12

#ifdef CONFIG_DYNAMIC_FTRACE

NESTED(ftrace_caller, PT_SIZE, ra)
	.globl _mcount
_mcount:
	b	ftrace_stub
	 nop
	lw	t1, function_trace_stop
	bnez	t1, ftrace_stub
	 nop

	MCOUNT_SAVE_REGS
#ifdef KBUILD_MCOUNT_RA_ADDRESS
	PTR_S	MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
#endif

	move	a0, ra		/* arg1: self return address */
	.globl ftrace_call
ftrace_call:
	nop	/* a placeholder for the call to a real tracing function */
	 move	a1, AT		/* arg2: parent's return address */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	.globl ftrace_graph_call
ftrace_graph_call:
	nop
	 nop
#endif

	MCOUNT_RESTORE_REGS
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(ftrace_caller)

#else	/* ! CONFIG_DYNAMIC_FTRACE */

NESTED(_mcount, PT_SIZE, ra)
	lw	t1, function_trace_stop
	bnez	t1, ftrace_stub
	 nop
	PTR_LA	t1, ftrace_stub
	PTR_L	t2, ftrace_trace_function /* Prepare t2 for (1) */
	bne	t1, t2, static_trace
	 nop

#ifdef	CONFIG_FUNCTION_GRAPH_TRACER
	PTR_L	t3, ftrace_graph_return
	bne	t1, t3, ftrace_graph_caller
	 nop
	PTR_LA	t1, ftrace_graph_entry_stub
	PTR_L	t3, ftrace_graph_entry
	bne	t1, t3, ftrace_graph_caller
	 nop
#endif
	b	ftrace_stub
	 nop

static_trace:
	MCOUNT_SAVE_REGS

	move	a0, ra		/* arg1: self return address */
	jalr	t2		/* (1) call *ftrace_trace_function */
	 move	a1, AT		/* arg2: parent's return address */

	MCOUNT_RESTORE_REGS
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(_mcount)

#endif	/* ! CONFIG_DYNAMIC_FTRACE */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER

NESTED(ftrace_graph_caller, PT_SIZE, ra)
#ifndef CONFIG_DYNAMIC_FTRACE
	MCOUNT_SAVE_REGS
#endif

	/* arg1: Get the location of the parent's return address */
#ifdef KBUILD_MCOUNT_RA_ADDRESS
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a0, PT_R12(sp)
#else
	move	a0, MCOUNT_RA_ADDRESS_REG
#endif
	bnez	a0, 1f	/* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
	 nop
#endif
	PTR_LA	a0, PT_R1(sp)	/* leaf func: the location in current stack */
1:

	/* arg2: Get self return address */
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a1, PT_R31(sp)
#else
	move	a1, ra
#endif

	/* arg3: Get frame pointer of current stack */
#ifdef CONFIG_FRAME_POINTER
	 move	a2, fp
#else /* ! CONFIG_FRAME_POINTER */
#ifdef CONFIG_64BIT
	 PTR_LA	a2, PT_SIZE(sp)
#else
	 PTR_LA	a2, (PT_SIZE+8)(sp)
#endif
#endif

	jal	prepare_ftrace_return
	 nop
	MCOUNT_RESTORE_REGS
	RETURN_BACK
	END(ftrace_graph_caller)

	.align	2
	.globl	return_to_handler
return_to_handler:
	PTR_SUBU	sp, PT_SIZE
	PTR_S	v0, PT_R2(sp)

	jal	ftrace_return_to_handler
	 PTR_S	v1, PT_R3(sp)

	/* restore the real parent address: v0 -> ra */
	move	ra, v0

	PTR_L	v0, PT_R2(sp)
	PTR_L	v1, PT_R3(sp)
	jr	ra
	 PTR_ADDIU	sp, PT_SIZE
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */

	.set at
	.set reorder
Commit	Line	Data
d2bb0762 WZ	1	/*
	2	* MIPS specific _mcount support
	3	*
	4	* This file is subject to the terms and conditions of the GNU General Public
	5	* License. See the file "COPYING" in the main directory of this archive for
	6	* more details.
	7	*
	8	* Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
042e571d	9	* Copyright (C) 2010 DSLab, Lanzhou University, China
f7a904df	10	* Author: Wu Zhangjin <wuzhangjin@gmail.com>
d2bb0762 WZ	11	*/
	12
	13	#include <asm/regdef.h>
	14	#include <asm/stackframe.h>
	15	#include <asm/ftrace.h>
	16
	17	.text
	18	.set noreorder
	19	.set noat
	20
	21	.macro MCOUNT_SAVE_REGS
	22	PTR_SUBU sp, PT_SIZE
	23	PTR_S ra, PT_R31(sp)
	24	PTR_S AT, PT_R1(sp)
	25	PTR_S a0, PT_R4(sp)
	26	PTR_S a1, PT_R5(sp)
	27	PTR_S a2, PT_R6(sp)
	28	PTR_S a3, PT_R7(sp)
	29	#ifdef CONFIG_64BIT
	30	PTR_S a4, PT_R8(sp)
	31	PTR_S a5, PT_R9(sp)
	32	PTR_S a6, PT_R10(sp)
	33	PTR_S a7, PT_R11(sp)
	34	#endif
	35	.endm
	36
	37	.macro MCOUNT_RESTORE_REGS
	38	PTR_L ra, PT_R31(sp)
	39	PTR_L AT, PT_R1(sp)
	40	PTR_L a0, PT_R4(sp)
	41	PTR_L a1, PT_R5(sp)
	42	PTR_L a2, PT_R6(sp)
	43	PTR_L a3, PT_R7(sp)
	44	#ifdef CONFIG_64BIT
	45	PTR_L a4, PT_R8(sp)
	46	PTR_L a5, PT_R9(sp)
	47	PTR_L a6, PT_R10(sp)
	48	PTR_L a7, PT_R11(sp)
d2bb0762 WZ	49	PTR_ADDIU sp, PT_SIZE
	50	#else
	51	PTR_ADDIU sp, (PT_SIZE + 8)
	52	#endif
	53	.endm
	54
	55	.macro RETURN_BACK
	56	jr ra
	57	move ra, AT
	58	.endm
	59
56b49cd3 WZ	60	/*
	61	* The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
	62	* the location of the parent's return address.
	63	*/
	64	#define MCOUNT_RA_ADDRESS_REG $12
	65
538f1952 WZ	66	#ifdef CONFIG_DYNAMIC_FTRACE
	67
	68	NESTED(ftrace_caller, PT_SIZE, ra)
	69	.globl _mcount
	70	_mcount:
	71	b ftrace_stub
	72	nop
fc49a3be WZ	73	lw t1, function_trace_stop
fc49a3be WZ	74	bnez t1, ftrace_stub
538f1952 WZ	75	nop
	76
	77	MCOUNT_SAVE_REGS
7326c4e5	78	#ifdef KBUILD_MCOUNT_RA_ADDRESS
56b49cd3	79	PTR_S MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
7326c4e5	80	#endif
538f1952	81
042e571d	82	move a0, ra /* arg1: self return address */
538f1952 WZ	83	.globl ftrace_call
	84	ftrace_call:
	85	nop /* a placeholder for the call to a real tracing function */
042e571d	86	move a1, AT /* arg2: parent's return address */
538f1952	87
e17ff5fe WZ	88	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	89	.globl ftrace_graph_call
	90	ftrace_graph_call:
	91	nop
	92	nop
	93	#endif
	94
538f1952 WZ	95	MCOUNT_RESTORE_REGS
	96	.globl ftrace_stub
	97	ftrace_stub:
	98	RETURN_BACK
	99	END(ftrace_caller)
	100
	101	#else /* ! CONFIG_DYNAMIC_FTRACE */
	102
d2bb0762	103	NESTED(_mcount, PT_SIZE, ra)
fc49a3be WZ	104	lw t1, function_trace_stop
fc49a3be WZ	105	bnez t1, ftrace_stub
69a7d1b3	106	nop
fc49a3be WZ	107	PTR_LA t1, ftrace_stub
	108	PTR_L t2, ftrace_trace_function /* Prepare t2 for (1) */
	109	bne t1, t2, static_trace
d2bb0762	110	nop
29c5d346 WZ	111
29c5d346 WZ	112	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
fc49a3be WZ	113	PTR_L t3, ftrace_graph_return
fc49a3be WZ	114	bne t1, t3, ftrace_graph_caller
29c5d346	115	nop
fc49a3be WZ	116	PTR_LA t1, ftrace_graph_entry_stub
	117	PTR_L t3, ftrace_graph_entry
	118	bne t1, t3, ftrace_graph_caller
29c5d346 WZ	119	nop
29c5d346 WZ	120	#endif
d2bb0762 WZ	121	b ftrace_stub
	122	nop
	123
	124	static_trace:
	125	MCOUNT_SAVE_REGS
	126
042e571d	127	move a0, ra /* arg1: self return address */
fc49a3be	128	jalr t2 /* (1) call ftrace_trace_function /
042e571d	129	move a1, AT /* arg2: parent's return address */
d2bb0762 WZ	130
	131	MCOUNT_RESTORE_REGS
	132	.globl ftrace_stub
	133	ftrace_stub:
	134	RETURN_BACK
	135	END(_mcount)
	136
538f1952 WZ	137	#endif /* ! CONFIG_DYNAMIC_FTRACE */
538f1952 WZ	138
29c5d346 WZ	139	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	140
	141	NESTED(ftrace_graph_caller, PT_SIZE, ra)
cbe555b0	142	#ifndef CONFIG_DYNAMIC_FTRACE
29c5d346	143	MCOUNT_SAVE_REGS
e17ff5fe	144	#endif
7326c4e5	145
cbe555b0	146	/* arg1: Get the location of the parent's return address */
7326c4e5	147	#ifdef KBUILD_MCOUNT_RA_ADDRESS
cbe555b0 WZ	148	#ifdef CONFIG_DYNAMIC_FTRACE
	149	PTR_L a0, PT_R12(sp)
	150	#else
56b49cd3	151	move a0, MCOUNT_RA_ADDRESS_REG
cbe555b0	152	#endif
56b49cd3	153	bnez a0, 1f /* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
7326c4e5	154	nop
cbe555b0 WZ	155	#endif
	156	PTR_LA a0, PT_R1(sp) /* leaf func: the location in current stack */
	157	1:
	158
	159	/* arg2: Get self return address */
	160	#ifdef CONFIG_DYNAMIC_FTRACE
	161	PTR_L a1, PT_R31(sp)
7326c4e5	162	#else
cbe555b0	163	move a1, ra
7326c4e5	164	#endif
cbe555b0 WZ	165
cbe555b0 WZ	166	/* arg3: Get frame pointer of current stack */
046199ca	167	#ifdef CONFIG_FRAME_POINTER
cbe555b0 WZ	168	move a2, fp
cbe555b0 WZ	169	#else /* ! CONFIG_FRAME_POINTER */
046199ca WZ	170	#ifdef CONFIG_64BIT
	171	PTR_LA a2, PT_SIZE(sp)
	172	#else
	173	PTR_LA a2, (PT_SIZE+8)(sp)
	174	#endif
	175	#endif
29c5d346	176
cbe555b0 WZ	177	jal prepare_ftrace_return
cbe555b0 WZ	178	nop
29c5d346 WZ	179	MCOUNT_RESTORE_REGS
	180	RETURN_BACK
	181	END(ftrace_graph_caller)
	182
	183	.align 2
	184	.globl return_to_handler
	185	return_to_handler:
	186	PTR_SUBU sp, PT_SIZE
	187	PTR_S v0, PT_R2(sp)
	188
	189	jal ftrace_return_to_handler
	190	PTR_S v1, PT_R3(sp)
	191
	192	/* restore the real parent address: v0 -> ra */
	193	move ra, v0
	194
	195	PTR_L v0, PT_R2(sp)
	196	PTR_L v1, PT_R3(sp)
	197	jr ra
	198	PTR_ADDIU sp, PT_SIZE
	199	#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
	200
d2bb0762 WZ	201	.set at
d2bb0762 WZ	202	.set reorder