[net-next-2.6.git] / scripts / recordmcount.pl

#!/usr/bin/perl -w
# (c) 2008, Steven Rostedt <srostedt@redhat.com>
# Licensed under the terms of the GNU GPL License version 2
#
# recordmcount.pl - makes a section called __mcount_loc that holds
#                   all the offsets to the calls to mcount.
#
#
# What we want to end up with this is that each object file will have a
# section called __mcount_loc that will hold the list of pointers to mcount
# callers. After final linking, the vmlinux will have within .init.data the
# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
# Later on boot up, the kernel will read this list, save the locations and turn
# them into nops. When tracing or profiling is later enabled, these locations
# will then be converted back to pointers to some function.
#
# This is no easy feat. This script is called just after the original
# object is compiled and before it is linked.
#
# When parse this object file using 'objdump', the references to the call
# sites are offsets from the section that the call site is in. Hence, all
# functions in a section that has a call site to mcount, will have the
# offset from the beginning of the section and not the beginning of the
# function.
#
# But where this section will reside finally in vmlinx is undetermined at
# this point. So we can't use this kind of offsets to record the final
# address of this call site.
#
# The trick is to change the call offset referring the start of a section to
# referring a function symbol in this section. During the link step, 'ld' will
# compute the final address according to the information we record.
#
# e.g.
#
#  .section ".sched.text", "ax"
#        [...]
#  func1:
#        [...]
#        call mcount  (offset: 0x10)
#        [...]
#        ret
#  .globl fun2
#  func2:             (offset: 0x20)
#        [...]
#        [...]
#        ret
#  func3:
#        [...]
#        call mcount (offset: 0x30)
#        [...]
#
# Both relocation offsets for the mcounts in the above example will be
# offset from .sched.text. If we choose global symbol func2 as a reference and
# make another file called tmp.s with the new offsets:
#
#  .section __mcount_loc
#  .quad  func2 - 0x10
#  .quad  func2 + 0x10
#
# We can then compile this tmp.s into tmp.o, and link it back to the original
# object.
#
# In our algorithm, we will choose the first global function we meet in this
# section as the reference. But this gets hard if there is no global functions
# in this section. In such a case we have to select a local one. E.g. func1:
#
#  .section ".sched.text", "ax"
#  func1:
#        [...]
#        call mcount  (offset: 0x10)
#        [...]
#        ret
#  func2:
#        [...]
#        call mcount (offset: 0x20)
#        [...]
#  .section "other.section"
#
# If we make the tmp.s the same as above, when we link together with
# the original object, we will end up with two symbols for func1:
# one local, one global.  After final compile, we will end up with
# an undefined reference to func1 or a wrong reference to another global
# func1 in other files.
#
# Since local objects can reference local variables, we need to find
# a way to make tmp.o reference the local objects of the original object
# file after it is linked together. To do this, we convert func1
# into a global symbol before linking tmp.o. Then after we link tmp.o
# we will only have a single symbol for func1 that is global.
# We can convert func1 back into a local symbol and we are done.
#
# Here are the steps we take:
#
# 1) Record all the local and weak symbols by using 'nm'
# 2) Use objdump to find all the call site offsets and sections for
#    mcount.
# 3) Compile the list into its own object.
# 4) Do we have to deal with local functions? If not, go to step 8.
# 5) Make an object that converts these local functions to global symbols
#    with objcopy.
# 6) Link together this new object with the list object.
# 7) Convert the local functions back to local symbols and rename
#    the result as the original object.
# 8) Link the object with the list object.
# 9) Move the result back to the original object.
#

use strict;

my $P = $0;
$P =~ s@.*/@@g;

my $V = '0.1';

if ($#ARGV != 11) {
	print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
	print "version: $V\n";
	exit(1);
}

my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
    $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;

# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
    exit(0);
}

# Acceptable sections to record.
my %text_sections = (
     ".text" => 1,
     ".sched.text" => 1,
     ".spinlock.text" => 1,
     ".irqentry.text" => 1,
     ".text.unlikely" => 1,
);

# Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
$objdump = 'objdump' if (!$objdump);
$objcopy = 'objcopy' if (!$objcopy);
$cc = 'gcc' if (!$cc);
$ld = 'ld' if (!$ld);
$nm = 'nm' if (!$nm);
$rm = 'rm' if (!$rm);
$mv = 'mv' if (!$mv);

#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
#    "'$nm' '$rm' '$mv' '$inputfile'\n";

my %locals;		# List of local (static) functions
my %weak;		# List of weak functions
my %convert;		# List of local functions used that needs conversion

my $type;
my $local_regex;	# Match a local function (return function)
my $weak_regex; 	# Match a weak function (return function)
my $section_regex;	# Find the start of a section
my $function_regex;	# Find the name of a function
			#    (return offset and func name)
my $mcount_regex;	# Find the call site to mcount (return offset)
my $alignment;		# The .align value to use for $mcount_section
my $section_type;	# Section header plus possible alignment command
my $can_use_local = 0; 	# If we can use local function references

# Shut up recordmcount if user has older objcopy
my $quiet_recordmcount = ".tmp_quiet_recordmcount";
my $print_warning = 1;
$print_warning = 0 if ( -f $quiet_recordmcount);

##
# check_objcopy - whether objcopy supports --globalize-symbols
#
#  --globalize-symbols came out in 2.17, we must test the version
#  of objcopy, and if it is less than 2.17, then we can not
#  record local functions.
sub check_objcopy
{
    open (IN, "$objcopy --version |") or die "error running $objcopy";
    while (<IN>) {
	if (/objcopy.*\s(\d+)\.(\d+)/) {
	    $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
	    last;
	}
    }
    close (IN);

    if (!$can_use_local && $print_warning) {
	print STDERR "WARNING: could not find objcopy version or version " .
	    "is less than 2.17.\n" .
	    "\tLocal function references are disabled.\n";
	open (QUIET, ">$quiet_recordmcount");
	printf QUIET "Disables the warning from recordmcount.pl\n";
	close QUIET;
    }
}

if ($arch =~ /(x86(_64)?)|(i386)/) {
    if ($bits == 64) {
	$arch = "x86_64";
    } else {
	$arch = "i386";
    }
}

#
# We base the defaults off of i386, the other archs may
# feel free to change them in the below if statements.
#
$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
$section_regex = "Disassembly of section\\s+(\\S+):";
$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
$section_type = '@progbits';
$type = ".long";

if ($arch eq "x86_64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
    $type = ".quad";
    $alignment = 8;

    # force flags for this arch
    $ld .= " -m elf_x86_64";
    $objdump .= " -M x86-64";
    $objcopy .= " -O elf64-x86-64";
    $cc .= " -m64";

} elsif ($arch eq "i386") {
    $alignment = 4;

    # force flags for this arch
    $ld .= " -m elf_i386";
    $objdump .= " -M i386";
    $objcopy .= " -O elf32-i386";
    $cc .= " -m32";

} elsif ($arch eq "s390" && $bits == 32) {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
    $alignment = 4;
    $ld .= " -m elf_s390";
    $cc .= " -m31";

} elsif ($arch eq "s390" && $bits == 64) {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
    $alignment = 8;
    $type = ".quad";
    $ld .= " -m elf64_s390";
    $cc .= " -m64";

} elsif ($arch eq "sh") {
    $alignment = 2;

    # force flags for this arch
    $ld .= " -m shlelf_linux";
    $objcopy .= " -O elf32-sh-linux";
    $cc .= " -m32";

} elsif ($arch eq "powerpc") {
    $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";

    if ($bits == 64) {
	$type = ".quad";
    }

} elsif ($arch eq "arm") {
    $alignment = 2;
    $section_type = '%progbits';

} elsif ($arch eq "ia64") {
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
    $type = "data8";

    if ($is_module eq "0") {
        $cc .= " -mconstant-gp";
    }
} elsif ($arch eq "sparc64") {
    # In the objdump output there are giblets like:
    # 0000000000000000 <igmp_net_exit-0x18>:
    # As there's some data blobs that get emitted into the
    # text section before the first instructions and the first
    # real symbols.  We don't want to match that, so to combat
    # this we use '\w' so we'll match just plain symbol names,
    # and not those that also include hex offsets inside of the
    # '<>' brackets.  Actually the generic function_regex setting
    # could safely use this too.
    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";

    # Sparc64 calls '_mcount' instead of plain 'mcount'.
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";

    $alignment = 8;
    $type = ".xword";
    $ld .= " -m elf64_sparc";
    $cc .= " -m64";
    $objcopy .= " -O elf64-sparc";
} elsif ($arch eq "mips") {
    # To enable module support, we need to enable the -mlong-calls option
    # of gcc for module, after using this option, we can not get the real
    # offset of the calling to _mcount, but the offset of the lui
    # instruction or the addiu one. herein, we record the address of the
    # first one, and then we can replace this instruction by a branch
    # instruction to jump over the profiling function to filter the
    # indicated functions, or swith back to the lui instruction to trace
    # them, which means dynamic tracing.
    #
    #       c:	3c030000 	lui	v1,0x0
    #			c: R_MIPS_HI16	_mcount
    #			c: R_MIPS_NONE	*ABS*
    #			c: R_MIPS_NONE	*ABS*
    #      10:	64630000 	daddiu	v1,v1,0
    #			10: R_MIPS_LO16	_mcount
    #			10: R_MIPS_NONE	*ABS*
    #			10: R_MIPS_NONE	*ABS*
    #      14:	03e0082d 	move	at,ra
    #      18:	0060f809 	jalr	v1
    #
    # for the kernel:
    #
    #     10:   03e0082d        move    at,ra
    #	  14:   0c000000        jal     0 <loongson_halt>
    #                    14: R_MIPS_26   _mcount
    #                    14: R_MIPS_NONE *ABS*
    #                    14: R_MIPS_NONE *ABS*
    #	 18:   00020021        nop
    if ($is_module eq "0") {
	    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
    } else {
	    $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
    }
    $objdump .= " -Melf-trad".$endian."mips ";

    if ($endian eq "big") {
	    $endian = " -EB ";
	    $ld .= " -melf".$bits."btsmip";
    } else {
	    $endian = " -EL ";
	    $ld .= " -melf".$bits."ltsmip";
    }

    $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
    $ld .= $endian;

    if ($bits == 64) {
	    $function_regex =
		"^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
	    $type = ".dword";
    }
} elsif ($arch eq "microblaze") {
    # Microblaze calls '_mcount' instead of plain 'mcount'.
    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
} else {
    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
}

my $text_found = 0;
my $read_function = 0;
my $opened = 0;
my $mcount_section = "__mcount_loc";

my $dirname;
my $filename;
my $prefix;
my $ext;

if ($inputfile =~ m,^(.*)/([^/]*)$,) {
    $dirname = $1;
    $filename = $2;
} else {
    $dirname = ".";
    $filename = $inputfile;
}

if ($filename =~ m,^(.*)(\.\S),) {
    $prefix = $1;
    $ext = $2;
} else {
    $prefix = $filename;
    $ext = "";
}

my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";

check_objcopy();

#
# Step 1: find all the local (static functions) and weak symbols.
#         't' is local, 'w/W' is weak
#
open (IN, "$nm $inputfile|") || die "error running $nm";
while (<IN>) {
    if (/$local_regex/) {
	$locals{$1} = 1;
    } elsif (/$weak_regex/) {
	$weak{$2} = $1;
    }
}
close(IN);

my @offsets;		# Array of offsets of mcount callers
my $ref_func;		# reference function to use for offsets
my $offset = 0;		# offset of ref_func to section beginning

##
# update_funcs - print out the current mcount callers
#
#  Go through the list of offsets to callers and write them to
#  the output file in a format that can be read by an assembler.
#
sub update_funcs
{
    return unless ($ref_func and @offsets);

    # Sanity check on weak function. A weak function may be overwritten by
    # another function of the same name, making all these offsets incorrect.
    if (defined $weak{$ref_func}) {
	die "$inputfile: ERROR: referencing weak function" .
	    " $ref_func for mcount\n";
    }

    # is this function static? If so, note this fact.
    if (defined $locals{$ref_func}) {

	# only use locals if objcopy supports globalize-symbols
	if (!$can_use_local) {
	    return;
	}
	$convert{$ref_func} = 1;
    }

    # Loop through all the mcount caller offsets and print a reference
    # to the caller based from the ref_func.
    if (!$opened) {
	open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
	$opened = 1;
	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	print FILE "\t.align $alignment\n" if (defined($alignment));
    }
    foreach my $cur_offset (@offsets) {
	printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
    }
}

#
# Step 2: find the sections and mcount call sites
#
open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";

my $text;


# read headers first
my $read_headers = 1;

while (<IN>) {

    if ($read_headers && /$mcount_section/) {
	#
	# Somehow the make process can execute this script on an
	# object twice. If it does, we would duplicate the mcount
	# section and it will cause the function tracer self test
	# to fail. Check if the mcount section exists, and if it does,
	# warn and exit.
	#
	print STDERR "ERROR: $mcount_section already in $inputfile\n" .
	    "\tThis may be an indication that your build is corrupted.\n" .
	    "\tDelete $inputfile and try again. If the same object file\n" .
	    "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
	exit(-1);
    }

    # is it a section?
    if (/$section_regex/) {
	$read_headers = 0;

	# Only record text sections that we know are safe
	$read_function = defined($text_sections{$1});
	# print out any recorded offsets
	update_funcs();

	# reset all markers and arrays
	$text_found = 0;
	undef($ref_func);
	undef(@offsets);

    # section found, now is this a start of a function?
    } elsif ($read_function && /$function_regex/) {
	$text_found = 1;
	$text = $2;

	# if this is either a local function or a weak function
	# keep looking for functions that are global that
	# we can use safely.
	if (!defined($locals{$text}) && !defined($weak{$text})) {
	    $ref_func = $text;
	    $read_function = 0;
	    $offset = hex $1;
	} else {
	    # if we already have a function, and this is weak, skip it
	    if (!defined($ref_func) && !defined($weak{$text}) &&
		 # PPC64 can have symbols that start with .L and
		 # gcc considers these special. Don't use them!
		 $text !~ /^\.L/) {
		$ref_func = $text;
		$offset = hex $1;
	    }
	}
    }
    # is this a call site to mcount? If so, record it to print later
    if ($text_found && /$mcount_regex/) {
	push(@offsets, hex $1);
    }
}

# dump out anymore offsets that may have been found
update_funcs();

# If we did not find any mcount callers, we are done (do nothing).
if (!$opened) {
    exit(0);
}

close(FILE);

#
# Step 3: Compile the file that holds the list of call sites to mcount.
#
`$cc -o $mcount_o -c $mcount_s`;

my @converts = keys %convert;

#
# Step 4: Do we have sections that started with local functions?
#
if ($#converts >= 0) {
    my $globallist = "";
    my $locallist = "";

    foreach my $con (@converts) {
	$globallist .= " --globalize-symbol $con";
	$locallist .= " --localize-symbol $con";
    }

    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
    my $globalmix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 5: set up each local function as a global
    #
    `$objcopy $globallist $inputfile $globalobj`;

    #
    # Step 6: Link the global version to our list.
    #
    `$ld -r $globalobj $mcount_o -o $globalmix`;

    #
    # Step 7: Convert the local functions back into local symbols
    #
    `$objcopy $locallist $globalmix $inputfile`;

    # Remove the temp files
    `$rm $globalobj $globalmix`;

} else {

    my $mix = $dirname . "/.tmp_mx_" . $filename;

    #
    # Step 8: Link the object with our list of call sites object.
    #
    `$ld -r $inputfile $mcount_o -o $mix`;

    #
    # Step 9: Move the result back to the original object.
    #
    `$mv $mix $inputfile`;
}

# Clean up the temp files
`$rm $mcount_o $mcount_s`;

exit(0);
Commit	Line	Data
8da3821b SR	1	#!/usr/bin/perl -w
	2	# (c) 2008, Steven Rostedt <srostedt@redhat.com>
	3	# Licensed under the terms of the GNU GPL License version 2
	4	#
	5	# recordmcount.pl - makes a section called __mcount_loc that holds
	6	# all the offsets to the calls to mcount.
	7	#
	8	#
d49f6aa7 LH	9	# What we want to end up with this is that each object file will have a
	10	# section called __mcount_loc that will hold the list of pointers to mcount
	11	# callers. After final linking, the vmlinux will have within .init.data the
	12	# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
	13	# Later on boot up, the kernel will read this list, save the locations and turn
	14	# them into nops. When tracing or profiling is later enabled, these locations
	15	# will then be converted back to pointers to some function.
8da3821b SR	16	#
	17	# This is no easy feat. This script is called just after the original
	18	# object is compiled and before it is linked.
	19	#
d49f6aa7 LH	20	# When parse this object file using 'objdump', the references to the call
	21	# sites are offsets from the section that the call site is in. Hence, all
	22	# functions in a section that has a call site to mcount, will have the
	23	# offset from the beginning of the section and not the beginning of the
	24	# function.
	25	#
	26	# But where this section will reside finally in vmlinx is undetermined at
	27	# this point. So we can't use this kind of offsets to record the final
	28	# address of this call site.
	29	#
	30	# The trick is to change the call offset referring the start of a section to
	31	# referring a function symbol in this section. During the link step, 'ld' will
	32	# compute the final address according to the information we record.
8da3821b	33	#
8da3821b SR	34	# e.g.
8da3821b SR	35	#
31b6e76e	36	# .section ".sched.text", "ax"
8da3821b	37	# [...]
d49f6aa7 LH	38	# func1:
	39	# [...]
	40	# call mcount (offset: 0x10)
	41	# [...]
	42	# ret
	43	# .globl fun2
	44	# func2: (offset: 0x20)
	45	# [...]
8da3821b SR	46	# [...]
8da3821b SR	47	# ret
d49f6aa7	48	# func3:
8da3821b	49	# [...]
d49f6aa7	50	# call mcount (offset: 0x30)
8da3821b SR	51	# [...]
	52	#
	53	# Both relocation offsets for the mcounts in the above example will be
d49f6aa7 LH	54	# offset from .sched.text. If we choose global symbol func2 as a reference and
d49f6aa7 LH	55	# make another file called tmp.s with the new offsets:
8da3821b SR	56	#
8da3821b SR	57	# .section __mcount_loc
d49f6aa7 LH	58	# .quad func2 - 0x10
d49f6aa7 LH	59	# .quad func2 + 0x10
8da3821b	60	#
d49f6aa7	61	# We can then compile this tmp.s into tmp.o, and link it back to the original
8da3821b SR	62	# object.
8da3821b SR	63	#
d49f6aa7 LH	64	# In our algorithm, we will choose the first global function we meet in this
	65	# section as the reference. But this gets hard if there is no global functions
	66	# in this section. In such a case we have to select a local one. E.g. func1:
8da3821b	67	#
31b6e76e	68	# .section ".sched.text", "ax"
d49f6aa7	69	# func1:
8da3821b	70	# [...]
d49f6aa7	71	# call mcount (offset: 0x10)
8da3821b SR	72	# [...]
8da3821b SR	73	# ret
d49f6aa7	74	# func2:
8da3821b	75	# [...]
d49f6aa7	76	# call mcount (offset: 0x20)
8da3821b	77	# [...]
d49f6aa7	78	# .section "other.section"
8da3821b SR	79	#
8da3821b SR	80	# If we make the tmp.s the same as above, when we link together with
d49f6aa7	81	# the original object, we will end up with two symbols for func1:
8da3821b	82	# one local, one global. After final compile, we will end up with
d49f6aa7 LH	83	# an undefined reference to func1 or a wrong reference to another global
d49f6aa7 LH	84	# func1 in other files.
8da3821b SR	85	#
	86	# Since local objects can reference local variables, we need to find
	87	# a way to make tmp.o reference the local objects of the original object
d49f6aa7	88	# file after it is linked together. To do this, we convert func1
8da3821b	89	# into a global symbol before linking tmp.o. Then after we link tmp.o
d49f6aa7 LH	90	# we will only have a single symbol for func1 that is global.
d49f6aa7 LH	91	# We can convert func1 back into a local symbol and we are done.
8da3821b SR	92	#
	93	# Here are the steps we take:
	94	#
306dcf47	95	# 1) Record all the local and weak symbols by using 'nm'
8da3821b SR	96	# 2) Use objdump to find all the call site offsets and sections for
	97	# mcount.
	98	# 3) Compile the list into its own object.
	99	# 4) Do we have to deal with local functions? If not, go to step 8.
	100	# 5) Make an object that converts these local functions to global symbols
	101	# with objcopy.
	102	# 6) Link together this new object with the list object.
	103	# 7) Convert the local functions back to local symbols and rename
	104	# the result as the original object.
8da3821b SR	105	# 8) Link the object with the list object.
8da3821b SR	106	# 9) Move the result back to the original object.
8da3821b SR	107	#
	108
	109	use strict;
	110
	111	my $P = $0;
	112	$P =~ s@.*/@@g;
	113
	114	my $V = '0.1';
	115
e6299d26 WZ	116	if ($#ARGV != 11) {
e6299d26 WZ	117	print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
8da3821b SR	118	print "version: $V\n";
	119	exit(1);
	120	}
	121
e6299d26	122	my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
18c167fd	123	$ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
8da3821b	124
25aac9dc	125	# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
bdd3b052	126	if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
25aac9dc SL	127	exit(0);
	128	}
	129
34698bcb SR	130	# Acceptable sections to record.
	131	my %text_sections = (
	132	".text" => 1,
d144d5ee LW	133	".sched.text" => 1,
d144d5ee LW	134	".spinlock.text" => 1,
a0343e82	135	".irqentry.text" => 1,
4d828949	136	".text.unlikely" => 1,
34698bcb SR	137	);
34698bcb SR	138
dfaa9e2c WS	139	# Note: we are nice to C-programmers here, thus we skip the '\|\|='-idiom.
	140	$objdump = 'objdump' if (!$objdump);
	141	$objcopy = 'objcopy' if (!$objcopy);
	142	$cc = 'gcc' if (!$cc);
	143	$ld = 'ld' if (!$ld);
	144	$nm = 'nm' if (!$nm);
	145	$rm = 'rm' if (!$rm);
	146	$mv = 'mv' if (!$mv);
8da3821b SR	147
	148	#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
	149	# "'$nm' '$rm' '$mv' '$inputfile'\n";
	150
8feff1ca SR	151	my %locals; # List of local (static) functions
	152	my %weak; # List of weak functions
	153	my %convert; # List of local functions used that needs conversion
8da3821b SR	154
8da3821b SR	155	my $type;
306dcf47 LH	156	my $local_regex; # Match a local function (return function)
306dcf47 LH	157	my $weak_regex; # Match a weak function (return function)
8da3821b	158	my $section_regex; # Find the start of a section
8feff1ca SR	159	my $function_regex; # Find the name of a function
8feff1ca SR	160	# (return offset and func name)
8da3821b	161	my $mcount_regex; # Find the call site to mcount (return offset)
3a3d04ae	162	my $alignment; # The .align value to use for $mcount_section
e58918ab	163	my $section_type; # Section header plus possible alignment command
7b7edc27 LH	164	my $can_use_local = 0; # If we can use local function references
7b7edc27 LH	165
638adb05 SR	166	# Shut up recordmcount if user has older objcopy
	167	my $quiet_recordmcount = ".tmp_quiet_recordmcount";
	168	my $print_warning = 1;
	169	$print_warning = 0 if ( -f $quiet_recordmcount);
	170
7b7edc27 LH	171	##
	172	# check_objcopy - whether objcopy supports --globalize-symbols
	173	#
	174	# --globalize-symbols came out in 2.17, we must test the version
	175	# of objcopy, and if it is less than 2.17, then we can not
	176	# record local functions.
	177	sub check_objcopy
	178	{
	179	open (IN, "$objcopy --version \|") or die "error running $objcopy";
	180	while (<IN>) {
	181	if (/objcopy.*\s(\d+)\.(\d+)/) {
	182	$can_use_local = 1 if ($1 > 2 \|\| ($1 == 2 && $2 >= 17));
	183	last;
	184	}
	185	}
	186	close (IN);
	187
638adb05	188	if (!$can_use_local && $print_warning) {
7b7edc27 LH	189	print STDERR "WARNING: could not find objcopy version or version " .
7b7edc27 LH	190	"is less than 2.17.\n" .
638adb05 SR	191	"\tLocal function references are disabled.\n";
	192	open (QUIET, ">$quiet_recordmcount");
	193	printf QUIET "Disables the warning from recordmcount.pl\n";
	194	close QUIET;
7b7edc27 LH	195	}
7b7edc27 LH	196	}
8da3821b	197
b82a4045	198	if ($arch =~ /(x86(_64)?)\|(i386)/) {
dce9d18a SR	199	if ($bits == 64) {
	200	$arch = "x86_64";
	201	} else {
	202	$arch = "i386";
	203	}
	204	}
	205
c204f726 SR	206	#
	207	# We base the defaults off of i386, the other archs may
	208	# feel free to change them in the below if statements.
	209	#
306dcf47 LH	210	$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
306dcf47 LH	211	$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
c204f726 SR	212	$section_regex = "Disassembly of section\\s+(\\S+):";
	213	$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
	214	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount\$";
e58918ab	215	$section_type = '@progbits';
c204f726 SR	216	$type = ".long";
c204f726 SR	217
8da3821b	218	if ($arch eq "x86_64") {
8da3821b SR	219	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
8da3821b SR	220	$type = ".quad";
7d5222a6	221	$alignment = 8;
d74fcd1e SR	222
	223	# force flags for this arch
	224	$ld .= " -m elf_x86_64";
	225	$objdump .= " -M x86-64";
	226	$objcopy .= " -O elf64-x86-64";
	227	$cc .= " -m64";
	228
8da3821b	229	} elsif ($arch eq "i386") {
7d5222a6	230	$alignment = 4;
d74fcd1e SR	231
	232	# force flags for this arch
	233	$ld .= " -m elf_i386";
	234	$objdump .= " -M i386";
	235	$objcopy .= " -O elf32-i386";
	236	$cc .= " -m32";
	237
dfd9f7ab HC	238	} elsif ($arch eq "s390" && $bits == 32) {
	239	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_390_32\\s+_mcount\$";
	240	$alignment = 4;
	241	$ld .= " -m elf_s390";
	242	$cc .= " -m31";
	243
	244	} elsif ($arch eq "s390" && $bits == 64) {
	245	$mcount_regex = "^\\s([0-9a-fA-F]+):\\sR_390_(PC\|PLT)32DBL\\s+_mcount\\+0x2\$";
	246	$alignment = 8;
	247	$type = ".quad";
	248	$ld .= " -m elf64_s390";
	249	$cc .= " -m64";
	250
0da85c09	251	} elsif ($arch eq "sh") {
3a3d04ae	252	$alignment = 2;
0da85c09 MF	253
	254	# force flags for this arch
	255	$ld .= " -m shlelf_linux";
	256	$objcopy .= " -O elf32-sh-linux";
	257	$cc .= " -m32";
	258
42e007d0	259	} elsif ($arch eq "powerpc") {
306dcf47	260	$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
42e007d0 SR	261	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
42e007d0 SR	262	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s\\.?_mcount\$";
c204f726	263
42e007d0 SR	264	if ($bits == 64) {
42e007d0 SR	265	$type = ".quad";
42e007d0 SR	266	}
42e007d0 SR	267
e58918ab JR	268	} elsif ($arch eq "arm") {
	269	$alignment = 2;
	270	$section_type = '%progbits';
	271
418071eb SL	272	} elsif ($arch eq "ia64") {
	273	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	274	$type = "data8";
	275
	276	if ($is_module eq "0") {
	277	$cc .= " -mconstant-gp";
	278	}
9be12f9b DM	279	} elsif ($arch eq "sparc64") {
	280	# In the objdump output there are giblets like:
	281	# 0000000000000000 <igmp_net_exit-0x18>:
	282	# As there's some data blobs that get emitted into the
	283	# text section before the first instructions and the first
	284	# real symbols. We don't want to match that, so to combat
	285	# this we use '\w' so we'll match just plain symbol names,
	286	# and not those that also include hex offsets inside of the
	287	# '<>' brackets. Actually the generic function_regex setting
	288	# could safely use this too.
	289	$function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
	290
	291	# Sparc64 calls '_mcount' instead of plain 'mcount'.
	292	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	293
	294	$alignment = 8;
	295	$type = ".xword";
	296	$ld .= " -m elf64_sparc";
	297	$cc .= " -m64";
	298	$objcopy .= " -O elf64-sparc";
538f1952 WZ	299	} elsif ($arch eq "mips") {
	300	# To enable module support, we need to enable the -mlong-calls option
	301	# of gcc for module, after using this option, we can not get the real
	302	# offset of the calling to _mcount, but the offset of the lui
	303	# instruction or the addiu one. herein, we record the address of the
	304	# first one, and then we can replace this instruction by a branch
	305	# instruction to jump over the profiling function to filter the
	306	# indicated functions, or swith back to the lui instruction to trace
	307	# them, which means dynamic tracing.
	308	#
	309	# c: 3c030000 lui v1,0x0
	310	# c: R_MIPS_HI16 _mcount
	311	# c: R_MIPS_NONE ABS
	312	# c: R_MIPS_NONE ABS
	313	# 10: 64630000 daddiu v1,v1,0
	314	# 10: R_MIPS_LO16 _mcount
	315	# 10: R_MIPS_NONE ABS
	316	# 10: R_MIPS_NONE ABS
	317	# 14: 03e0082d move at,ra
	318	# 18: 0060f809 jalr v1
	319	#
	320	# for the kernel:
	321	#
	322	# 10: 03e0082d move at,ra
	323	# 14: 0c000000 jal 0 <loongson_halt>
	324	# 14: R_MIPS_26 _mcount
	325	# 14: R_MIPS_NONE ABS
	326	# 14: R_MIPS_NONE ABS
	327	# 18: 00020021 nop
	328	if ($is_module eq "0") {
	329	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
	330	} else {
	331	$mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
	332	}
	333	$objdump .= " -Melf-trad".$endian."mips ";
	334
	335	if ($endian eq "big") {
	336	$endian = " -EB ";
	337	$ld .= " -melf".$bits."btsmip";
	338	} else {
	339	$endian = " -EL ";
	340	$ld .= " -melf".$bits."ltsmip";
	341	}
	342
	343	$cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
	344	$ld .= $endian;
	345
	346	if ($bits == 64) {
	347	$function_regex =
	348	"^([0-9a-fA-F]+)\\s+<(.\|[^\$]L.?\|\$[^L].?\|[^\$][^L].*?)>:";
	349	$type = ".dword";
	350	}
7d241ff0 MS	351	} elsif ($arch eq "microblaze") {
	352	# Microblaze calls '_mcount' instead of plain 'mcount'.
	353	$mcount_regex = "^\\s([0-9a-fA-F]+):.\\s_mcount\$";
8da3821b SR	354	} else {
	355	die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
	356	}
	357
	358	my $text_found = 0;
	359	my $read_function = 0;
	360	my $opened = 0;
8da3821b SR	361	my $mcount_section = "__mcount_loc";
	362
	363	my $dirname;
	364	my $filename;
	365	my $prefix;
	366	my $ext;
	367
	368	if ($inputfile =~ m,^(.)/([^/])$,) {
	369	$dirname = $1;
	370	$filename = $2;
	371	} else {
	372	$dirname = ".";
	373	$filename = $inputfile;
	374	}
	375
	376	if ($filename =~ m,^(.*)(\.\S),) {
	377	$prefix = $1;
	378	$ext = $2;
	379	} else {
	380	$prefix = $filename;
	381	$ext = "";
	382	}
	383
	384	my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
	385	my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
	386
7b7edc27	387	check_objcopy();
f2f8458e	388
8da3821b	389	#
8feff1ca	390	# Step 1: find all the local (static functions) and weak symbols.
306dcf47	391	# 't' is local, 'w/W' is weak
8da3821b SR	392	#
	393	open (IN, "$nm $inputfile\|") \|\| die "error running $nm";
	394	while (<IN>) {
306dcf47	395	if (/$local_regex/) {
8da3821b	396	$locals{$1} = 1;
306dcf47	397	} elsif (/$weak_regex/) {
8feff1ca	398	$weak{$2} = $1;
8da3821b SR	399	}
	400	}
	401	close(IN);
	402
8feff1ca SR	403	my @offsets; # Array of offsets of mcount callers
	404	my $ref_func; # reference function to use for offsets
	405	my $offset = 0; # offset of ref_func to section beginning
	406
	407	##
	408	# update_funcs - print out the current mcount callers
	409	#
	410	# Go through the list of offsets to callers and write them to
	411	# the output file in a format that can be read by an assembler.
	412	#
	413	sub update_funcs
	414	{
6092858c	415	return unless ($ref_func and @offsets);
8feff1ca	416
c4b8ac2c LH	417	# Sanity check on weak function. A weak function may be overwritten by
c4b8ac2c LH	418	# another function of the same name, making all these offsets incorrect.
8feff1ca	419	if (defined $weak{$ref_func}) {
c4b8ac2c	420	die "$inputfile: ERROR: referencing weak function" .
8feff1ca	421	" $ref_func for mcount\n";
8feff1ca SR	422	}
	423
	424	# is this function static? If so, note this fact.
	425	if (defined $locals{$ref_func}) {
f2f8458e SR	426
f2f8458e SR	427	# only use locals if objcopy supports globalize-symbols
7b7edc27	428	if (!$can_use_local) {
f2f8458e SR	429	return;
f2f8458e SR	430	}
8feff1ca SR	431	$convert{$ref_func} = 1;
	432	}
	433
	434	# Loop through all the mcount caller offsets and print a reference
	435	# to the caller based from the ref_func.
dc4f8845 WS	436	if (!$opened) {
	437	open(FILE, ">$mcount_s") \|\| die "can't create $mcount_s\n";
	438	$opened = 1;
	439	print FILE "\t.section $mcount_section,\"a\",$section_type\n";
	440	print FILE "\t.align $alignment\n" if (defined($alignment));
	441	}
	442	foreach my $cur_offset (@offsets) {
	443	printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
8feff1ca SR	444	}
	445	}
	446
8da3821b SR	447	#
	448	# Step 2: find the sections and mcount call sites
	449	#
b43f7093	450	open(IN, "$objdump -hdr $inputfile\|") \|\| die "error running $objdump";
8da3821b	451
8feff1ca SR	452	my $text;
8feff1ca SR	453
db24c7dc LH	454
db24c7dc LH	455	# read headers first
b43f7093 SR	456	my $read_headers = 1;
b43f7093 SR	457
8da3821b	458	while (<IN>) {
db24c7dc LH	459
	460	if ($read_headers && /$mcount_section/) {
	461	#
	462	# Somehow the make process can execute this script on an
	463	# object twice. If it does, we would duplicate the mcount
	464	# section and it will cause the function tracer self test
	465	# to fail. Check if the mcount section exists, and if it does,
	466	# warn and exit.
	467	#
	468	print STDERR "ERROR: $mcount_section already in $inputfile\n" .
	469	"\tThis may be an indication that your build is corrupted.\n" .
	470	"\tDelete $inputfile and try again. If the same object file\n" .
	471	"\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
	472	exit(-1);
	473	}
	474
8da3821b SR	475	# is it a section?
8da3821b SR	476	if (/$section_regex/) {
b43f7093	477	$read_headers = 0;
34698bcb SR	478
34698bcb SR	479	# Only record text sections that we know are safe
dfaa9e2c	480	$read_function = defined($text_sections{$1});
8feff1ca	481	# print out any recorded offsets
6092858c	482	update_funcs();
8feff1ca SR	483
8feff1ca SR	484	# reset all markers and arrays
8da3821b	485	$text_found = 0;
8feff1ca SR	486	undef($ref_func);
	487	undef(@offsets);
	488
8da3821b SR	489	# section found, now is this a start of a function?
8da3821b SR	490	} elsif ($read_function && /$function_regex/) {
8da3821b	491	$text_found = 1;
8feff1ca SR	492	$text = $2;
	493
	494	# if this is either a local function or a weak function
	495	# keep looking for functions that are global that
	496	# we can use safely.
	497	if (!defined($locals{$text}) && !defined($weak{$text})) {
	498	$ref_func = $text;
	499	$read_function = 0;
bd171d5f	500	$offset = hex $1;
8feff1ca SR	501	} else {
8feff1ca SR	502	# if we already have a function, and this is weak, skip it
3f6e968e SR	503	if (!defined($ref_func) && !defined($weak{$text}) &&
	504	# PPC64 can have symbols that start with .L and
	505	# gcc considers these special. Don't use them!
	506	$text !~ /^\.L/) {
8feff1ca	507	$ref_func = $text;
bd171d5f	508	$offset = hex $1;
8feff1ca	509	}
8da3821b	510	}
8feff1ca	511	}
8feff1ca SR	512	# is this a call site to mcount? If so, record it to print later
8feff1ca SR	513	if ($text_found && /$mcount_regex/) {
dc4f8845	514	push(@offsets, hex $1);
8da3821b SR	515	}
	516	}
	517
8feff1ca	518	# dump out anymore offsets that may have been found
6092858c	519	update_funcs();
8feff1ca	520
8da3821b SR	521	# If we did not find any mcount callers, we are done (do nothing).
	522	if (!$opened) {
	523	exit(0);
	524	}
	525
	526	close(FILE);
	527
	528	#
	529	# Step 3: Compile the file that holds the list of call sites to mcount.
	530	#
	531	`$cc -o $mcount_o -c $mcount_s`;
	532
	533	my @converts = keys %convert;
	534
	535	#
	536	# Step 4: Do we have sections that started with local functions?
	537	#
	538	if ($#converts >= 0) {
	539	my $globallist = "";
	540	my $locallist = "";
	541
	542	foreach my $con (@converts) {
	543	$globallist .= " --globalize-symbol $con";
	544	$locallist .= " --localize-symbol $con";
	545	}
	546
	547	my $globalobj = $dirname . "/.tmp_gl_" . $filename;
	548	my $globalmix = $dirname . "/.tmp_mx_" . $filename;
	549
	550	#
	551	# Step 5: set up each local function as a global
	552	#
	553	`$objcopy $globallist $inputfile $globalobj`;
	554
	555	#
	556	# Step 6: Link the global version to our list.
	557	#
	558	`$ld -r $globalobj $mcount_o -o $globalmix`;
	559
	560	#
	561	# Step 7: Convert the local functions back into local symbols
	562	#
	563	`$objcopy $locallist $globalmix $inputfile`;
	564
	565	# Remove the temp files
	566	`$rm $globalobj $globalmix`;
	567
	568	} else {
	569
	570	my $mix = $dirname . "/.tmp_mx_" . $filename;
	571
	572	#
	573	# Step 8: Link the object with our list of call sites object.
	574	#
	575	`$ld -r $inputfile $mcount_o -o $mix`;
	576
	577	#
	578	# Step 9: Move the result back to the original object.
	579	#
	580	`$mv $mix $inputfile`;
	581	}
	582
	583	# Clean up the temp files
	584	`$rm $mcount_o $mcount_s`;
585
586	exit(0);