[net-next-2.6.git] / arch / sparc / kernel / syscalls.S

	/* SunOS's execv() call only specifies the argv argument, the
	 * environment settings are the same as the calling processes.
	 */
sys_execve:
	sethi	%hi(sparc_execve), %g1
	ba,pt	%xcc, execve_merge
	 or	%g1, %lo(sparc_execve), %g1

#ifdef CONFIG_COMPAT
sunos_execv:
	stx	%g0, [%sp + PTREGS_OFF + PT_V9_I2]
sys32_execve:
	sethi	%hi(sparc32_execve), %g1
	or	%g1, %lo(sparc32_execve), %g1
#endif

execve_merge:
	flushw
	jmpl	%g1, %g0
	 add	%sp, PTREGS_OFF, %o0

	.align	32
sys_sparc_pipe:
	ba,pt	%xcc, sys_sparc_pipe_real
	 add	%sp, PTREGS_OFF, %o0
sys_nis_syscall:
	ba,pt	%xcc, c_sys_nis_syscall
	 add	%sp, PTREGS_OFF, %o0
sys_memory_ordering:
	ba,pt	%xcc, sparc_memory_ordering
	 add	%sp, PTREGS_OFF, %o1
sys_sigaltstack:
	ba,pt	%xcc, do_sigaltstack
	 add	%i6, STACK_BIAS, %o2
#ifdef CONFIG_COMPAT
sys32_sigstack:
	ba,pt	%xcc, do_sys32_sigstack
	 mov	%i6, %o2
sys32_sigaltstack:
	ba,pt	%xcc, do_sys32_sigaltstack
	 mov	%i6, %o2
#endif
	.align	32
#ifdef CONFIG_COMPAT
sys32_sigreturn:
	add	%sp, PTREGS_OFF, %o0
	call	do_sigreturn32
	 add	%o7, 1f-.-4, %o7
	nop
#endif
sys_rt_sigreturn:
	add	%sp, PTREGS_OFF, %o0
	call	do_rt_sigreturn
	 add	%o7, 1f-.-4, %o7
	nop
#ifdef CONFIG_COMPAT
sys32_rt_sigreturn:
	add	%sp, PTREGS_OFF, %o0
	call	do_rt_sigreturn32
	 add	%o7, 1f-.-4, %o7
	nop
#endif
	.align	32
1:	ldx	[%g6 + TI_FLAGS], %l5
	andcc	%l5, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT), %g0
	be,pt	%icc, rtrap
	 nop
	call	syscall_trace_leave
	 add	%sp, PTREGS_OFF, %o0
	ba,pt	%xcc, rtrap
	 nop

	/* This is how fork() was meant to be done, 8 instruction entry.
	 *
	 * I questioned the following code briefly, let me clear things
	 * up so you must not reason on it like I did.
	 *
	 * Know the fork_kpsr etc. we use in the sparc32 port?  We don't
	 * need it here because the only piece of window state we copy to
	 * the child is the CWP register.  Even if the parent sleeps,
	 * we are safe because we stuck it into pt_regs of the parent
	 * so it will not change.
	 *
	 * XXX This raises the question, whether we can do the same on
	 * XXX sparc32 to get rid of fork_kpsr _and_ fork_kwim.  The
	 * XXX answer is yes.  We stick fork_kpsr in UREG_G0 and
	 * XXX fork_kwim in UREG_G1 (global registers are considered
	 * XXX volatile across a system call in the sparc ABI I think
	 * XXX if it isn't we can use regs->y instead, anyone who depends
	 * XXX upon the Y register being preserved across a fork deserves
	 * XXX to lose).
	 *
	 * In fact we should take advantage of that fact for other things
	 * during system calls...
	 */
	.align	32
sys_vfork: /* Under Linux, vfork and fork are just special cases of clone. */
	sethi	%hi(0x4000 | 0x0100 | SIGCHLD), %o0
	or	%o0, %lo(0x4000 | 0x0100 | SIGCHLD), %o0
	ba,pt	%xcc, sys_clone
sys_fork:
	 clr	%o1
	mov	SIGCHLD, %o0
sys_clone:
	flushw
	movrz	%o1, %fp, %o1
	mov	0, %o3
	ba,pt	%xcc, sparc_do_fork
	 add	%sp, PTREGS_OFF, %o2

	.globl	ret_from_syscall
ret_from_syscall:
	/* Clear current_thread_info()->new_child. */
	stb	%g0, [%g6 + TI_NEW_CHILD]
	ldx	[%g6 + TI_FLAGS], %l0
	call	schedule_tail
	 mov	%g7, %o0
	ba,pt	%xcc, ret_sys_call
	 ldx	[%sp + PTREGS_OFF + PT_V9_I0], %o0

	.globl	sparc_exit
	.type	sparc_exit,#function
sparc_exit:
	rdpr	%pstate, %g2
	wrpr	%g2, PSTATE_IE, %pstate
	rdpr	%otherwin, %g1
	rdpr	%cansave, %g3
	add	%g3, %g1, %g3
	wrpr	%g3, 0x0, %cansave
	wrpr	%g0, 0x0, %otherwin
	wrpr	%g2, 0x0, %pstate
	ba,pt	%xcc, sys_exit
	 stb	%g0, [%g6 + TI_WSAVED]
	.size	sparc_exit,.-sparc_exit

linux_sparc_ni_syscall:
	sethi	%hi(sys_ni_syscall), %l7
	ba,pt	%xcc, 4f
	 or	%l7, %lo(sys_ni_syscall), %l7

linux_syscall_trace32:
	call	syscall_trace_enter
	 add	%sp, PTREGS_OFF, %o0
	brnz,pn	%o0, 3f
	 mov	-ENOSYS, %o0
	srl	%i0, 0, %o0
	srl	%i4, 0, %o4
	srl	%i1, 0, %o1
	srl	%i2, 0, %o2
	ba,pt	%xcc, 2f
	 srl	%i3, 0, %o3

linux_syscall_trace:
	call	syscall_trace_enter
	 add	%sp, PTREGS_OFF, %o0
	brnz,pn	%o0, 3f
	 mov	-ENOSYS, %o0
	mov	%i0, %o0
	mov	%i1, %o1
	mov	%i2, %o2
	mov	%i3, %o3
	b,pt	%xcc, 2f
	 mov	%i4, %o4


	/* Linux 32-bit system calls enter here... */
	.align	32
	.globl	linux_sparc_syscall32
linux_sparc_syscall32:
	/* Direct access to user regs, much faster. */
	cmp	%g1, NR_syscalls			! IEU1	Group
	bgeu,pn	%xcc, linux_sparc_ni_syscall		! CTI
	 srl	%i0, 0, %o0				! IEU0
	sll	%g1, 2, %l4				! IEU0	Group
	srl	%i4, 0, %o4				! IEU1
	lduw	[%l7 + %l4], %l7			! Load
	srl	%i1, 0, %o1				! IEU0	Group
	ldx	[%g6 + TI_FLAGS], %l0		! Load

	srl	%i5, 0, %o5				! IEU1
	srl	%i2, 0, %o2				! IEU0	Group
	andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT), %g0
	bne,pn	%icc, linux_syscall_trace32		! CTI
	 mov	%i0, %l5				! IEU1
	call	%l7					! CTI	Group brk forced
	 srl	%i3, 0, %o3				! IEU0
	ba,a,pt	%xcc, 3f

	/* Linux native system calls enter here... */
	.align	32
	.globl	linux_sparc_syscall
linux_sparc_syscall:
	/* Direct access to user regs, much faster. */
	cmp	%g1, NR_syscalls			! IEU1	Group
	bgeu,pn	%xcc, linux_sparc_ni_syscall		! CTI
	 mov	%i0, %o0				! IEU0
	sll	%g1, 2, %l4				! IEU0	Group
	mov	%i1, %o1				! IEU1
	lduw	[%l7 + %l4], %l7			! Load
4:	mov	%i2, %o2				! IEU0	Group
	ldx	[%g6 + TI_FLAGS], %l0		! Load

	mov	%i3, %o3				! IEU1
	mov	%i4, %o4				! IEU0	Group
	andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT), %g0
	bne,pn	%icc, linux_syscall_trace		! CTI	Group
	 mov	%i0, %l5				! IEU0
2:	call	%l7					! CTI	Group brk forced
	 mov	%i5, %o5				! IEU0
	nop

3:	stx	%o0, [%sp + PTREGS_OFF + PT_V9_I0]
ret_sys_call:
	ldx	[%sp + PTREGS_OFF + PT_V9_TSTATE], %g3
	ldx	[%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc
	sra	%o0, 0, %o0
	mov	%ulo(TSTATE_XCARRY | TSTATE_ICARRY), %g2
	sllx	%g2, 32, %g2

	/* Check if force_successful_syscall_return()
	 * was invoked.
	 */
	ldub	[%g6 + TI_SYS_NOERROR], %l2
	brnz,a,pn %l2, 80f
	 stb	%g0, [%g6 + TI_SYS_NOERROR]

	cmp	%o0, -ERESTART_RESTARTBLOCK
	bgeu,pn	%xcc, 1f
	 andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT), %l6
80:
	/* System call success, clear Carry condition code. */
	andn	%g3, %g2, %g3
	stx	%g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]	
	bne,pn	%icc, linux_syscall_trace2
	 add	%l1, 0x4, %l2			! npc = npc+4
	stx	%l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	ba,pt	%xcc, rtrap
	 stx	%l2, [%sp + PTREGS_OFF + PT_V9_TNPC]

1:
	/* System call failure, set Carry condition code.
	 * Also, get abs(errno) to return to the process.
	 */
	andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT), %l6	
	sub	%g0, %o0, %o0
	or	%g3, %g2, %g3
	stx	%o0, [%sp + PTREGS_OFF + PT_V9_I0]
	stx	%g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]
	bne,pn	%icc, linux_syscall_trace2
	 add	%l1, 0x4, %l2			! npc = npc+4
	stx	%l1, [%sp + PTREGS_OFF + PT_V9_TPC]

	b,pt	%xcc, rtrap
	 stx	%l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
linux_syscall_trace2:
	call	syscall_trace_leave
	 add	%sp, PTREGS_OFF, %o0
	stx	%l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	ba,pt	%xcc, rtrap
	 stx	%l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
Commit	Line	Data
6eda3a75 DM	1	/* SunOS's execv() call only specifies the argv argument, the
	2	* environment settings are the same as the calling processes.
	3	*/
	4	sys_execve:
	5	sethi %hi(sparc_execve), %g1
	6	ba,pt %xcc, execve_merge
	7	or %g1, %lo(sparc_execve), %g1
	8
	9	#ifdef CONFIG_COMPAT
	10	sunos_execv:
	11	stx %g0, [%sp + PTREGS_OFF + PT_V9_I2]
	12	sys32_execve:
	13	sethi %hi(sparc32_execve), %g1
	14	or %g1, %lo(sparc32_execve), %g1
	15	#endif
	16
	17	execve_merge:
	18	flushw
	19	jmpl %g1, %g0
	20	add %sp, PTREGS_OFF, %o0
	21
	22	.align 32
1134723e	23	sys_sparc_pipe:
e4265019	24	ba,pt %xcc, sys_sparc_pipe_real
6eda3a75 DM	25	add %sp, PTREGS_OFF, %o0
	26	sys_nis_syscall:
	27	ba,pt %xcc, c_sys_nis_syscall
	28	add %sp, PTREGS_OFF, %o0
	29	sys_memory_ordering:
	30	ba,pt %xcc, sparc_memory_ordering
	31	add %sp, PTREGS_OFF, %o1
	32	sys_sigaltstack:
	33	ba,pt %xcc, do_sigaltstack
	34	add %i6, STACK_BIAS, %o2
	35	#ifdef CONFIG_COMPAT
	36	sys32_sigstack:
	37	ba,pt %xcc, do_sys32_sigstack
	38	mov %i6, %o2
	39	sys32_sigaltstack:
	40	ba,pt %xcc, do_sys32_sigaltstack
	41	mov %i6, %o2
	42	#endif
	43	.align 32
	44	#ifdef CONFIG_COMPAT
	45	sys32_sigreturn:
	46	add %sp, PTREGS_OFF, %o0
	47	call do_sigreturn32
	48	add %o7, 1f-.-4, %o7
	49	nop
	50	#endif
	51	sys_rt_sigreturn:
	52	add %sp, PTREGS_OFF, %o0
	53	call do_rt_sigreturn
	54	add %o7, 1f-.-4, %o7
	55	nop
	56	#ifdef CONFIG_COMPAT
	57	sys32_rt_sigreturn:
	58	add %sp, PTREGS_OFF, %o0
	59	call do_rt_sigreturn32
	60	add %o7, 1f-.-4, %o7
	61	nop
	62	#endif
	63	.align 32
	64	1: ldx [%g6 + TI_FLAGS], %l5
c658ad1b	65	andcc %l5, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT), %g0
6eda3a75 DM	66	be,pt %icc, rtrap
6eda3a75 DM	67	nop
fe06ccaa DM	68	call syscall_trace_leave
fe06ccaa DM	69	add %sp, PTREGS_OFF, %o0
6eda3a75 DM	70	ba,pt %xcc, rtrap
	71	nop
	72
	73	/* This is how fork() was meant to be done, 8 instruction entry.
	74	*
	75	* I questioned the following code briefly, let me clear things
	76	* up so you must not reason on it like I did.
	77	*
	78	* Know the fork_kpsr etc. we use in the sparc32 port? We don't
	79	* need it here because the only piece of window state we copy to
	80	* the child is the CWP register. Even if the parent sleeps,
	81	* we are safe because we stuck it into pt_regs of the parent
	82	* so it will not change.
	83	*
	84	* XXX This raises the question, whether we can do the same on
	85	* XXX sparc32 to get rid of fork_kpsr _and_ fork_kwim. The
	86	* XXX answer is yes. We stick fork_kpsr in UREG_G0 and
	87	* XXX fork_kwim in UREG_G1 (global registers are considered
	88	* XXX volatile across a system call in the sparc ABI I think
	89	* XXX if it isn't we can use regs->y instead, anyone who depends
	90	* XXX upon the Y register being preserved across a fork deserves
	91	* XXX to lose).
	92	*
	93	* In fact we should take advantage of that fact for other things
	94	* during system calls...
	95	*/
	96	.align 32
	97	sys_vfork: /* Under Linux, vfork and fork are just special cases of clone. */
	98	sethi %hi(0x4000 \| 0x0100 \| SIGCHLD), %o0
	99	or %o0, %lo(0x4000 \| 0x0100 \| SIGCHLD), %o0
	100	ba,pt %xcc, sys_clone
	101	sys_fork:
	102	clr %o1
	103	mov SIGCHLD, %o0
	104	sys_clone:
	105	flushw
	106	movrz %o1, %fp, %o1
	107	mov 0, %o3
	108	ba,pt %xcc, sparc_do_fork
	109	add %sp, PTREGS_OFF, %o2
	110
	111	.globl ret_from_syscall
	112	ret_from_syscall:
c7d5a005	113	/* Clear current_thread_info()->new_child. */
6eda3a75 DM	114	stb %g0, [%g6 + TI_NEW_CHILD]
	115	ldx [%g6 + TI_FLAGS], %l0
	116	call schedule_tail
	117	mov %g7, %o0
c7d5a005	118	ba,pt %xcc, ret_sys_call
6eda3a75 DM	119	ldx [%sp + PTREGS_OFF + PT_V9_I0], %o0
	120
	121	.globl sparc_exit
	122	.type sparc_exit,#function
	123	sparc_exit:
	124	rdpr %pstate, %g2
	125	wrpr %g2, PSTATE_IE, %pstate
	126	rdpr %otherwin, %g1
	127	rdpr %cansave, %g3
	128	add %g3, %g1, %g3
	129	wrpr %g3, 0x0, %cansave
	130	wrpr %g0, 0x0, %otherwin
	131	wrpr %g2, 0x0, %pstate
	132	ba,pt %xcc, sys_exit
	133	stb %g0, [%g6 + TI_WSAVED]
	134	.size sparc_exit,.-sparc_exit
	135
	136	linux_sparc_ni_syscall:
	137	sethi %hi(sys_ni_syscall), %l7
	138	ba,pt %xcc, 4f
	139	or %l7, %lo(sys_ni_syscall), %l7
	140
	141	linux_syscall_trace32:
fe06ccaa DM	142	call syscall_trace_enter
fe06ccaa DM	143	add %sp, PTREGS_OFF, %o0
73ccefab RM	144	brnz,pn %o0, 3f
73ccefab RM	145	mov -ENOSYS, %o0
6eda3a75 DM	146	srl %i0, 0, %o0
	147	srl %i4, 0, %o4
	148	srl %i1, 0, %o1
	149	srl %i2, 0, %o2
	150	ba,pt %xcc, 2f
	151	srl %i3, 0, %o3
	152
	153	linux_syscall_trace:
fe06ccaa DM	154	call syscall_trace_enter
fe06ccaa DM	155	add %sp, PTREGS_OFF, %o0
73ccefab RM	156	brnz,pn %o0, 3f
73ccefab RM	157	mov -ENOSYS, %o0
6eda3a75 DM	158	mov %i0, %o0
	159	mov %i1, %o1
	160	mov %i2, %o2
	161	mov %i3, %o3
	162	b,pt %xcc, 2f
	163	mov %i4, %o4
	164
	165
	166	/* Linux 32-bit system calls enter here... */
	167	.align 32
	168	.globl linux_sparc_syscall32
	169	linux_sparc_syscall32:
	170	/* Direct access to user regs, much faster. */
c658ad1b	171	cmp %g1, NR_syscalls ! IEU1 Group
6eda3a75 DM	172	bgeu,pn %xcc, linux_sparc_ni_syscall ! CTI
	173	srl %i0, 0, %o0 ! IEU0
	174	sll %g1, 2, %l4 ! IEU0 Group
	175	srl %i4, 0, %o4 ! IEU1
	176	lduw [%l7 + %l4], %l7 ! Load
	177	srl %i1, 0, %o1 ! IEU0 Group
	178	ldx [%g6 + TI_FLAGS], %l0 ! Load
	179
	180	srl %i5, 0, %o5 ! IEU1
	181	srl %i2, 0, %o2 ! IEU0 Group
c658ad1b	182	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT), %g0
6eda3a75 DM	183	bne,pn %icc, linux_syscall_trace32 ! CTI
	184	mov %i0, %l5 ! IEU1
	185	call %l7 ! CTI Group brk forced
	186	srl %i3, 0, %o3 ! IEU0
	187	ba,a,pt %xcc, 3f
	188
	189	/* Linux native system calls enter here... */
	190	.align 32
	191	.globl linux_sparc_syscall
	192	linux_sparc_syscall:
	193	/* Direct access to user regs, much faster. */
c658ad1b	194	cmp %g1, NR_syscalls ! IEU1 Group
6eda3a75 DM	195	bgeu,pn %xcc, linux_sparc_ni_syscall ! CTI
	196	mov %i0, %o0 ! IEU0
	197	sll %g1, 2, %l4 ! IEU0 Group
	198	mov %i1, %o1 ! IEU1
	199	lduw [%l7 + %l4], %l7 ! Load
	200	4: mov %i2, %o2 ! IEU0 Group
	201	ldx [%g6 + TI_FLAGS], %l0 ! Load
	202
	203	mov %i3, %o3 ! IEU1
	204	mov %i4, %o4 ! IEU0 Group
c658ad1b	205	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT), %g0
6eda3a75 DM	206	bne,pn %icc, linux_syscall_trace ! CTI Group
	207	mov %i0, %l5 ! IEU0
	208	2: call %l7 ! CTI Group brk forced
	209	mov %i5, %o5 ! IEU0
	210	nop
	211
	212	3: stx %o0, [%sp + PTREGS_OFF + PT_V9_I0]
	213	ret_sys_call:
	214	ldx [%sp + PTREGS_OFF + PT_V9_TSTATE], %g3
	215	ldx [%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc
	216	sra %o0, 0, %o0
	217	mov %ulo(TSTATE_XCARRY \| TSTATE_ICARRY), %g2
	218	sllx %g2, 32, %g2
	219
	220	/* Check if force_successful_syscall_return()
	221	* was invoked.
	222	*/
	223	ldub [%g6 + TI_SYS_NOERROR], %l2
	224	brnz,a,pn %l2, 80f
	225	stb %g0, [%g6 + TI_SYS_NOERROR]
	226
	227	cmp %o0, -ERESTART_RESTARTBLOCK
	228	bgeu,pn %xcc, 1f
c658ad1b	229	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT), %l6
6eda3a75 DM	230	80:
	231	/* System call success, clear Carry condition code. */
	232	andn %g3, %g2, %g3
	233	stx %g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]
	234	bne,pn %icc, linux_syscall_trace2
	235	add %l1, 0x4, %l2 ! npc = npc+4
	236	stx %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	237	ba,pt %xcc, rtrap
	238	stx %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
	239
	240	1:
	241	/* System call failure, set Carry condition code.
	242	* Also, get abs(errno) to return to the process.
	243	*/
c658ad1b	244	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT), %l6
6eda3a75 DM	245	sub %g0, %o0, %o0
	246	or %g3, %g2, %g3
	247	stx %o0, [%sp + PTREGS_OFF + PT_V9_I0]
	248	stx %g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]
	249	bne,pn %icc, linux_syscall_trace2
	250	add %l1, 0x4, %l2 ! npc = npc+4
	251	stx %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	252
	253	b,pt %xcc, rtrap
	254	stx %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
	255	linux_syscall_trace2:
fe06ccaa DM	256	call syscall_trace_leave
fe06ccaa DM	257	add %sp, PTREGS_OFF, %o0
6eda3a75 DM	258	stx %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	259	ba,pt %xcc, rtrap
	260	stx %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]