arch/arm/kernel/head.S

   1 /*
   2  *  linux/arch/arm/kernel/head.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  *  Kernel startup code for all 32-bit CPUs
  13  */
  14 #include <linux/linkage.h>
  15 #include <linux/init.h>
  16
  17 #include <asm/assembler.h>
  18 #include <asm/domain.h>
  19 #include <asm/ptrace.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/memory.h>
  22 #include <asm/thread_info.h>
  23 #include <asm/system.h>
  24
  25 #if (PHYS_OFFSET & 0x001fffff)
  26 #error "PHYS_OFFSET must be at an even 2MiB boundary!"
  27 #endif
  28
  29 #define KERNEL_RAM_VADDR        (PAGE_OFFSET + TEXT_OFFSET)
  30 #define KERNEL_RAM_PADDR        (PHYS_OFFSET + TEXT_OFFSET)
  31
  32
  33 /*
  34  * swapper_pg_dir is the virtual address of the initial page table.
  35  * We place the page tables 16K below KERNEL_RAM_VADDR.  Therefore, we must
  36  * make sure that KERNEL_RAM_VADDR is correctly set.  Currently, we expect
  37  * the least significant 16 bits to be 0x8000, but we could probably
  38  * relax this restriction to KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
  39  */
  40 #if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
  41 #error KERNEL_RAM_VADDR must start at 0xXXXX8000
  42 #endif
  43
  44         .globl  swapper_pg_dir
  45         .equ    swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000
  46
  47         .macro  pgtbl, rd
  48         ldr     \rd, =(KERNEL_RAM_PADDR - 0x4000)
  49         .endm
  50
  51 #ifdef CONFIG_XIP_KERNEL
  52 #define KERNEL_START    XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
  53 #define KERNEL_END      _edata_loc
  54 #else
  55 #define KERNEL_START    KERNEL_RAM_VADDR
  56 #define KERNEL_END      _end
  57 #endif
  58
  59 /*
  60  * Kernel startup entry point.
  61  * ---------------------------
  62  *
  63  * This is normally called from the decompressor code.  The requirements
  64  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  65  * r1 = machine nr, r2 = atags pointer.
  66  *
  67  * This code is mostly position independent, so if you link the kernel at
  68  * 0xc0008000, you call this at __pa(0xc0008000).
  69  *
  70  * See linux/arch/arm/tools/mach-types for the complete list of machine
  71  * numbers for r1.
  72  *
  73  * We're trying to keep crap to a minimum; DO NOT add any machine specific
  74  * crap here - that's what the boot loader (or in extreme, well justified
  75  * circumstances, zImage) is for.
  76  */
  77         __HEAD
  78 ENTRY(stext)
  79         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ ensure svc mode
  80                                                 @ and irqs disabled
  81         mrc     p15, 0, r9, c0, c0              @ get processor id
  82         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
  83         movs    r10, r5                         @ invalid processor (r5=0)?
  84         beq     __error_p                       @ yes, error 'p'
  85         bl      __lookup_machine_type           @ r5=machinfo
  86         movs    r8, r5                          @ invalid machine (r5=0)?
  87         beq     __error_a                       @ yes, error 'a'
  88         bl      __vet_atags
  89 #ifdef CONFIG_SMP_ON_UP
  90         bl      __fixup_smp
  91 #endif
  92         bl      __create_page_tables
  93
  94         /*
  95          * The following calls CPU specific code in a position independent
  96          * manner.  See arch/arm/mm/proc-*.S for details.  r10 = base of
  97          * xxx_proc_info structure selected by __lookup_machine_type
  98          * above.  On return, the CPU will be ready for the MMU to be
  99          * turned on, and r0 will hold the CPU control register value.
 100          */
 101         ldr     r13, __switch_data              @ address to jump to after
 102                                                 @ mmu has been enabled
 103         adr     lr, BSYM(__enable_mmu)          @ return (PIC) address
 104  ARM(   add     pc, r10, #PROCINFO_INITFUNC     )
 105  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 106  THUMB( mov     pc, r12                         )
 107 ENDPROC(stext)
 108
 109 #if defined(CONFIG_SMP)
 110 ENTRY(secondary_startup)
 111         /*
 112          * Common entry point for secondary CPUs.
 113          *
 114          * Ensure that we're in SVC mode, and IRQs are disabled.  Lookup
 115          * the processor type - there is no need to check the machine type
 116          * as it has already been validated by the primary processor.
 117          */
 118         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9
 119         mrc     p15, 0, r9, c0, c0              @ get processor id
 120         bl      __lookup_processor_type
 121         movs    r10, r5                         @ invalid processor?
 122         moveq   r0, #'p'                        @ yes, error 'p'
 123         beq     __error
 124
 125         /*
 126          * Use the page tables supplied from  __cpu_up.
 127          */
 128         adr     r4, __secondary_data
 129         ldmia   r4, {r5, r7, r12}               @ address to jump to after
 130         sub     r4, r4, r5                      @ mmu has been enabled
 131         ldr     r4, [r7, r4]                    @ get secondary_data.pgdir
 132         adr     lr, BSYM(__enable_mmu)          @ return address
 133         mov     r13, r12                        @ __secondary_switched address
 134  ARM(   add     pc, r10, #PROCINFO_INITFUNC     ) @ initialise processor
 135                                                   @ (return control reg)
 136  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 137  THUMB( mov     pc, r12                         )
 138 ENDPROC(secondary_startup)
 139
 140         /*
 141          * r6  = &secondary_data
 142          */
 143 ENTRY(__secondary_switched)
 144         ldr     sp, [r7, #4]                    @ get secondary_data.stack
 145         mov     fp, #0
 146         b       secondary_start_kernel
 147 ENDPROC(__secondary_switched)
 148
 149         .type   __secondary_data, %object
 150 __secondary_data:
 151         .long   .
 152         .long   secondary_data
 153         .long   __secondary_switched
 154 #endif /* defined(CONFIG_SMP) */
 155
 156
 157
 158 /*
 159  * Setup common bits before finally enabling the MMU.  Essentially
 160  * this is just loading the page table pointer and domain access
 161  * registers.
 162  */
 163 __enable_mmu:
 164 #ifdef CONFIG_ALIGNMENT_TRAP
 165         orr     r0, r0, #CR_A
 166 #else
 167         bic     r0, r0, #CR_A
 168 #endif
 169 #ifdef CONFIG_CPU_DCACHE_DISABLE
 170         bic     r0, r0, #CR_C
 171 #endif
 172 #ifdef CONFIG_CPU_BPREDICT_DISABLE
 173         bic     r0, r0, #CR_Z
 174 #endif
 175 #ifdef CONFIG_CPU_ICACHE_DISABLE
 176         bic     r0, r0, #CR_I
 177 #endif
 178         mov     r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
 179                       domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
 180                       domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
 181                       domain_val(DOMAIN_IO, DOMAIN_CLIENT))
 182         mcr     p15, 0, r5, c3, c0, 0           @ load domain access register
 183         mcr     p15, 0, r4, c2, c0, 0           @ load page table pointer
 184         b       __turn_mmu_on
 185 ENDPROC(__enable_mmu)
 186
 187 /*
 188  * Enable the MMU.  This completely changes the structure of the visible
 189  * memory space.  You will not be able to trace execution through this.
 190  * If you have an enquiry about this, *please* check the linux-arm-kernel
 191  * mailing list archives BEFORE sending another post to the list.
 192  *
 193  *  r0  = cp#15 control register
 194  *  r13 = *virtual* address to jump to upon completion
 195  *
 196  * other registers depend on the function called upon completion
 197  */
 198         .align  5
 199 __turn_mmu_on:
 200         mov     r0, r0
 201         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
 202         mrc     p15, 0, r3, c0, c0, 0           @ read id reg
 203         mov     r3, r3
 204         mov     r3, r13
 205         mov     pc, r3
 206 ENDPROC(__turn_mmu_on)
 207
 208
 209 /*
 210  * Setup the initial page tables.  We only setup the barest
 211  * amount which are required to get the kernel running, which
 212  * generally means mapping in the kernel code.
 213  *
 214  * r8  = machinfo
 215  * r9  = cpuid
 216  * r10 = procinfo
 217  *
 218  * Returns:
 219  *  r0, r3, r6, r7 corrupted
 220  *  r4 = physical page table address
 221  */
 222 __create_page_tables:
 223         pgtbl   r4                              @ page table address
 224
 225         /*
 226          * Clear the 16K level 1 swapper page table
 227          */
 228         mov     r0, r4
 229         mov     r3, #0
 230         add     r6, r0, #0x4000
 231 1:      str     r3, [r0], #4
 232         str     r3, [r0], #4
 233         str     r3, [r0], #4
 234         str     r3, [r0], #4
 235         teq     r0, r6
 236         bne     1b
 237
 238         ldr     r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
 239
 240         /*
 241          * Create identity mapping for first MB of kernel to
 242          * cater for the MMU enable.  This identity mapping
 243          * will be removed by paging_init().  We use our current program
 244          * counter to determine corresponding section base address.
 245          */
 246         mov     r6, pc
 247         mov     r6, r6, lsr #20                 @ start of kernel section
 248         orr     r3, r7, r6, lsl #20             @ flags + kernel base
 249         str     r3, [r4, r6, lsl #2]            @ identity mapping
 250
 251         /*
 252          * Now setup the pagetables for our kernel direct
 253          * mapped region.
 254          */
 255         add     r0, r4,  #(KERNEL_START & 0xff000000) >> 18
 256         str     r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]!
 257         ldr     r6, =(KERNEL_END - 1)
 258         add     r0, r0, #4
 259         add     r6, r4, r6, lsr #18
 260 1:      cmp     r0, r6
 261         add     r3, r3, #1 << 20
 262         strls   r3, [r0], #4
 263         bls     1b
 264
 265 #ifdef CONFIG_XIP_KERNEL
 266         /*
 267          * Map some ram to cover our .data and .bss areas.
 268          */
 269         orr     r3, r7, #(KERNEL_RAM_PADDR & 0xff000000)
 270         .if     (KERNEL_RAM_PADDR & 0x00f00000)
 271         orr     r3, r3, #(KERNEL_RAM_PADDR & 0x00f00000)
 272         .endif
 273         add     r0, r4,  #(KERNEL_RAM_VADDR & 0xff000000) >> 18
 274         str     r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> 18]!
 275         ldr     r6, =(_end - 1)
 276         add     r0, r0, #4
 277         add     r6, r4, r6, lsr #18
 278 1:      cmp     r0, r6
 279         add     r3, r3, #1 << 20
 280         strls   r3, [r0], #4
 281         bls     1b
 282 #endif
 283
 284         /*
 285          * Then map first 1MB of ram in case it contains our boot params.
 286          */
 287         add     r0, r4, #PAGE_OFFSET >> 18
 288         orr     r6, r7, #(PHYS_OFFSET & 0xff000000)
 289         .if     (PHYS_OFFSET & 0x00f00000)
 290         orr     r6, r6, #(PHYS_OFFSET & 0x00f00000)
 291         .endif
 292         str     r6, [r0]
 293
 294 #ifdef CONFIG_DEBUG_LL
 295         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 296         /*
 297          * Map in IO space for serial debugging.
 298          * This allows debug messages to be output
 299          * via a serial console before paging_init.
 300          */
 301         ldr     r3, [r8, #MACHINFO_PGOFFIO]
 302         add     r0, r4, r3
 303         rsb     r3, r3, #0x4000                 @ PTRS_PER_PGD*sizeof(long)
 304         cmp     r3, #0x0800                     @ limit to 512MB
 305         movhi   r3, #0x0800
 306         add     r6, r0, r3
 307         ldr     r3, [r8, #MACHINFO_PHYSIO]
 308         orr     r3, r3, r7
 309 1:      str     r3, [r0], #4
 310         add     r3, r3, #1 << 20
 311         teq     r0, r6
 312         bne     1b
 313 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
 314         /*
 315          * If we're using the NetWinder or CATS, we also need to map
 316          * in the 16550-type serial port for the debug messages
 317          */
 318         add     r0, r4, #0xff000000 >> 18
 319         orr     r3, r7, #0x7c000000
 320         str     r3, [r0]
 321 #endif
 322 #ifdef CONFIG_ARCH_RPC
 323         /*
 324          * Map in screen at 0x02000000 & SCREEN2_BASE
 325          * Similar reasons here - for debug.  This is
 326          * only for Acorn RiscPC architectures.
 327          */
 328         add     r0, r4, #0x02000000 >> 18
 329         orr     r3, r7, #0x02000000
 330         str     r3, [r0]
 331         add     r0, r4, #0xd8000000 >> 18
 332         str     r3, [r0]
 333 #endif
 334 #endif
 335         mov     pc, lr
 336 ENDPROC(__create_page_tables)
 337         .ltorg
 338
 339 #ifdef CONFIG_SMP_ON_UP
 340 __fixup_smp:
 341         mov     r7, #0x00070000
 342         orr     r6, r7, #0xff000000     @ mask 0xff070000
 343         orr     r7, r7, #0x41000000     @ val 0x41070000
 344         and     r0, r9, r6
 345         teq     r0, r7                  @ ARM CPU and ARMv6/v7?
 346         bne     __fixup_smp_on_up       @ no, assume UP
 347
 348         orr     r6, r6, #0x0000ff00
 349         orr     r6, r6, #0x000000f0     @ mask 0xff07fff0
 350         orr     r7, r7, #0x0000b000
 351         orr     r7, r7, #0x00000020     @ val 0x4107b020
 352         and     r0, r9, r6
 353         teq     r0, r7                  @ ARM 11MPCore?
 354         moveq   pc, lr                  @ yes, assume SMP
 355
 356         mrc     p15, 0, r0, c0, c0, 5   @ read MPIDR
 357         tst     r0, #1 << 31
 358         movne   pc, lr                  @ bit 31 => SMP
 359
 360 __fixup_smp_on_up:
 361         adr     r0, 1f
 362         ldmia   r0, {r3, r6, r7}
 363         sub     r3, r0, r3
 364         add     r6, r6, r3
 365         add     r7, r7, r3
 366 2:      cmp     r6, r7
 367         ldmia   r6!, {r0, r4}
 368         strlo   r4, [r0, r3]
 369         blo     2b
 370         mov     pc, lr
 371 ENDPROC(__fixup_smp)
 372
 373 1:      .word   .
 374         .word   __smpalt_begin
 375         .word   __smpalt_end
 376
 377         .pushsection .data
 378         .globl  smp_on_up
 379 smp_on_up:
 380         ALT_SMP(.long   1)
 381         ALT_UP(.long    0)
 382         .popsection
 383
 384 #endif
 385
 386 #include "head-common.S"