[net-next-2.6.git] / scripts / recordmcount.pl

#!/usr/bin/perl -w
# (c) 2008, Steven Rostedt <srostedt@redhat.com>
# Licensed under the terms of the GNU GPL License version 2
#
# recordmcount.pl - makes a section called __mcount_loc that holds
#                   all the offsets to the calls to mcount.
#
#
# What we want to end up with is a section in vmlinux called
# __mcount_loc that contains a list of pointers to all the
# call sites in the kernel that call mcount. Later on boot up, the kernel
# will read this list, save the locations and turn them into nops.
# When tracing or profiling is later enabled, these locations will then
# be converted back to pointers to some function.
#
# This is no easy feat. This script is called just after the original
# object is compiled and before it is linked.
#
# The references to the call sites are offsets from the section of text
# that the call site is in. Hence, all functions in a section that
# has a call site to mcount, will have the offset from the beginning of
# the section and not the beginning of the function.
#
# The trick is to find a way to record the beginning of the section.
# The way we do this is to look at the first function in the section
# which will also be the location of that section after final link.
# e.g.
#
#  .section ".text.sched"
#  .globl my_func
#  my_func:
#        [...]
#        call mcount  (offset: 0x5)
#        [...]
#        ret
#  other_func:
#        [...]
#        call mcount (offset: 0x1b)
#        [...]
#
# Both relocation offsets for the mcounts in the above example will be
# offset from .text.sched. If we make another file called tmp.s with:
#
#  .section __mcount_loc
#  .quad  my_func + 0x5
#  .quad  my_func + 0x1b
#
# We can then compile this tmp.s into tmp.o, and link it to the original
# object.
#
# But this gets hard if my_func is not globl (a static function).
# In such a case we have:
#
#  .section ".text.sched"
#  my_func:
#        [...]
#        call mcount  (offset: 0x5)
#        [...]
#        ret
#  .globl my_func
#  other_func:
#        [...]
#        call mcount (offset: 0x1b)
#        [...]
#
# If we make the tmp.s the same as above, when we link together with
# the original object, we will end up with two symbols for my_func:
# one local, one global.  After final compile, we will end up with
# an undefined reference to my_func.
#
# Since local objects can reference local variables, we need to find
# a way to make tmp.o reference the local objects of the original object
# file after it is linked together. To do this, we convert the my_func
# into a global symbol before linking tmp.o. Then after we link tmp.o
# we will only have a single symbol for my_func that is global.
# We can convert my_func back into a local symbol and we are done.
#
# Here are the steps we take:
#
# 1) Record all the local symbols by using 'nm'
# 2) Use objdump to find all the call site offsets and sections for
#    mcount.
# 3) Compile the list into its own object.
# 4) Do we have to deal with local functions? If not, go to step 8.
# 5) Make an object that converts these local functions to global symbols
#    with objcopy.
# 6) Link together this new object with the list object.
# 7) Convert the local functions back to local symbols and rename
#    the result as the original object.
#    End.
# 8) Link the object with the list object.
# 9) Move the result back to the original object.
#    End.
#

use strict;

my $P = $0;
$P =~ s@.*/@@g;

my $V = '0.1';

if ($#ARGV < 7) {
	print "usage: $P arch objdump objcopy cc ld nm rm mv is_module inputfile\n";
	print "version: $V\n";
	exit(1);
}

my ($arch, $bits, $objdump, $objcopy, $cc,
    $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;

# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
if ($inputfile eq "kernel/trace/ftrace.o") {
    exit(0);
}

# Acceptable sections to record.
my %text_sections = (
     ".text" => 1,
     ".sched.text" => 1,
     ".spinlock.text" => 1,
     ".irqentry.text" => 1,
);

$objdump = "objdump" if ((length $objdump) == 0);
$objcopy = "objcopy" if ((length $objcopy) == 0);
$cc = "gcc" if ((length $cc) == 0);
$ld = "ld" if ((length $ld) == 0);
$nm = "nm" if ((length $nm) == 0);
$rm = "rm" if ((length $rm) == 0);
$mv = "mv" if ((length $mv) == 0);

#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
#    "'$nm' '$rm' '$mv' '$inputfile'\n";

my %locals;		# List of local (static) functions
my %weak;		# List of weak functions
my %convert;		# List of local functions used that needs conversion

my $type;
my $nm_regex;		# Find the local functions (return function)
my $section_regex;	# Find the start of a section
my $function_regex;	# Find the name of a function
			#    (return offset and func name)
my $mcount_regex;	# Find the call site to mcount (return offset)
my $alignment;		# The .align value to use for $mcount_section
my $section_type;	# Section header plus possible alignment command

if ($arch eq "x86") {
    if ($bits == 64) {
	$arch = "x86_64";
    } else {
	$arch = "i386";
    }
}

#
# We base the defaults off of i386, the other archs may
# feel free to change them in the below if statements.
#
$nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
$section_regex = "Disassembly of section\\s+(\\S+):";
$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
$section_type = '@progbits';
$type = ".long";

if ($arch eq "x86_64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
    $type = ".quad";
    $alignment = 8;

    # force flags for this arch
    $ld .= " -m elf_x86_64";
    $objdump .= " -M x86-64";
    $objcopy .= " -O elf64-x86-64";
    $cc .= " -m64";

} elsif ($arch eq "i386") {
    $alignment = 4;

    # force flags for this arch
    $ld .= " -m elf_i386";
    $objdump .= " -M i386";
    $objcopy .= " -O elf32-i386";
    $cc .= " -m32";

} elsif ($arch eq "sh") {
    $alignment = 2;

    # force flags for this arch
    $ld .= " -m shlelf_linux";
    $objcopy .= " -O elf32-sh-linux";
    $cc .= " -m32";

} elsif ($arch eq "powerpc") {
    $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";

    if ($bits == 64) {
	$type = ".quad";
    }

} elsif ($arch eq "arm") {
    $alignment = 2;
    $section_type = '%progbits';

} elsif ($arch eq "ia64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
    $type = "data8";

    if ($is_module eq "0") {
        $cc .= " -mconstant-gp";
    }
} else {
    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
}

my $text_found = 0;
my $read_function = 0;
my $opened = 0;
my $mcount_section = "__mcount_loc";

my $dirname;
my $filename;
my $prefix;
my $ext;

if ($inputfile =~ m,^(.*)/([^/]*)$,) {
    $dirname = $1;
    $filename = $2;
} else {
    $dirname = ".";
    $filename = $inputfile;
}

if ($filename =~ m,^(.*)(\.\S),) {
    $prefix = $1;
    $ext = $2;
} else {
    $prefix = $filename;
    $ext = "";
}

my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";

#
# --globalize-symbols came out in 2.17, we must test the version
# of objcopy, and if it is less than 2.17, then we can not
# record local functions.
my $use_locals = 01;
my $local_warn_once = 0;
my $found_version = 0;

open (IN, "$objcopy --version |") || die "error running $objcopy";
while (<IN>) {
    if (/objcopy.*\s(\d+)\.(\d+)/) {
	my $major = $1;
	my $minor = $2;

	$found_version = 1;
	if ($major < 2 ||
	    ($major == 2 && $minor < 17)) {
	    $use_locals = 0;
	}
	last;
    }
}
close (IN);

if (!$found_version) {
    print STDERR "WARNING: could not find objcopy version.\n" .
	"\tDisabling local function references.\n";
}


#
# Step 1: find all the local (static functions) and weak symbols.
#        't' is local, 'w/W' is weak (we never use a weak function)
#
open (IN, "$nm $inputfile|") || die "error running $nm";
while (<IN>) {
    if (/$nm_regex/) {
	$locals{$1} = 1;
    } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
	$weak{$2} = $1;
    }
}
close(IN);

my @offsets;		# Array of offsets of mcount callers
my $ref_func;		# reference function to use for offsets
my $offset = 0;		# offset of ref_func to section beginning

##
# update_funcs - print out the current mcount callers
#
#  Go through the list of offsets to callers and write them to
#  the output file in a format that can be read by an assembler.
#
sub update_funcs
{
    return if ($#offsets < 0);

    defined($ref_func) || die "No function to reference";

    # A section only had a weak function, to represent it.
    # Unfortunately, a weak function may be overwritten by another
    # function of the same name, making all these offsets incorrect.
    # To be safe, we simply print a warning and bail.
    if (defined $weak{$ref_func}) {
	print STDERR
	    "$inputfile: WARNING: referencing weak function" .
	    " $ref_func for mcount\n";
	return;
    }

    # is this function static? If so, note this fact.
    if (defined $locals{$ref_func}) {

	# only use locals if objcopy supports globalize-symbols
	if (!$use_locals) {
	    return;
	}
	$convert{$ref_func} = 1;
    }

    # Loop through all the mcount caller offsets and print a reference
    # to the caller based from the ref_func.
    for (my $i=0; $i <= $#offsets; $i++) {
	if (!$opened) {
	    open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
	    $opened = 1;
	    print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	    print FILE "\t.align $alignment\n" if (defined($alignment));
	}
	printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
    }
}

#
# Step 2: find the sections and mcount call sites
#
open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";

my $text;

while (<IN>) {
    # is it a section?
    if (/$section_regex/) {

	# Only record text sections that we know are safe
	if (defined($text_sections{$1})) {
	    $read_function = 1;
	} else {
	    $read_function = 0;
	}
	# print out any recorded offsets
	update_funcs() if ($text_found);

	# reset all markers and arrays
	$text_found = 0;
	undef($ref_func);
	undef(@offsets);

    # section found, now is this a start of a function?
    } elsif ($read_function && /$function_regex/) {
	$text_found = 1;
	$offset = hex $1;
	$text = $2;

	# if this is either a local function or a weak function
	# keep looking for functions that are global that
	# we can use safely.
	if (!defined($locals{$text}) && !defined($weak{$text})) {
	    $ref_func = $text;
	    $read_function = 0;
	} else {
	    # if we already have a function, and this is weak, skip it
	    if (!defined($ref_func) || !defined($weak{$text})) {
		$ref_func = $text;
	    }
	}
    }

    # is this a call site to mcount? If so, record it to print later
    if ($text_found && /$mcount_regex/) {
	$offsets[$#offsets + 1] = hex $1;
    }
}

# dump out anymore offsets that may have been found
update_funcs() if ($text_found);

# If we did not find any mcount callers, we are done (do nothing).
if (!$opened) {
    exit(0);
}

close(FILE);

#
# Step 3: Compile the file that holds the list of call sites to mcount.
#
`$cc -o $mcount_o -c $mcount_s`;

my @converts = keys %convert;

#
# Step 4: Do we have sections that started with local functions?
#
if ($#converts >= 0) {
    my $globallist = "";
    my $locallist = "";

    foreach my $con (@converts) {
	$globallist .= " --globalize-symbol $con";
	$locallist .= " --localize-symbol $con";
    }

    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
    my $globalmix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 5: set up each local function as a global
    #
    `$objcopy $globallist $inputfile $globalobj`;

    #
    # Step 6: Link the global version to our list.
    #
    `$ld -r $globalobj $mcount_o -o $globalmix`;

    #
    # Step 7: Convert the local functions back into local symbols
    #
    `$objcopy $locallist $globalmix $inputfile`;

    # Remove the temp files
    `$rm $globalobj $globalmix`;

} else {

    my $mix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 8: Link the object with our list of call sites object.
    #
    `$ld -r $inputfile $mcount_o -o $mix`;

    #
    # Step 9: Move the result back to the original object.
    #
    `$mv $mix $inputfile`;
}

# Clean up the temp files
`$rm $mcount_o $mcount_s`;

exit(0);
Commit	Line	Data
8da3821b SR	1	#!/usr/bin/perl -w
	2	# (c) 2008, Steven Rostedt <srostedt@redhat.com>
	3	# Licensed under the terms of the GNU GPL License version 2
	4	#
	5	# recordmcount.pl - makes a section called __mcount_loc that holds
	6	# all the offsets to the calls to mcount.
	7	#
	8	#
	9	# What we want to end up with is a section in vmlinux called
	10	# __mcount_loc that contains a list of pointers to all the
	11	# call sites in the kernel that call mcount. Later on boot up, the kernel
	12	# will read this list, save the locations and turn them into nops.
	13	# When tracing or profiling is later enabled, these locations will then
	14	# be converted back to pointers to some function.
	15	#
	16	# This is no easy feat. This script is called just after the original
	17	# object is compiled and before it is linked.
	18	#
	19	# The references to the call sites are offsets from the section of text
	20	# that the call site is in. Hence, all functions in a section that
	21	# has a call site to mcount, will have the offset from the beginning of
	22	# the section and not the beginning of the function.
	23	#
	24	# The trick is to find a way to record the beginning of the section.
	25	# The way we do this is to look at the first function in the section
	26	# which will also be the location of that section after final link.
	27	# e.g.
	28	#
	29	# .section ".text.sched"
	30	# .globl my_func
	31	# my_func:
	32	# [...]
	33	# call mcount (offset: 0x5)
	34	# [...]
	35	# ret
	36	# other_func:
	37	# [...]
	38	# call mcount (offset: 0x1b)
	39	# [...]
	40	#
	41	# Both relocation offsets for the mcounts in the above example will be
	42	# offset from .text.sched. If we make another file called tmp.s with:
	43	#
	44	# .section __mcount_loc
	45	# .quad my_func + 0x5
	46	# .quad my_func + 0x1b
	47	#
	48	# We can then compile this tmp.s into tmp.o, and link it to the original
	49	# object.
	50	#
	51	# But this gets hard if my_func is not globl (a static function).
	52	# In such a case we have:
	53	#
	54	# .section ".text.sched"
	55	# my_func:
	56	# [...]
	57	# call mcount (offset: 0x5)
	58	# [...]
	59	# ret
	60	# .globl my_func
	61	# other_func:
	62	# [...]
	63	# call mcount (offset: 0x1b)
	64	# [...]
65	#
66	# If we make the tmp.s the same as above, when we link together with
67	# the original object, we will end up with two symbols for my_func:
68	# one local, one global. After final compile, we will end up with
69	# an undefined reference to my_func.
70	#
71	# Since local objects can reference local variables, we need to find
72	# a way to make tmp.o reference the local objects of the original object
73	# file after it is linked together. To do this, we convert the my_func
74	# into a global symbol before linking tmp.o. Then after we link tmp.o
75	# we will only have a single symbol for my_func that is global.
76	# We can convert my_func back into a local symbol and we are done.
77	#
78	# Here are the steps we take:
79	#
80	# 1) Record all the local symbols by using 'nm'
81	# 2) Use objdump to find all the call site offsets and sections for
82	# mcount.
83	# 3) Compile the list into its own object.
84	# 4) Do we have to deal with local functions? If not, go to step 8.
85	# 5) Make an object that converts these local functions to global symbols
86	# with objcopy.
87	# 6) Link together this new object with the list object.
88	# 7) Convert the local functions back to local symbols and rename
89	# the result as the original object.
90	# End.
91	# 8) Link the object with the list object.
92	# 9) Move the result back to the original object.
93	# End.
94	#
95
96	use strict;
97
98	my $P = $0;
99	$P =~ s@.*/@@g;
100
101	my $V = '0.1';
102
18c167fd SL	103	if ($#ARGV < 7) {
18c167fd SL	104	print "usage: $P arch objdump objcopy cc ld nm rm mv is_module inputfile\n";
8da3821b SR	105	print "version: $V\n";
	106	exit(1);
	107	}
	108
dce9d18a	109	my ($arch, $bits, $objdump, $objcopy, $cc,
18c167fd	110	$ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
8da3821b	111
25aac9dc SL	112	# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
	113	if ($inputfile eq "kernel/trace/ftrace.o") {
	114	exit(0);
	115	}
	116
34698bcb SR	117	# Acceptable sections to record.
	118	my %text_sections = (
	119	".text" => 1,
d144d5ee LW	120	".sched.text" => 1,
d144d5ee LW	121	".spinlock.text" => 1,
a0343e82	122	".irqentry.text" => 1,
34698bcb SR	123	);
34698bcb SR	124
8da3821b SR	125	$objdump = "objdump" if ((length $objdump) == 0);
	126	$objcopy = "objcopy" if ((length $objcopy) == 0);
	127	$cc = "gcc" if ((length $cc) == 0);
	128	$ld = "ld" if ((length $ld) == 0);
	129	$nm = "nm" if ((length $nm) == 0);
	130	$rm = "rm" if ((length $rm) == 0);
	131	$mv = "mv" if ((length $mv) == 0);
	132
	133	#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
	134	# "'$nm' '$rm' '$mv' '$inputfile'\n";
	135
8feff1ca SR	136	my %locals; # List of local (static) functions
	137	my %weak; # List of weak functions
	138	my %convert; # List of local functions used that needs conversion
8da3821b SR	139
8da3821b SR	140	my $type;
42e007d0	141	my $nm_regex; # Find the local functions (return function)
8da3821b	142	my $section_regex; # Find the start of a section
8feff1ca SR	143	my $function_regex; # Find the name of a function
8feff1ca SR	144	# (return offset and func name)
8da3821b	145	my $mcount_regex; # Find the call site to mcount (return offset)
3a3d04ae	146	my $alignment; # The .align value to use for $mcount_section
e58918ab	147	my $section_type; # Section header plus possible alignment command
8da3821b	148
dce9d18a SR	149	if ($arch eq "x86") {
	150	if ($bits == 64) {
	151	$arch = "x86_64";
	152	} else {
	153	$arch = "i386";
	154	}
	155	}
	156
c204f726 SR	157	#
	158	# We base the defaults off of i386, the other archs may
	159	# feel free to change them in the below if statements.
	160	#
	161	$nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
	162	$section_regex = "Disassembly of section\\s+(\\S+):";
	163	$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
	164	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount\$";
e58918ab	165	$section_type = '@progbits';
c204f726 SR	166	$type = ".long";
c204f726 SR	167
8da3821b	168	if ($arch eq "x86_64") {
8da3821b SR	169	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
8da3821b SR	170	$type = ".quad";
7d5222a6	171	$alignment = 8;
d74fcd1e SR	172
	173	# force flags for this arch
	174	$ld .= " -m elf_x86_64";
	175	$objdump .= " -M x86-64";
	176	$objcopy .= " -O elf64-x86-64";
	177	$cc .= " -m64";
	178
8da3821b	179	} elsif ($arch eq "i386") {
7d5222a6	180	$alignment = 4;
d74fcd1e SR	181
	182	# force flags for this arch
	183	$ld .= " -m elf_i386";
	184	$objdump .= " -M i386";
	185	$objcopy .= " -O elf32-i386";
	186	$cc .= " -m32";
	187
0da85c09	188	} elsif ($arch eq "sh") {
3a3d04ae	189	$alignment = 2;
0da85c09 MF	190
	191	# force flags for this arch
	192	$ld .= " -m shlelf_linux";
	193	$objcopy .= " -O elf32-sh-linux";
	194	$cc .= " -m32";
	195
42e007d0 SR	196	} elsif ($arch eq "powerpc") {
42e007d0 SR	197	$nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
42e007d0 SR	198	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
42e007d0 SR	199	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s\\.?_mcount\$";
c204f726	200
42e007d0 SR	201	if ($bits == 64) {
42e007d0 SR	202	$type = ".quad";
42e007d0 SR	203	}
42e007d0 SR	204
e58918ab JR	205	} elsif ($arch eq "arm") {
	206	$alignment = 2;
	207	$section_type = '%progbits';
	208
418071eb SL	209	} elsif ($arch eq "ia64") {
	210	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	211	$type = "data8";
	212
	213	if ($is_module eq "0") {
	214	$cc .= " -mconstant-gp";
	215	}
8da3821b SR	216	} else {
	217	die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
	218	}
	219
	220	my $text_found = 0;
	221	my $read_function = 0;
	222	my $opened = 0;
8da3821b SR	223	my $mcount_section = "__mcount_loc";
	224
	225	my $dirname;
	226	my $filename;
	227	my $prefix;
	228	my $ext;
	229
	230	if ($inputfile =~ m,^(.)/([^/])$,) {
	231	$dirname = $1;
	232	$filename = $2;
	233	} else {
	234	$dirname = ".";
	235	$filename = $inputfile;
	236	}
	237
	238	if ($filename =~ m,^(.*)(\.\S),) {
	239	$prefix = $1;
	240	$ext = $2;
	241	} else {
	242	$prefix = $filename;
	243	$ext = "";
	244	}
	245
	246	my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
	247	my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
	248
f2f8458e SR	249	#
	250	# --globalize-symbols came out in 2.17, we must test the version
	251	# of objcopy, and if it is less than 2.17, then we can not
	252	# record local functions.
	253	my $use_locals = 01;
	254	my $local_warn_once = 0;
	255	my $found_version = 0;
	256
	257	open (IN, "$objcopy --version \|") \|\| die "error running $objcopy";
	258	while (<IN>) {
	259	if (/objcopy.*\s(\d+)\.(\d+)/) {
	260	my $major = $1;
	261	my $minor = $2;
	262
	263	$found_version = 1;
	264	if ($major < 2 \|\|
	265	($major == 2 && $minor < 17)) {
	266	$use_locals = 0;
	267	}
	268	last;
	269	}
	270	}
	271	close (IN);
	272
	273	if (!$found_version) {
	274	print STDERR "WARNING: could not find objcopy version.\n" .
	275	"\tDisabling local function references.\n";
	276	}
	277
	278
8da3821b	279	#
8feff1ca SR	280	# Step 1: find all the local (static functions) and weak symbols.
8feff1ca SR	281	# 't' is local, 'w/W' is weak (we never use a weak function)
8da3821b SR	282	#
	283	open (IN, "$nm $inputfile\|") \|\| die "error running $nm";
	284	while (<IN>) {
42e007d0	285	if (/$nm_regex/) {
8da3821b	286	$locals{$1} = 1;
8feff1ca SR	287	} elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
8feff1ca SR	288	$weak{$2} = $1;
8da3821b SR	289	}
	290	}
	291	close(IN);
	292
8feff1ca SR	293	my @offsets; # Array of offsets of mcount callers
	294	my $ref_func; # reference function to use for offsets
	295	my $offset = 0; # offset of ref_func to section beginning
	296
	297	##
	298	# update_funcs - print out the current mcount callers
	299	#
	300	# Go through the list of offsets to callers and write them to
	301	# the output file in a format that can be read by an assembler.
	302	#
	303	sub update_funcs
	304	{
	305	return if ($#offsets < 0);
	306
	307	defined($ref_func) \|\| die "No function to reference";
	308
	309	# A section only had a weak function, to represent it.
	310	# Unfortunately, a weak function may be overwritten by another
	311	# function of the same name, making all these offsets incorrect.
	312	# To be safe, we simply print a warning and bail.
	313	if (defined $weak{$ref_func}) {
	314	print STDERR
	315	"$inputfile: WARNING: referencing weak function" .
	316	" $ref_func for mcount\n";
	317	return;
	318	}
	319
	320	# is this function static? If so, note this fact.
	321	if (defined $locals{$ref_func}) {
f2f8458e SR	322
	323	# only use locals if objcopy supports globalize-symbols
	324	if (!$use_locals) {
f2f8458e SR	325	return;
f2f8458e SR	326	}
8feff1ca SR	327	$convert{$ref_func} = 1;
	328	}
	329
	330	# Loop through all the mcount caller offsets and print a reference
	331	# to the caller based from the ref_func.
	332	for (my $i=0; $i <= $#offsets; $i++) {
	333	if (!$opened) {
	334	open(FILE, ">$mcount_s") \|\| die "can't create $mcount_s\n";
	335	$opened = 1;
e58918ab	336	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
42e007d0	337	print FILE "\t.align $alignment\n" if (defined($alignment));
8feff1ca SR	338	}
	339	printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
	340	}
	341	}
	342
8da3821b SR	343	#
	344	# Step 2: find the sections and mcount call sites
	345	#
	346	open(IN, "$objdump -dr $inputfile\|") \|\| die "error running $objdump";
	347
8feff1ca SR	348	my $text;
8feff1ca SR	349
8da3821b SR	350	while (<IN>) {
	351	# is it a section?
	352	if (/$section_regex/) {
34698bcb SR	353
	354	# Only record text sections that we know are safe
	355	if (defined($text_sections{$1})) {
	356	$read_function = 1;
	357	} else {
	358	$read_function = 0;
	359	}
8feff1ca SR	360	# print out any recorded offsets
	361	update_funcs() if ($text_found);
	362
	363	# reset all markers and arrays
8da3821b	364	$text_found = 0;
8feff1ca SR	365	undef($ref_func);
	366	undef(@offsets);
	367
8da3821b SR	368	# section found, now is this a start of a function?
8da3821b SR	369	} elsif ($read_function && /$function_regex/) {
8da3821b	370	$text_found = 1;
8feff1ca SR	371	$offset = hex $1;
	372	$text = $2;
	373
	374	# if this is either a local function or a weak function
	375	# keep looking for functions that are global that
	376	# we can use safely.
	377	if (!defined($locals{$text}) && !defined($weak{$text})) {
	378	$ref_func = $text;
	379	$read_function = 0;
	380	} else {
	381	# if we already have a function, and this is weak, skip it
	382	if (!defined($ref_func) \|\| !defined($weak{$text})) {
	383	$ref_func = $text;
	384	}
8da3821b	385	}
8feff1ca SR	386	}
	387
	388	# is this a call site to mcount? If so, record it to print later
	389	if ($text_found && /$mcount_regex/) {
	390	$offsets[$#offsets + 1] = hex $1;
8da3821b SR	391	}
	392	}
	393
8feff1ca SR	394	# dump out anymore offsets that may have been found
	395	update_funcs() if ($text_found);
	396
8da3821b SR	397	# If we did not find any mcount callers, we are done (do nothing).
	398	if (!$opened) {
	399	exit(0);
	400	}
	401
	402	close(FILE);
	403
	404	#
	405	# Step 3: Compile the file that holds the list of call sites to mcount.
	406	#
	407	`$cc -o $mcount_o -c $mcount_s`;
	408
	409	my @converts = keys %convert;
	410
	411	#
	412	# Step 4: Do we have sections that started with local functions?
	413	#
	414	if ($#converts >= 0) {
	415	my $globallist = "";
	416	my $locallist = "";
	417
	418	foreach my $con (@converts) {
	419	$globallist .= " --globalize-symbol $con";
	420	$locallist .= " --localize-symbol $con";
	421	}
	422
	423	my $globalobj = $dirname . "/.tmp_gl_" . $filename;
	424	my $globalmix = $dirname . "/.tmp_mx_" . $filename;
	425
	426	#
	427	# Step 5: set up each local function as a global
	428	#
	429	`$objcopy $globallist $inputfile $globalobj`;
	430
	431	#
	432	# Step 6: Link the global version to our list.
	433	#
	434	`$ld -r $globalobj $mcount_o -o $globalmix`;
	435
	436	#
	437	# Step 7: Convert the local functions back into local symbols
	438	#
	439	`$objcopy $locallist $globalmix $inputfile`;
	440
	441	# Remove the temp files
	442	`$rm $globalobj $globalmix`;
	443
	444	} else {
	445
	446	my $mix = $dirname . "/.tmp_mx_" . $filename;
	447
	448	#
	449	# Step 8: Link the object with our list of call sites object.
	450	#
	451	`$ld -r $inputfile $mcount_o -o $mix`;
	452
	453	#
	454	# Step 9: Move the result back to the original object.
	455	#
	456	`$mv $mix $inputfile`;
	457	}
	458
	459	# Clean up the temp files
	460	`$rm $mcount_o $mcount_s`;
461
462	exit(0);