[net-next-2.6.git] / scripts / kconfig / streamline_config.pl

#!/usr/bin/perl -w
#
# Copywrite 2005-2009 - Steven Rostedt
# Licensed under the terms of the GNU GPL License version 2
#
#  It's simple enough to figure out how this works.
#  If not, then you can ask me at stripconfig@goodmis.org
#
# What it does?
#
#   If you have installed a Linux kernel from a distribution
#   that turns on way too many modules than you need, and
#   you only want the modules you use, then this program
#   is perfect for you.
#
#   It gives you the ability to turn off all the modules that are
#   not loaded on your system.
#
# Howto:
#
#  1. Boot up the kernel that you want to stream line the config on.
#  2. Change directory to the directory holding the source of the
#       kernel that you just booted.
#  3. Copy the configuraton file to this directory as .config
#  4. Have all your devices that you need modules for connected and
#      operational (make sure that their corresponding modules are loaded)
#  5. Run this script redirecting the output to some other file
#       like config_strip.
#  6. Back up your old config (if you want too).
#  7. copy the config_strip file to .config
#  8. Run "make oldconfig"
#
#  Now your kernel is ready to be built with only the modules that
#  are loaded.
#
# Here's what I did with my Debian distribution.
#
#    cd /usr/src/linux-2.6.10
#    cp /boot/config-2.6.10-1-686-smp .config
#    ~/bin/streamline_config > config_strip
#    mv .config config_sav
#    mv config_strip .config
#    make oldconfig
#
use strict;

my $config = ".config";

my $uname = `uname -r`;
chomp $uname;

my @searchconfigs = (
	{
	    "file" => ".config",
	    "exec" => "cat",
	},
	{
	    "file" => "/proc/config.gz",
	    "exec" => "zcat",
	},
	{
	    "file" => "/boot/config-$uname",
	    "exec" => "cat",
	},
	{
	    "file" => "/boot/vmlinuz-$uname",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "vmlinux",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "kernel/configs.ko",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
	{
	    "file" => "kernel/configs.o",
	    "exec" => "scripts/extract-ikconfig",
	    "test" => "scripts/extract-ikconfig",
	},
);

sub find_config {
    foreach my $conf (@searchconfigs) {
	my $file = $conf->{"file"};

	next if ( ! -f "$file");

	if (defined($conf->{"test"})) {
	    `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
	    next if ($?);
	}

	my $exec = $conf->{"exec"};

	print STDERR "using config: '$file'\n";

	open(CIN, "$exec $file |") || die "Failed to run $exec $file";
	return;
    }
    die "No config file found";
}

find_config;

# Get the build source and top level Kconfig file (passed in)
my $ksource = $ARGV[0];
my $kconfig = $ARGV[1];
my $lsmod_file = $ARGV[2];

my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
chomp @makefiles;

my %depends;
my %selects;
my %prompts;
my %objects;
my $var;
my $iflevel = 0;
my @ifdeps;

# prevent recursion
my %read_kconfigs;

sub read_kconfig {
    my ($kconfig) = @_;

    my $state = "NONE";
    my $config;
    my @kconfigs;

    my $cont = 0;
    my $line;

    my $source = "$ksource/$kconfig";
    my $last_source = "";

    # Check for any environment variables used
    while ($source =~ /\$(\w+)/ && $last_source ne $source) {
	my $env = $1;
	$last_source = $source;
	$source =~ s/\$$env/$ENV{$env}/;
    }

    open(KIN, "$source") || die "Can't open $kconfig";
    while (<KIN>) {
	chomp;

	# Make sure that lines ending with \ continue
	if ($cont) {
	    $_ = $line . " " . $_;
	}

	if (s/\\$//) {
	    $cont = 1;
	    $line = $_;
	    next;
	}

	$cont = 0;

	# collect any Kconfig sources
	if (/^source\s*"(.*)"/) {
	    $kconfigs[$#kconfigs+1] = $1;
	}

	# configs found
	if (/^\s*(menu)?config\s+(\S+)\s*$/) {
	    $state = "NEW";
	    $config = $2;

	    for (my $i = 0; $i < $iflevel; $i++) {
		if ($i) {
		    $depends{$config} .= " " . $ifdeps[$i];
		} else {
		    $depends{$config} = $ifdeps[$i];
		}
		$state = "DEP";
	    }

	# collect the depends for the config
	} elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
	    $state = "DEP";
	    $depends{$config} = $1;
	} elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
	    $depends{$config} .= " " . $1;

	# Get the configs that select this config
	} elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
	    if (defined($selects{$1})) {
		$selects{$1} .= " " . $config;
	    } else {
		$selects{$1} = $config;
	    }

	# configs without prompts must be selected
	} elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
	    # note if the config has a prompt
	    $prompts{$config} = 1;

	# Check for if statements
	} elsif (/^if\s+(.*\S)\s*$/) {
	    my $deps = $1;
	    # remove beginning and ending non text
	    $deps =~ s/^[^a-zA-Z0-9_]*//;
	    $deps =~ s/[^a-zA-Z0-9_]*$//;

	    my @deps = split /[^a-zA-Z0-9_]+/, $deps;

	    $ifdeps[$iflevel++] = join ':', @deps;

	} elsif (/^endif/) {

	    $iflevel-- if ($iflevel);

	# stop on "help"
	} elsif (/^\s*help\s*$/) {
	    $state = "NONE";
	}
    }
    close(KIN);

    # read in any configs that were found.
    foreach $kconfig (@kconfigs) {
	if (!defined($read_kconfigs{$kconfig})) {
	    $read_kconfigs{$kconfig} = 1;
	    read_kconfig($kconfig);
	}
    }
}

if ($kconfig) {
    read_kconfig($kconfig);
}

# Read all Makefiles to map the configs to the objects
foreach my $makefile (@makefiles) {

    my $cont = 0;

    open(MIN,$makefile) || die "Can't open $makefile";
    while (<MIN>) {
	my $objs;

	# is this a line after a line with a backslash?
	if ($cont && /(\S.*)$/) {
	    $objs = $1;
	}
	$cont = 0;

	# collect objects after obj-$(CONFIG_FOO_BAR)
	if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
	    $var = $1;
	    $objs = $2;
	}
	if (defined($objs)) {
	    # test if the line ends with a backslash
	    if ($objs =~ m,(.*)\\$,) {
		$objs = $1;
		$cont = 1;
	    }

	    foreach my $obj (split /\s+/,$objs) {
		$obj =~ s/-/_/g;
		if ($obj =~ /(.*)\.o$/) {
		    # Objects may be enabled by more than one config.
		    # Store configs in an array.
		    my @arr;

		    if (defined($objects{$1})) {
			@arr = @{$objects{$1}};
		    }

		    $arr[$#arr+1] = $var;

		    # The objects have a hash mapping to a reference
		    # of an array of configs.
		    $objects{$1} = \@arr;
		}
	    }
	}
    }
    close(MIN);
}

my %modules;

if (defined($lsmod_file)) {
    if ( ! -f $lsmod_file) {
	die "$lsmod_file not found";
    }
    if ( -x $lsmod_file) {
	# the file is executable, run it
	open(LIN, "$lsmod_file|");
    } else {
	# Just read the contents
	open(LIN, "$lsmod_file");
    }
} else {

    # see what modules are loaded on this system
    my $lsmod;

    foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
	if ( -x "$dir/lsmod" ) {
	    $lsmod = "$dir/lsmod";
	    last;
	}
}
    if (!defined($lsmod)) {
	# try just the path
	$lsmod = "lsmod";
    }

    open(LIN,"$lsmod|") || die "Can not call lsmod with $lsmod";
}

while (<LIN>) {
	next if (/^Module/);  # Skip the first line.
	if (/^(\S+)/) {
		$modules{$1} = 1;
	}
}
close (LIN);

# add to the configs hash all configs that are needed to enable
# a loaded module.
my %configs;
foreach my $module (keys(%modules)) {
    if (defined($objects{$module})) {
	my @arr = @{$objects{$module}};
	foreach my $conf (@arr) {
	    $configs{$conf} = $module;
	}
    } else {
	# Most likely, someone has a custom (binary?) module loaded.
	print STDERR "$module config not found!!\n";
    }
}

my $valid = "A-Za-z_0-9";
my $repeat = 1;

#
# Note, we do not care about operands (like: &&, ||, !) we want to add any
# config that is in the depend list of another config. This script does
# not enable configs that are not already enabled. If we come across a
# config A that depends on !B, we can still add B to the list of depends
# to keep on. If A was on in the original config, B would not have been
# and B would not be turned on by this script.
#
sub parse_config_dep_select
{
    my ($p) = @_;

    while ($p =~ /[$valid]/) {

	if ($p =~ /^[^$valid]*([$valid]+)/) {
	    my $conf = "CONFIG_" . $1;

	    $p =~ s/^[^$valid]*[$valid]+//;

	    if (!defined($configs{$conf})) {
		# We must make sure that this config has its
		# dependencies met.
		$repeat = 1; # do again
		$configs{$conf} = 1;
	    }
	} else {
	    die "this should never happen";
	}
    }
}

while ($repeat) {
    $repeat = 0;

    foreach my $config (keys %configs) {
	$config =~ s/^CONFIG_//;

	if (defined($depends{$config})) {
	    # This config has dependencies. Make sure they are also included
	    parse_config_dep_select $depends{$config};
	}

	if (defined($prompts{$config}) || !defined($selects{$config})) {
	    next;
	}

	# config has no prompt and must be selected.
	parse_config_dep_select $selects{$config};
    }
}

my %setconfigs;

# Finally, read the .config file and turn off any module enabled that
# we could not find a reason to keep enabled.
while(<CIN>) {

    if (/CONFIG_IKCONFIG/) {
	if (/# CONFIG_IKCONFIG is not set/) {
	    # enable IKCONFIG at least as a module
	    print "CONFIG_IKCONFIG=m\n";
	    # don't ask about PROC
	    print "# CONFIG_IKCONFIG_PROC is not set\n";
	} else {
	    print;
	}
	next;
    }

    if (/^(CONFIG.*)=(m|y)/) {
	if (defined($configs{$1})) {
	    $setconfigs{$1} = $2;
	} elsif ($2 eq "m") {
	    print "# $1 is not set\n";
	    next;
	}
    }
    print;
}
close(CIN);

# Integrity check, make sure all modules that we want enabled do
# indeed have their configs set.
loop:
foreach my $module (keys(%modules)) {
    if (defined($objects{$module})) {
	my @arr = @{$objects{$module}};
	foreach my $conf (@arr) {
	    if (defined($setconfigs{$conf})) {
		next loop;
	    }
	}
	print STDERR "module $module did not have configs";
	foreach my $conf (@arr) {
	    print STDERR " " , $conf;
	}
	print STDERR "\n";
    }
}
Commit	Line	Data
dcc60243 SR	1	#!/usr/bin/perl -w
	2	#
	3	# Copywrite 2005-2009 - Steven Rostedt
	4	# Licensed under the terms of the GNU GPL License version 2
	5	#
	6	# It's simple enough to figure out how this works.
	7	# If not, then you can ask me at stripconfig@goodmis.org
	8	#
	9	# What it does?
	10	#
	11	# If you have installed a Linux kernel from a distribution
	12	# that turns on way too many modules than you need, and
	13	# you only want the modules you use, then this program
	14	# is perfect for you.
	15	#
	16	# It gives you the ability to turn off all the modules that are
	17	# not loaded on your system.
	18	#
	19	# Howto:
	20	#
	21	# 1. Boot up the kernel that you want to stream line the config on.
	22	# 2. Change directory to the directory holding the source of the
	23	# kernel that you just booted.
	24	# 3. Copy the configuraton file to this directory as .config
	25	# 4. Have all your devices that you need modules for connected and
	26	# operational (make sure that their corresponding modules are loaded)
	27	# 5. Run this script redirecting the output to some other file
	28	# like config_strip.
	29	# 6. Back up your old config (if you want too).
	30	# 7. copy the config_strip file to .config
	31	# 8. Run "make oldconfig"
	32	#
	33	# Now your kernel is ready to be built with only the modules that
	34	# are loaded.
	35	#
	36	# Here's what I did with my Debian distribution.
	37	#
	38	# cd /usr/src/linux-2.6.10
	39	# cp /boot/config-2.6.10-1-686-smp .config
	40	# ~/bin/streamline_config > config_strip
	41	# mv .config config_sav
	42	# mv config_strip .config
	43	# make oldconfig
	44	#
cf5a189d	45	use strict;
cf5a189d	46
dcc60243	47	my $config = ".config";
dcc60243	48
cdfc4795 SR	49	my $uname = `uname -r`;
	50	chomp $uname;
	51
	52	my @searchconfigs = (
a9024838 SR	53	{
	54	"file" => ".config",
	55	"exec" => "cat",
	56	},
cdfc4795 SR	57	{
	58	"file" => "/proc/config.gz",
	59	"exec" => "zcat",
	60	},
810b2be6 SR	61	{
	62	"file" => "/boot/config-$uname",
	63	"exec" => "cat",
	64	},
cdfc4795 SR	65	{
	66	"file" => "/boot/vmlinuz-$uname",
	67	"exec" => "scripts/extract-ikconfig",
	68	"test" => "scripts/extract-ikconfig",
	69	},
	70	{
	71	"file" => "vmlinux",
	72	"exec" => "scripts/extract-ikconfig",
	73	"test" => "scripts/extract-ikconfig",
	74	},
	75	{
	76	"file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
	77	"exec" => "scripts/extract-ikconfig",
	78	"test" => "scripts/extract-ikconfig",
	79	},
	80	{
	81	"file" => "kernel/configs.ko",
	82	"exec" => "scripts/extract-ikconfig",
	83	"test" => "scripts/extract-ikconfig",
	84	},
	85	{
	86	"file" => "kernel/configs.o",
	87	"exec" => "scripts/extract-ikconfig",
	88	"test" => "scripts/extract-ikconfig",
	89	},
cdfc4795 SR	90	);
	91
	92	sub find_config {
	93	foreach my $conf (@searchconfigs) {
	94	my $file = $conf->{"file"};
	95
	96	next if ( ! -f "$file");
	97
	98	if (defined($conf->{"test"})) {
	99	`$conf->{"test"} $conf->{"file"} 2>/dev/null`;
	100	next if ($?);
	101	}
	102
	103	my $exec = $conf->{"exec"};
	104
	105	print STDERR "using config: '$file'\n";
	106
	107	open(CIN, "$exec $file \|") \|\| die "Failed to run $exec $file";
	108	return;
	109	}
	110	die "No config file found";
	111	}
	112
	113	find_config;
	114
463bf900 SR	115	# Get the build source and top level Kconfig file (passed in)
	116	my $ksource = $ARGV[0];
	117	my $kconfig = $ARGV[1];
615f0833	118	my $lsmod_file = $ARGV[2];
463bf900	119
17431928 TF	120	my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
	121	chomp @makefiles;
	122
dcc60243 SR	123	my %depends;
	124	my %selects;
	125	my %prompts;
	126	my %objects;
	127	my $var;
13d7e938 SR	128	my $iflevel = 0;
13d7e938 SR	129	my @ifdeps;
dcc60243	130
dcc60243 SR	131	# prevent recursion
	132	my %read_kconfigs;
	133
	134	sub read_kconfig {
	135	my ($kconfig) = @_;
	136
	137	my $state = "NONE";
	138	my $config;
	139	my @kconfigs;
	140
20d19047 SR	141	my $cont = 0;
	142	my $line;
	143
4908980b SR	144	my $source = "$ksource/$kconfig";
	145	my $last_source = "";
	146
	147	# Check for any environment variables used
	148	while ($source =~ /\$(\w+)/ && $last_source ne $source) {
	149	my $env = $1;
	150	$last_source = $source;
	151	$source =~ s/\$$env/$ENV{$env}/;
	152	}
	153
	154	open(KIN, "$source") \|\| die "Can't open $kconfig";
dcc60243 SR	155	while (<KIN>) {
	156	chomp;
	157
20d19047 SR	158	# Make sure that lines ending with \ continue
	159	if ($cont) {
	160	$_ = $line . " " . $_;
	161	}
	162
	163	if (s/\\$//) {
	164	$cont = 1;
	165	$line = $_;
	166	next;
	167	}
	168
	169	$cont = 0;
	170
dcc60243 SR	171	# collect any Kconfig sources
	172	if (/^source\s"(.)"/) {
	173	$kconfigs[$#kconfigs+1] = $1;
	174	}
	175
	176	# configs found
8ef17fa2	177	if (/^\s(menu)?config\s+(\S+)\s$/) {
dcc60243	178	$state = "NEW";
8ef17fa2	179	$config = $2;
dcc60243	180
13d7e938 SR	181	for (my $i = 0; $i < $iflevel; $i++) {
	182	if ($i) {
	183	$depends{$config} .= " " . $ifdeps[$i];
	184	} else {
	185	$depends{$config} = $ifdeps[$i];
	186	}
	187	$state = "DEP";
	188	}
	189
dcc60243 SR	190	# collect the depends for the config
	191	} elsif ($state eq "NEW" && /^\sdepends\s+on\s+(.)$/) {
	192	$state = "DEP";
	193	$depends{$config} = $1;
	194	} elsif ($state eq "DEP" && /^\sdepends\s+on\s+(.)$/) {
	195	$depends{$config} .= " " . $1;
	196
	197	# Get the configs that select this config
	198	} elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
	199	if (defined($selects{$1})) {
	200	$selects{$1} .= " " . $config;
	201	} else {
	202	$selects{$1} = $config;
	203	}
	204
	205	# configs without prompts must be selected
	206	} elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
	207	# note if the config has a prompt
ccece60a	208	$prompts{$config} = 1;
dcc60243	209
13d7e938 SR	210	# Check for if statements
	211	} elsif (/^if\s+(.\S)\s$/) {
	212	my $deps = $1;
	213	# remove beginning and ending non text
	214	$deps =~ s/^[^a-zA-Z0-9_]*//;
	215	$deps =~ s/[^a-zA-Z0-9_]*$//;
	216
	217	my @deps = split /[^a-zA-Z0-9_]+/, $deps;
	218
	219	$ifdeps[$iflevel++] = join ':', @deps;
	220
	221	} elsif (/^endif/) {
	222
	223	$iflevel-- if ($iflevel);
	224
dcc60243 SR	225	# stop on "help"
	226	} elsif (/^\shelp\s$/) {
	227	$state = "NONE";
	228	}
	229	}
	230	close(KIN);
	231
	232	# read in any configs that were found.
	233	foreach $kconfig (@kconfigs) {
	234	if (!defined($read_kconfigs{$kconfig})) {
	235	$read_kconfigs{$kconfig} = 1;
	236	read_kconfig($kconfig);
	237	}
	238	}
	239	}
	240
	241	if ($kconfig) {
	242	read_kconfig($kconfig);
	243	}
	244
	245	# Read all Makefiles to map the configs to the objects
	246	foreach my $makefile (@makefiles) {
dcc60243	247
20d19047 SR	248	my $cont = 0;
20d19047 SR	249
dcc60243 SR	250	open(MIN,$makefile) \|\| die "Can't open $makefile";
	251	while (<MIN>) {
	252	my $objs;
	253
	254	# is this a line after a line with a backslash?
	255	if ($cont && /(\S.*)$/) {
	256	$objs = $1;
	257	}
	258	$cont = 0;
	259
	260	# collect objects after obj-$(CONFIG_FOO_BAR)
	261	if (/obj-\$\((CONFIG_[^\)])\)\s[+:]?=\s(.)/) {
	262	$var = $1;
	263	$objs = $2;
	264	}
	265	if (defined($objs)) {
	266	# test if the line ends with a backslash
	267	if ($objs =~ m,(.*)\\$,) {
	268	$objs = $1;
	269	$cont = 1;
	270	}
	271
	272	foreach my $obj (split /\s+/,$objs) {
	273	$obj =~ s/-/_/g;
	274	if ($obj =~ /(.*)\.o$/) {
1d1d1fea	275	# Objects may be enabled by more than one config.
dcc60243 SR	276	# Store configs in an array.
	277	my @arr;
	278
	279	if (defined($objects{$1})) {
	280	@arr = @{$objects{$1}};
	281	}
	282
	283	$arr[$#arr+1] = $var;
	284
	285	# The objects have a hash mapping to a reference
	286	# of an array of configs.
	287	$objects{$1} = \@arr;
	288	}
	289	}
	290	}
	291	}
	292	close(MIN);
	293	}
	294
	295	my %modules;
	296
615f0833 SR	297	if (defined($lsmod_file)) {
	298	if ( ! -f $lsmod_file) {
	299	die "$lsmod_file not found";
	300	}
	301	if ( -x $lsmod_file) {
	302	# the file is executable, run it
	303	open(LIN, "$lsmod_file\|");
	304	} else {
	305	# Just read the contents
	306	open(LIN, "$lsmod_file");
88f66ea9	307	}
615f0833 SR	308	} else {
	309
	310	# see what modules are loaded on this system
	311	my $lsmod;
	312
cf5a189d	313	foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
615f0833 SR	314	if ( -x "$dir/lsmod" ) {
	315	$lsmod = "$dir/lsmod";
	316	last;
	317	}
88f66ea9	318	}
615f0833 SR	319	if (!defined($lsmod)) {
	320	# try just the path
	321	$lsmod = "lsmod";
	322	}
	323
	324	open(LIN,"$lsmod\|") \|\| die "Can not call lsmod with $lsmod";
88f66ea9 SR	325	}
88f66ea9 SR	326
dcc60243 SR	327	while (<LIN>) {
	328	next if (/^Module/); # Skip the first line.
	329	if (/^(\S+)/) {
	330	$modules{$1} = 1;
	331	}
	332	}
	333	close (LIN);
	334
	335	# add to the configs hash all configs that are needed to enable
	336	# a loaded module.
	337	my %configs;
	338	foreach my $module (keys(%modules)) {
	339	if (defined($objects{$module})) {
e5199edb	340	my @arr = @{$objects{$module}};
dcc60243 SR	341	foreach my $conf (@arr) {
	342	$configs{$conf} = $module;
	343	}
	344	} else {
	345	# Most likely, someone has a custom (binary?) module loaded.
	346	print STDERR "$module config not found!!\n";
	347	}
	348	}
	349
	350	my $valid = "A-Za-z_0-9";
	351	my $repeat = 1;
	352
	353	#
	354	# Note, we do not care about operands (like: &&, \|\|, !) we want to add any
	355	# config that is in the depend list of another config. This script does
	356	# not enable configs that are not already enabled. If we come across a
	357	# config A that depends on !B, we can still add B to the list of depends
	358	# to keep on. If A was on in the original config, B would not have been
	359	# and B would not be turned on by this script.
	360	#
	361	sub parse_config_dep_select
	362	{
	363	my ($p) = @_;
	364
	365	while ($p =~ /[$valid]/) {
	366
	367	if ($p =~ /^[^$valid]*([$valid]+)/) {
	368	my $conf = "CONFIG_" . $1;
	369
	370	$p =~ s/^[^$valid]*[$valid]+//;
	371
	372	if (!defined($configs{$conf})) {
	373	# We must make sure that this config has its
	374	# dependencies met.
	375	$repeat = 1; # do again
	376	$configs{$conf} = 1;
	377	}
	378	} else {
	379	die "this should never happen";
	380	}
	381	}
	382	}
	383
	384	while ($repeat) {
	385	$repeat = 0;
	386
	387	foreach my $config (keys %configs) {
	388	$config =~ s/^CONFIG_//;
	389
74398d32 SR	390	if (defined($depends{$config})) {
	391	# This config has dependencies. Make sure they are also included
	392	parse_config_dep_select $depends{$config};
dcc60243 SR	393	}
dcc60243 SR	394
ccece60a	395	if (defined($prompts{$config}) \|\| !defined($selects{$config})) {
dcc60243 SR	396	next;
	397	}
	398
	399	# config has no prompt and must be selected.
	400	parse_config_dep_select $selects{$config};
	401	}
	402	}
	403
	404	my %setconfigs;
	405
	406	# Finally, read the .config file and turn off any module enabled that
	407	# we could not find a reason to keep enabled.
	408	while(<CIN>) {
744ffcbe SR	409
	410	if (/CONFIG_IKCONFIG/) {
	411	if (/# CONFIG_IKCONFIG is not set/) {
	412	# enable IKCONFIG at least as a module
	413	print "CONFIG_IKCONFIG=m\n";
	414	# don't ask about PROC
d08ca277	415	print "# CONFIG_IKCONFIG_PROC is not set\n";
744ffcbe SR	416	} else {
	417	print;
	418	}
	419	next;
	420	}
	421
	422	if (/^(CONFIG.*)=(m\|y)/) {
	423	if (defined($configs{$1})) {
	424	$setconfigs{$1} = $2;
744ffcbe SR	425	} elsif ($2 eq "m") {
744ffcbe SR	426	print "# $1 is not set\n";
d08ca277	427	next;
dcc60243	428	}
744ffcbe	429	}
d08ca277	430	print;
dcc60243 SR	431	}
	432	close(CIN);
	433
	434	# Integrity check, make sure all modules that we want enabled do
	435	# indeed have their configs set.
	436	loop:
	437	foreach my $module (keys(%modules)) {
	438	if (defined($objects{$module})) {
	439	my @arr = @{$objects{$module}};
	440	foreach my $conf (@arr) {
	441	if (defined($setconfigs{$conf})) {
	442	next loop;
	443	}
	444	}
	445	print STDERR "module $module did not have configs";
	446	foreach my $conf (@arr) {
	447	print STDERR " " , $conf;
	448	}
	449	print STDERR "\n";
	450	}
	451	}