[net-next-2.6.git] / scripts / recordmcount.pl

#!/usr/bin/perl -w
# (c) 2008, Steven Rostedt <srostedt@redhat.com>
# Licensed under the terms of the GNU GPL License version 2
#
# recordmcount.pl - makes a section called __mcount_loc that holds
#                   all the offsets to the calls to mcount.
#
#
# What we want to end up with this is that each object file will have a
# section called __mcount_loc that will hold the list of pointers to mcount
# callers. After final linking, the vmlinux will have within .init.data the
# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
# Later on boot up, the kernel will read this list, save the locations and turn
# them into nops. When tracing or profiling is later enabled, these locations
# will then be converted back to pointers to some function.
#
# This is no easy feat. This script is called just after the original
# object is compiled and before it is linked.
#
# When parse this object file using 'objdump', the references to the call
# sites are offsets from the section that the call site is in. Hence, all
# functions in a section that has a call site to mcount, will have the
# offset from the beginning of the section and not the beginning of the
# function.
#
# But where this section will reside finally in vmlinx is undetermined at
# this point. So we can't use this kind of offsets to record the final
# address of this call site.
#
# The trick is to change the call offset referring the start of a section to
# referring a function symbol in this section. During the link step, 'ld' will
# compute the final address according to the information we record.
#
# e.g.
#
#  .section ".sched.text", "ax"
#        [...]
#  func1:
#        [...]
#        call mcount  (offset: 0x10)
#        [...]
#        ret
#  .globl fun2
#  func2:             (offset: 0x20)
#        [...]
#        [...]
#        ret
#  func3:
#        [...]
#        call mcount (offset: 0x30)
#        [...]
#
# Both relocation offsets for the mcounts in the above example will be
# offset from .sched.text. If we choose global symbol func2 as a reference and
# make another file called tmp.s with the new offsets:
#
#  .section __mcount_loc
#  .quad  func2 - 0x10
#  .quad  func2 + 0x10
#
# We can then compile this tmp.s into tmp.o, and link it back to the original
# object.
#
# In our algorithm, we will choose the first global function we meet in this
# section as the reference. But this gets hard if there is no global functions
# in this section. In such a case we have to select a local one. E.g. func1:
#
#  .section ".sched.text", "ax"
#  func1:
#        [...]
#        call mcount  (offset: 0x10)
#        [...]
#        ret
#  func2:
#        [...]
#        call mcount (offset: 0x20)
#        [...]
#  .section "other.section"
#
# If we make the tmp.s the same as above, when we link together with
# the original object, we will end up with two symbols for func1:
# one local, one global.  After final compile, we will end up with
# an undefined reference to func1 or a wrong reference to another global
# func1 in other files.
#
# Since local objects can reference local variables, we need to find
# a way to make tmp.o reference the local objects of the original object
# file after it is linked together. To do this, we convert func1
# into a global symbol before linking tmp.o. Then after we link tmp.o
# we will only have a single symbol for func1 that is global.
# We can convert func1 back into a local symbol and we are done.
#
# Here are the steps we take:
#
# 1) Record all the local and weak symbols by using 'nm'
# 2) Use objdump to find all the call site offsets and sections for
#    mcount.
# 3) Compile the list into its own object.
# 4) Do we have to deal with local functions? If not, go to step 8.
# 5) Make an object that converts these local functions to global symbols
#    with objcopy.
# 6) Link together this new object with the list object.
# 7) Convert the local functions back to local symbols and rename
#    the result as the original object.
# 8) Link the object with the list object.
# 9) Move the result back to the original object.
#

use strict;

my $P = $0;
$P =~ s@.*/@@g;

my $V = '0.1';

if ($#ARGV != 11) {
	print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
	print "version: $V\n";
	exit(1);
}

my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
    $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;

# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
    exit(0);
}

# Acceptable sections to record.
my %text_sections = (
     ".text" => 1,
     ".sched.text" => 1,
     ".spinlock.text" => 1,
     ".irqentry.text" => 1,
     ".text.unlikely" => 1,
);

# Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
$objdump = 'objdump' if (!$objdump);
$objcopy = 'objcopy' if (!$objcopy);
$cc = 'gcc' if (!$cc);
$ld = 'ld' if (!$ld);
$nm = 'nm' if (!$nm);
$rm = 'rm' if (!$rm);
$mv = 'mv' if (!$mv);

#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
#    "'$nm' '$rm' '$mv' '$inputfile'\n";

my %locals;		# List of local (static) functions
my %weak;		# List of weak functions
my %convert;		# List of local functions used that needs conversion

my $type;
my $local_regex;	# Match a local function (return function)
my $weak_regex; 	# Match a weak function (return function)
my $section_regex;	# Find the start of a section
my $function_regex;	# Find the name of a function
			#    (return offset and func name)
my $mcount_regex;	# Find the call site to mcount (return offset)
my $mcount_adjust;	# Address adjustment to mcount offset
my $alignment;		# The .align value to use for $mcount_section
my $section_type;	# Section header plus possible alignment command
my $can_use_local = 0; 	# If we can use local function references

# Shut up recordmcount if user has older objcopy
my $quiet_recordmcount = ".tmp_quiet_recordmcount";
my $print_warning = 1;
$print_warning = 0 if ( -f $quiet_recordmcount);

##
# check_objcopy - whether objcopy supports --globalize-symbols
#
#  --globalize-symbols came out in 2.17, we must test the version
#  of objcopy, and if it is less than 2.17, then we can not
#  record local functions.
sub check_objcopy
{
    open (IN, "$objcopy --version |") or die "error running $objcopy";
    while (<IN>) {
	if (/objcopy.*\s(\d+)\.(\d+)/) {
	    $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
	    last;
	}
    }
    close (IN);

    if (!$can_use_local && $print_warning) {
	print STDERR "WARNING: could not find objcopy version or version " .
	    "is less than 2.17.\n" .
	    "\tLocal function references are disabled.\n";
	open (QUIET, ">$quiet_recordmcount");
	printf QUIET "Disables the warning from recordmcount.pl\n";
	close QUIET;
    }
}

if ($arch =~ /(x86(_64)?)|(i386)/) {
    if ($bits == 64) {
	$arch = "x86_64";
    } else {
	$arch = "i386";
    }
}

#
# We base the defaults off of i386, the other archs may
# feel free to change them in the below if statements.
#
$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
$section_regex = "Disassembly of section\\s+(\\S+):";
$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
$section_type = '@progbits';
$mcount_adjust = 0;
$type = ".long";

if ($arch eq "x86_64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
    $type = ".quad";
    $alignment = 8;

    # force flags for this arch
    $ld .= " -m elf_x86_64";
    $objdump .= " -M x86-64";
    $objcopy .= " -O elf64-x86-64";
    $cc .= " -m64";

} elsif ($arch eq "i386") {
    $alignment = 4;

    # force flags for this arch
    $ld .= " -m elf_i386";
    $objdump .= " -M i386";
    $objcopy .= " -O elf32-i386";
    $cc .= " -m32";

} elsif ($arch eq "s390" && $bits == 32) {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
    $alignment = 4;
    $ld .= " -m elf_s390";
    $cc .= " -m31";

} elsif ($arch eq "s390" && $bits == 64) {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
    $alignment = 8;
    $type = ".quad";
    $ld .= " -m elf64_s390";
    $cc .= " -m64";

} elsif ($arch eq "sh") {
    $alignment = 2;

    # force flags for this arch
    $ld .= " -m shlelf_linux";
    $objcopy .= " -O elf32-sh-linux";
    $cc .= " -m32";

} elsif ($arch eq "powerpc") {
    $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";

    if ($bits == 64) {
	$type = ".quad";
    }

} elsif ($arch eq "arm") {
    $alignment = 2;
    $section_type = '%progbits';
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
			"\\s+(__gnu_mcount_nc|mcount)\$";

} elsif ($arch eq "ia64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
    $type = "data8";

    if ($is_module eq "0") {
        $cc .= " -mconstant-gp";
    }
} elsif ($arch eq "sparc64") {
    # In the objdump output there are giblets like:
    # 0000000000000000 <igmp_net_exit-0x18>:
    # As there's some data blobs that get emitted into the
    # text section before the first instructions and the first
    # real symbols.  We don't want to match that, so to combat
    # this we use '\w' so we'll match just plain symbol names,
    # and not those that also include hex offsets inside of the
    # '<>' brackets.  Actually the generic function_regex setting
    # could safely use this too.
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";

    # Sparc64 calls '_mcount' instead of plain 'mcount'.
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";

    $alignment = 8;
    $type = ".xword";
    $ld .= " -m elf64_sparc";
    $cc .= " -m64";
    $objcopy .= " -O elf64-sparc";
} elsif ($arch eq "mips") {
    # To enable module support, we need to enable the -mlong-calls option
    # of gcc for module, after using this option, we can not get the real
    # offset of the calling to _mcount, but the offset of the lui
    # instruction or the addiu one. herein, we record the address of the
    # first one, and then we can replace this instruction by a branch
    # instruction to jump over the profiling function to filter the
    # indicated functions, or swith back to the lui instruction to trace
    # them, which means dynamic tracing.
    #
    #       c:	3c030000 	lui	v1,0x0
    #			c: R_MIPS_HI16	_mcount
    #			c: R_MIPS_NONE	*ABS*
    #			c: R_MIPS_NONE	*ABS*
    #      10:	64630000 	daddiu	v1,v1,0
    #			10: R_MIPS_LO16	_mcount
    #			10: R_MIPS_NONE	*ABS*
    #			10: R_MIPS_NONE	*ABS*
    #      14:	03e0082d 	move	at,ra
    #      18:	0060f809 	jalr	v1
    #
    # for the kernel:
    #
    #     10:   03e0082d        move    at,ra
    #	  14:   0c000000        jal     0 <loongson_halt>
    #                    14: R_MIPS_26   _mcount
    #                    14: R_MIPS_NONE *ABS*
    #                    14: R_MIPS_NONE *ABS*
    #	 18:   00020021        nop
    if ($is_module eq "0") {
	    $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
    } else {
	    $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
    }
    $objdump .= " -Melf-trad".$endian."mips ";

    if ($endian eq "big") {
	    $endian = " -EB ";
	    $ld .= " -melf".$bits."btsmip";
    } else {
	    $endian = " -EL ";
	    $ld .= " -melf".$bits."ltsmip";
    }

    $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
    $ld .= $endian;

    if ($bits == 64) {
	    $function_regex =
		"^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
	    $type = ".dword";
    }
} elsif ($arch eq "microblaze") {
    # Microblaze calls '_mcount' instead of plain 'mcount'.
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
} elsif ($arch eq "blackfin") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
    $mcount_adjust = -4;
} else {
    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
}

my $text_found = 0;
my $read_function = 0;
my $opened = 0;
my $mcount_section = "__mcount_loc";

my $dirname;
my $filename;
my $prefix;
my $ext;

if ($inputfile =~ m,^(.*)/([^/]*)$,) {
    $dirname = $1;
    $filename = $2;
} else {
    $dirname = ".";
    $filename = $inputfile;
}

if ($filename =~ m,^(.*)(\.\S),) {
    $prefix = $1;
    $ext = $2;
} else {
    $prefix = $filename;
    $ext = "";
}

my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";

check_objcopy();

#
# Step 1: find all the local (static functions) and weak symbols.
#         't' is local, 'w/W' is weak
#
open (IN, "$nm $inputfile|") || die "error running $nm";
while (<IN>) {
    if (/$local_regex/) {
	$locals{$1} = 1;
    } elsif (/$weak_regex/) {
	$weak{$2} = $1;
    }
}
close(IN);

my @offsets;		# Array of offsets of mcount callers
my $ref_func;		# reference function to use for offsets
my $offset = 0;		# offset of ref_func to section beginning

##
# update_funcs - print out the current mcount callers
#
#  Go through the list of offsets to callers and write them to
#  the output file in a format that can be read by an assembler.
#
sub update_funcs
{
    return unless ($ref_func and @offsets);

    # Sanity check on weak function. A weak function may be overwritten by
    # another function of the same name, making all these offsets incorrect.
    if (defined $weak{$ref_func}) {
	die "$inputfile: ERROR: referencing weak function" .
	    " $ref_func for mcount\n";
    }

    # is this function static? If so, note this fact.
    if (defined $locals{$ref_func}) {

	# only use locals if objcopy supports globalize-symbols
	if (!$can_use_local) {
	    return;
	}
	$convert{$ref_func} = 1;
    }

    # Loop through all the mcount caller offsets and print a reference
    # to the caller based from the ref_func.
    if (!$opened) {
	open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
	$opened = 1;
	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	print FILE "\t.align $alignment\n" if (defined($alignment));
    }
    foreach my $cur_offset (@offsets) {
	printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
    }
}

#
# Step 2: find the sections and mcount call sites
#
open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";

my $text;


# read headers first
my $read_headers = 1;

while (<IN>) {

    if ($read_headers && /$mcount_section/) {
	#
	# Somehow the make process can execute this script on an
	# object twice. If it does, we would duplicate the mcount
	# section and it will cause the function tracer self test
	# to fail. Check if the mcount section exists, and if it does,
	# warn and exit.
	#
	print STDERR "ERROR: $mcount_section already in $inputfile\n" .
	    "\tThis may be an indication that your build is corrupted.\n" .
	    "\tDelete $inputfile and try again. If the same object file\n" .
	    "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
	exit(-1);
    }

    # is it a section?
    if (/$section_regex/) {
	$read_headers = 0;

	# Only record text sections that we know are safe
	$read_function = defined($text_sections{$1});
	# print out any recorded offsets
	update_funcs();

	# reset all markers and arrays
	$text_found = 0;
	undef($ref_func);
	undef(@offsets);

    # section found, now is this a start of a function?
    } elsif ($read_function && /$function_regex/) {
	$text_found = 1;
	$text = $2;

	# if this is either a local function or a weak function
	# keep looking for functions that are global that
	# we can use safely.
	if (!defined($locals{$text}) && !defined($weak{$text})) {
	    $ref_func = $text;
	    $read_function = 0;
	    $offset = hex $1;
	} else {
	    # if we already have a function, and this is weak, skip it
	    if (!defined($ref_func) && !defined($weak{$text}) &&
		 # PPC64 can have symbols that start with .L and
		 # gcc considers these special. Don't use them!
		 $text !~ /^\.L/) {
		$ref_func = $text;
		$offset = hex $1;
	    }
	}
    }
    # is this a call site to mcount? If so, record it to print later
    if ($text_found && /$mcount_regex/) {
	push(@offsets, (hex $1) + $mcount_adjust);
    }
}

# dump out anymore offsets that may have been found
update_funcs();

# If we did not find any mcount callers, we are done (do nothing).
if (!$opened) {
    exit(0);
}

close(FILE);

#
# Step 3: Compile the file that holds the list of call sites to mcount.
#
`$cc -o $mcount_o -c $mcount_s`;

my @converts = keys %convert;

#
# Step 4: Do we have sections that started with local functions?
#
if ($#converts >= 0) {
    my $globallist = "";
    my $locallist = "";

    foreach my $con (@converts) {
	$globallist .= " --globalize-symbol $con";
	$locallist .= " --localize-symbol $con";
    }

    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
    my $globalmix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 5: set up each local function as a global
    #
    `$objcopy $globallist $inputfile $globalobj`;

    #
    # Step 6: Link the global version to our list.
    #
    `$ld -r $globalobj $mcount_o -o $globalmix`;

    #
    # Step 7: Convert the local functions back into local symbols
    #
    `$objcopy $locallist $globalmix $inputfile`;

    # Remove the temp files
    `$rm $globalobj $globalmix`;

} else {

    my $mix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 8: Link the object with our list of call sites object.
    #
    `$ld -r $inputfile $mcount_o -o $mix`;

    #
    # Step 9: Move the result back to the original object.
    #
    `$mv $mix $inputfile`;
}

# Clean up the temp files
`$rm $mcount_o $mcount_s`;

exit(0);
Commit	Line	Data
	1	#!/usr/bin/perl -w
	2	# (c) 2008, Steven Rostedt <srostedt@redhat.com>
	3	# Licensed under the terms of the GNU GPL License version 2
	4	#
	5	# recordmcount.pl - makes a section called __mcount_loc that holds
	6	# all the offsets to the calls to mcount.
	7	#
	8	#
	9	# What we want to end up with this is that each object file will have a
	10	# section called __mcount_loc that will hold the list of pointers to mcount
	11	# callers. After final linking, the vmlinux will have within .init.data the
	12	# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
	13	# Later on boot up, the kernel will read this list, save the locations and turn
	14	# them into nops. When tracing or profiling is later enabled, these locations
	15	# will then be converted back to pointers to some function.
	16	#
	17	# This is no easy feat. This script is called just after the original
	18	# object is compiled and before it is linked.
	19	#
	20	# When parse this object file using 'objdump', the references to the call
	21	# sites are offsets from the section that the call site is in. Hence, all
	22	# functions in a section that has a call site to mcount, will have the
	23	# offset from the beginning of the section and not the beginning of the
	24	# function.
	25	#
	26	# But where this section will reside finally in vmlinx is undetermined at
	27	# this point. So we can't use this kind of offsets to record the final
	28	# address of this call site.
	29	#
	30	# The trick is to change the call offset referring the start of a section to
	31	# referring a function symbol in this section. During the link step, 'ld' will
	32	# compute the final address according to the information we record.
	33	#
	34	# e.g.
	35	#
	36	# .section ".sched.text", "ax"
	37	# [...]
	38	# func1:
	39	# [...]
	40	# call mcount (offset: 0x10)
	41	# [...]
	42	# ret
	43	# .globl fun2
	44	# func2: (offset: 0x20)
	45	# [...]
	46	# [...]
	47	# ret
	48	# func3:
	49	# [...]
	50	# call mcount (offset: 0x30)
	51	# [...]
	52	#
	53	# Both relocation offsets for the mcounts in the above example will be
	54	# offset from .sched.text. If we choose global symbol func2 as a reference and
	55	# make another file called tmp.s with the new offsets:
	56	#
	57	# .section __mcount_loc
	58	# .quad func2 - 0x10
	59	# .quad func2 + 0x10
	60	#
	61	# We can then compile this tmp.s into tmp.o, and link it back to the original
	62	# object.
	63	#
	64	# In our algorithm, we will choose the first global function we meet in this
	65	# section as the reference. But this gets hard if there is no global functions
	66	# in this section. In such a case we have to select a local one. E.g. func1:
	67	#
	68	# .section ".sched.text", "ax"
	69	# func1:
	70	# [...]
	71	# call mcount (offset: 0x10)
	72	# [...]
	73	# ret
	74	# func2:
	75	# [...]
	76	# call mcount (offset: 0x20)
	77	# [...]
	78	# .section "other.section"
	79	#
	80	# If we make the tmp.s the same as above, when we link together with
	81	# the original object, we will end up with two symbols for func1:
	82	# one local, one global. After final compile, we will end up with
	83	# an undefined reference to func1 or a wrong reference to another global
	84	# func1 in other files.
	85	#
	86	# Since local objects can reference local variables, we need to find
	87	# a way to make tmp.o reference the local objects of the original object
	88	# file after it is linked together. To do this, we convert func1
	89	# into a global symbol before linking tmp.o. Then after we link tmp.o
	90	# we will only have a single symbol for func1 that is global.
	91	# We can convert func1 back into a local symbol and we are done.
	92	#
	93	# Here are the steps we take:
	94	#
	95	# 1) Record all the local and weak symbols by using 'nm'
	96	# 2) Use objdump to find all the call site offsets and sections for
	97	# mcount.
	98	# 3) Compile the list into its own object.
	99	# 4) Do we have to deal with local functions? If not, go to step 8.
	100	# 5) Make an object that converts these local functions to global symbols
	101	# with objcopy.
	102	# 6) Link together this new object with the list object.
	103	# 7) Convert the local functions back to local symbols and rename
	104	# the result as the original object.
	105	# 8) Link the object with the list object.
	106	# 9) Move the result back to the original object.
	107	#
	108
	109	use strict;
	110
	111	my $P = $0;
	112	$P =~ s@.*/@@g;
	113
	114	my $V = '0.1';
	115
	116	if ($#ARGV != 11) {
	117	print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
	118	print "version: $V\n";
	119	exit(1);
	120	}
	121
	122	my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
	123	$ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
	124
	125	# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
	126	if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
	127	exit(0);
	128	}
	129
	130	# Acceptable sections to record.
	131	my %text_sections = (
	132	".text" => 1,
	133	".sched.text" => 1,
	134	".spinlock.text" => 1,
	135	".irqentry.text" => 1,
	136	".text.unlikely" => 1,
	137	);
	138
	139	# Note: we are nice to C-programmers here, thus we skip the '\|\|='-idiom.
	140	$objdump = 'objdump' if (!$objdump);
	141	$objcopy = 'objcopy' if (!$objcopy);
	142	$cc = 'gcc' if (!$cc);
	143	$ld = 'ld' if (!$ld);
	144	$nm = 'nm' if (!$nm);
	145	$rm = 'rm' if (!$rm);
	146	$mv = 'mv' if (!$mv);
	147
	148	#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
	149	# "'$nm' '$rm' '$mv' '$inputfile'\n";
	150
	151	my %locals; # List of local (static) functions
	152	my %weak; # List of weak functions
	153	my %convert; # List of local functions used that needs conversion
	154
	155	my $type;
	156	my $local_regex; # Match a local function (return function)
	157	my $weak_regex; # Match a weak function (return function)
	158	my $section_regex; # Find the start of a section
	159	my $function_regex; # Find the name of a function
	160	# (return offset and func name)
	161	my $mcount_regex; # Find the call site to mcount (return offset)
	162	my $mcount_adjust; # Address adjustment to mcount offset
	163	my $alignment; # The .align value to use for $mcount_section
	164	my $section_type; # Section header plus possible alignment command
	165	my $can_use_local = 0; # If we can use local function references
	166
	167	# Shut up recordmcount if user has older objcopy
	168	my $quiet_recordmcount = ".tmp_quiet_recordmcount";
	169	my $print_warning = 1;
	170	$print_warning = 0 if ( -f $quiet_recordmcount);
	171
	172	##
	173	# check_objcopy - whether objcopy supports --globalize-symbols
	174	#
	175	# --globalize-symbols came out in 2.17, we must test the version
	176	# of objcopy, and if it is less than 2.17, then we can not
	177	# record local functions.
	178	sub check_objcopy
	179	{
	180	open (IN, "$objcopy --version \|") or die "error running $objcopy";
	181	while (<IN>) {
	182	if (/objcopy.*\s(\d+)\.(\d+)/) {
	183	$can_use_local = 1 if ($1 > 2 \|\| ($1 == 2 && $2 >= 17));
	184	last;
	185	}
	186	}
	187	close (IN);
	188
	189	if (!$can_use_local && $print_warning) {
	190	print STDERR "WARNING: could not find objcopy version or version " .
	191	"is less than 2.17.\n" .
	192	"\tLocal function references are disabled.\n";
	193	open (QUIET, ">$quiet_recordmcount");
	194	printf QUIET "Disables the warning from recordmcount.pl\n";
	195	close QUIET;
	196	}
	197	}
	198
	199	if ($arch =~ /(x86(_64)?)\|(i386)/) {
	200	if ($bits == 64) {
	201	$arch = "x86_64";
	202	} else {
	203	$arch = "i386";
	204	}
	205	}
	206
	207	#
	208	# We base the defaults off of i386, the other archs may
	209	# feel free to change them in the below if statements.
	210	#
	211	$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
	212	$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
	213	$section_regex = "Disassembly of section\\s+(\\S+):";
	214	$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
	215	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount\$";
	216	$section_type = '@progbits';
	217	$mcount_adjust = 0;
	218	$type = ".long";
	219
	220	if ($arch eq "x86_64") {
	221	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
	222	$type = ".quad";
	223	$alignment = 8;
	224
	225	# force flags for this arch
	226	$ld .= " -m elf_x86_64";
	227	$objdump .= " -M x86-64";
	228	$objcopy .= " -O elf64-x86-64";
	229	$cc .= " -m64";
	230
	231	} elsif ($arch eq "i386") {
	232	$alignment = 4;
	233
	234	# force flags for this arch
	235	$ld .= " -m elf_i386";
	236	$objdump .= " -M i386";
	237	$objcopy .= " -O elf32-i386";
	238	$cc .= " -m32";
	239
	240	} elsif ($arch eq "s390" && $bits == 32) {
	241	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_390_32\\s+_mcount\$";
	242	$alignment = 4;
	243	$ld .= " -m elf_s390";
	244	$cc .= " -m31";
	245
	246	} elsif ($arch eq "s390" && $bits == 64) {
	247	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_390_(PC\|PLT)32DBL\\s+_mcount\\+0x2\$";
	248	$alignment = 8;
	249	$type = ".quad";
	250	$ld .= " -m elf64_s390";
	251	$cc .= " -m64";
	252
	253	} elsif ($arch eq "sh") {
	254	$alignment = 2;
	255
	256	# force flags for this arch
	257	$ld .= " -m shlelf_linux";
	258	$objcopy .= " -O elf32-sh-linux";
	259	$cc .= " -m32";
	260
	261	} elsif ($arch eq "powerpc") {
	262	$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
	263	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
	264	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s\\.?_mcount\$";
	265
	266	if ($bits == 64) {
	267	$type = ".quad";
	268	}
	269
	270	} elsif ($arch eq "arm") {
	271	$alignment = 2;
	272	$section_type = '%progbits';
	273	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_ARM_(CALL\|PC24\|THM_CALL)" .
	274	"\\s+(__gnu_mcount_nc\|mcount)\$";
	275
	276	} elsif ($arch eq "ia64") {
	277	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	278	$type = "data8";
	279
	280	if ($is_module eq "0") {
	281	$cc .= " -mconstant-gp";
	282	}
	283	} elsif ($arch eq "sparc64") {
	284	# In the objdump output there are giblets like:
	285	# 0000000000000000 <igmp_net_exit-0x18>:
	286	# As there's some data blobs that get emitted into the
	287	# text section before the first instructions and the first
	288	# real symbols. We don't want to match that, so to combat
	289	# this we use '\w' so we'll match just plain symbol names,
	290	# and not those that also include hex offsets inside of the
	291	# '<>' brackets. Actually the generic function_regex setting
	292	# could safely use this too.
	293	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
	294
	295	# Sparc64 calls '_mcount' instead of plain 'mcount'.
	296	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	297
	298	$alignment = 8;
	299	$type = ".xword";
	300	$ld .= " -m elf64_sparc";
	301	$cc .= " -m64";
	302	$objcopy .= " -O elf64-sparc";
	303	} elsif ($arch eq "mips") {
	304	# To enable module support, we need to enable the -mlong-calls option
	305	# of gcc for module, after using this option, we can not get the real
	306	# offset of the calling to _mcount, but the offset of the lui
	307	# instruction or the addiu one. herein, we record the address of the
	308	# first one, and then we can replace this instruction by a branch
	309	# instruction to jump over the profiling function to filter the
	310	# indicated functions, or swith back to the lui instruction to trace
	311	# them, which means dynamic tracing.
	312	#
	313	# c: 3c030000 lui v1,0x0
	314	# c: R_MIPS_HI16 _mcount
	315	# c: R_MIPS_NONE ABS
	316	# c: R_MIPS_NONE ABS
	317	# 10: 64630000 daddiu v1,v1,0
	318	# 10: R_MIPS_LO16 _mcount
	319	# 10: R_MIPS_NONE ABS
	320	# 10: R_MIPS_NONE ABS
	321	# 14: 03e0082d move at,ra
	322	# 18: 0060f809 jalr v1
	323	#
	324	# for the kernel:
	325	#
	326	# 10: 03e0082d move at,ra
	327	# 14: 0c000000 jal 0 <loongson_halt>
	328	# 14: R_MIPS_26 _mcount
	329	# 14: R_MIPS_NONE ABS
	330	# 14: R_MIPS_NONE ABS
	331	# 18: 00020021 nop
	332	if ($is_module eq "0") {
	333	$mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
	334	} else {
	335	$mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
	336	}
	337	$objdump .= " -Melf-trad".$endian."mips ";
	338
	339	if ($endian eq "big") {
	340	$endian = " -EB ";
	341	$ld .= " -melf".$bits."btsmip";
	342	} else {
	343	$endian = " -EL ";
	344	$ld .= " -melf".$bits."ltsmip";
	345	}
	346
	347	$cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
	348	$ld .= $endian;
	349
	350	if ($bits == 64) {
	351	$function_regex =
	352	"^([0-9a-fA-F]+)\\s+<(.\|[^\$]L.?\|\$[^L].?\|[^\$][^L].*?)>:";
	353	$type = ".dword";
	354	}
	355	} elsif ($arch eq "microblaze") {
	356	# Microblaze calls '_mcount' instead of plain 'mcount'.
	357	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	358	} elsif ($arch eq "blackfin") {
	359	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s__mcount\$";
	360	$mcount_adjust = -4;
	361	} else {
	362	die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
	363	}
	364
	365	my $text_found = 0;
	366	my $read_function = 0;
	367	my $opened = 0;
	368	my $mcount_section = "__mcount_loc";
	369
	370	my $dirname;
	371	my $filename;
	372	my $prefix;
	373	my $ext;
	374
	375	if ($inputfile =~ m,^(.)/([^/])$,) {
	376	$dirname = $1;
	377	$filename = $2;
	378	} else {
	379	$dirname = ".";
	380	$filename = $inputfile;
	381	}
	382
	383	if ($filename =~ m,^(.*)(\.\S),) {
	384	$prefix = $1;
	385	$ext = $2;
	386	} else {
	387	$prefix = $filename;
	388	$ext = "";
	389	}
	390
	391	my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
	392	my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
	393
	394	check_objcopy();
	395
	396	#
	397	# Step 1: find all the local (static functions) and weak symbols.
	398	# 't' is local, 'w/W' is weak
	399	#
	400	open (IN, "$nm $inputfile\|") \|\| die "error running $nm";
	401	while (<IN>) {
	402	if (/$local_regex/) {
	403	$locals{$1} = 1;
	404	} elsif (/$weak_regex/) {
	405	$weak{$2} = $1;
	406	}
	407	}
	408	close(IN);
	409
	410	my @offsets; # Array of offsets of mcount callers
	411	my $ref_func; # reference function to use for offsets
	412	my $offset = 0; # offset of ref_func to section beginning
	413
	414	##
	415	# update_funcs - print out the current mcount callers
	416	#
	417	# Go through the list of offsets to callers and write them to
	418	# the output file in a format that can be read by an assembler.
	419	#
	420	sub update_funcs
	421	{
	422	return unless ($ref_func and @offsets);
	423
	424	# Sanity check on weak function. A weak function may be overwritten by
	425	# another function of the same name, making all these offsets incorrect.
	426	if (defined $weak{$ref_func}) {
	427	die "$inputfile: ERROR: referencing weak function" .
	428	" $ref_func for mcount\n";
	429	}
	430
	431	# is this function static? If so, note this fact.
	432	if (defined $locals{$ref_func}) {
	433
	434	# only use locals if objcopy supports globalize-symbols
	435	if (!$can_use_local) {
	436	return;
	437	}
	438	$convert{$ref_func} = 1;
	439	}
	440
	441	# Loop through all the mcount caller offsets and print a reference
	442	# to the caller based from the ref_func.
	443	if (!$opened) {
	444	open(FILE, ">$mcount_s") \|\| die "can't create $mcount_s\n";
	445	$opened = 1;
	446	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	447	print FILE "\t.align $alignment\n" if (defined($alignment));
	448	}
	449	foreach my $cur_offset (@offsets) {
	450	printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
	451	}
	452	}
	453
	454	#
	455	# Step 2: find the sections and mcount call sites
	456	#
	457	open(IN, "$objdump -hdr $inputfile\|") \|\| die "error running $objdump";
	458
	459	my $text;
	460
	461
	462	# read headers first
	463	my $read_headers = 1;
	464
	465	while (<IN>) {
	466
	467	if ($read_headers && /$mcount_section/) {
	468	#
	469	# Somehow the make process can execute this script on an
	470	# object twice. If it does, we would duplicate the mcount
	471	# section and it will cause the function tracer self test
	472	# to fail. Check if the mcount section exists, and if it does,
	473	# warn and exit.
	474	#
	475	print STDERR "ERROR: $mcount_section already in $inputfile\n" .
	476	"\tThis may be an indication that your build is corrupted.\n" .
	477	"\tDelete $inputfile and try again. If the same object file\n" .
	478	"\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
	479	exit(-1);
	480	}
	481
	482	# is it a section?
	483	if (/$section_regex/) {
	484	$read_headers = 0;
	485
	486	# Only record text sections that we know are safe
	487	$read_function = defined($text_sections{$1});
	488	# print out any recorded offsets
	489	update_funcs();
	490
	491	# reset all markers and arrays
	492	$text_found = 0;
	493	undef($ref_func);
	494	undef(@offsets);
	495
	496	# section found, now is this a start of a function?
	497	} elsif ($read_function && /$function_regex/) {
	498	$text_found = 1;
	499	$text = $2;
	500
	501	# if this is either a local function or a weak function
	502	# keep looking for functions that are global that
	503	# we can use safely.
	504	if (!defined($locals{$text}) && !defined($weak{$text})) {
	505	$ref_func = $text;
	506	$read_function = 0;
	507	$offset = hex $1;
	508	} else {
	509	# if we already have a function, and this is weak, skip it
	510	if (!defined($ref_func) && !defined($weak{$text}) &&
	511	# PPC64 can have symbols that start with .L and
	512	# gcc considers these special. Don't use them!
	513	$text !~ /^\.L/) {
	514	$ref_func = $text;
	515	$offset = hex $1;
	516	}
	517	}
	518	}
	519	# is this a call site to mcount? If so, record it to print later
	520	if ($text_found && /$mcount_regex/) {
	521	push(@offsets, (hex $1) + $mcount_adjust);
	522	}
	523	}
	524
	525	# dump out anymore offsets that may have been found
	526	update_funcs();
	527
	528	# If we did not find any mcount callers, we are done (do nothing).
	529	if (!$opened) {
	530	exit(0);
	531	}
	532
	533	close(FILE);
	534
	535	#
	536	# Step 3: Compile the file that holds the list of call sites to mcount.
	537	#
	538	`$cc -o $mcount_o -c $mcount_s`;
	539
	540	my @converts = keys %convert;
	541
	542	#
	543	# Step 4: Do we have sections that started with local functions?
	544	#
	545	if ($#converts >= 0) {
	546	my $globallist = "";
	547	my $locallist = "";
	548
	549	foreach my $con (@converts) {
	550	$globallist .= " --globalize-symbol $con";
	551	$locallist .= " --localize-symbol $con";
	552	}
	553
	554	my $globalobj = $dirname . "/.tmp_gl_" . $filename;
	555	my $globalmix = $dirname . "/.tmp_mx_" . $filename;
	556
	557	#
	558	# Step 5: set up each local function as a global
	559	#
	560	`$objcopy $globallist $inputfile $globalobj`;
	561
	562	#
	563	# Step 6: Link the global version to our list.
	564	#
	565	`$ld -r $globalobj $mcount_o -o $globalmix`;
	566
	567	#
	568	# Step 7: Convert the local functions back into local symbols
	569	#
	570	`$objcopy $locallist $globalmix $inputfile`;
	571
	572	# Remove the temp files
	573	`$rm $globalobj $globalmix`;
	574
	575	} else {
	576
	577	my $mix = $dirname . "/.tmp_mx_" . $filename;
	578
	579	#
	580	# Step 8: Link the object with our list of call sites object.
	581	#
	582	`$ld -r $inputfile $mcount_o -o $mix`;
	583
	584	#
	585	# Step 9: Move the result back to the original object.
	586	#
	587	`$mv $mix $inputfile`;
	588	}
	589
	590	# Clean up the temp files
	591	`$rm $mcount_o $mcount_s`;
	592
	593	exit(0);