[net-next-2.6.git] / arch / s390 / kernel / head.S

/*
 * Copyright IBM Corp. 1999,2010
 *
 *    Author(s): Hartmut Penner <hp@de.ibm.com>
 *		 Martin Schwidefsky <schwidefsky@de.ibm.com>
 *		 Rob van der Heij <rvdhei@iae.nl>
 *		 Heiko Carstens <heiko.carstens@de.ibm.com>
 *
 * There are 5 different IPL methods
 *  1) load the image directly into ram at address 0 and do an PSW restart
 *  2) linload will load the image from address 0x10000 to memory 0x10000
 *     and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
 *  3) generate the tape ipl header, store the generated image on a tape
 *     and ipl from it
 *     In case of SL tape you need to IPL 5 times to get past VOL1 etc
 *  4) generate the vm reader ipl header, move the generated image to the
 *     VM reader (use option NOH!) and do a ipl from reader (VM only)
 *  5) direct call of start by the SALIPL loader
 *  We use the cpuid to distinguish between VM and native ipl
 *  params for kernel are pushed to 0x10400 (see setup.h)
 *
 */

#include <linux/init.h>
#include <asm/asm-offsets.h>
#include <asm/thread_info.h>
#include <asm/page.h>

#ifdef CONFIG_64BIT
#define ARCH_OFFSET	4
#else
#define ARCH_OFFSET	0
#endif

__HEAD
#ifndef CONFIG_IPL
	.org   0
	.long  0x00080000,0x80000000+startup	# Just a restart PSW
#else
#ifdef CONFIG_IPL_TAPE
#define IPL_BS 1024
	.org   0
	.long  0x00080000,0x80000000+iplstart	# The first 24 bytes are loaded
	.long  0x27000000,0x60000001		# by ipl to addresses 0-23.
	.long  0x02000000,0x20000000+IPL_BS	# (a PSW and two CCWs).
	.long  0x00000000,0x00000000		# external old psw
	.long  0x00000000,0x00000000		# svc old psw
	.long  0x00000000,0x00000000		# program check old psw
	.long  0x00000000,0x00000000		# machine check old psw
	.long  0x00000000,0x00000000		# io old psw
	.long  0x00000000,0x00000000
	.long  0x00000000,0x00000000
	.long  0x00000000,0x00000000
	.long  0x000a0000,0x00000058		# external new psw
	.long  0x000a0000,0x00000060		# svc new psw
	.long  0x000a0000,0x00000068		# program check new psw
	.long  0x000a0000,0x00000070		# machine check new psw
	.long  0x00080000,0x80000000+.Lioint	# io new psw

	.org   0x100
#
# subroutine for loading from tape
# Parameters:
#  R1 = device number
#  R2 = load address
.Lloader:
	st	%r14,.Lldret
	la	%r3,.Lorbread		# r3 = address of orb
	la	%r5,.Lirb		# r5 = address of irb
	st	%r2,.Lccwread+4 	# initialize CCW data addresses
	lctl	%c6,%c6,.Lcr6
	slr	%r2,%r2
.Lldlp:
	la	%r6,3			# 3 retries
.Lssch:
	ssch	0(%r3)			# load chunk of IPL_BS bytes
	bnz	.Llderr
.Lw4end:
	bas	%r14,.Lwait4io
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Lrecov
	slr	%r7,%r7
	icm	%r7,3,10(%r5)		# get residual count
	lcr	%r7,%r7
	la	%r7,IPL_BS(%r7) 	# IPL_BS-residual=#bytes read
	ar	%r2,%r7 		# add to total size
	tm	8(%r5),0x01		# found a tape mark ?
	bnz	.Ldone
	l	%r0,.Lccwread+4 	# update CCW data addresses
	ar	%r0,%r7
	st	%r0,.Lccwread+4
	b	.Lldlp
.Ldone:
	l	%r14,.Lldret
	br	%r14			# r2 contains the total size
.Lrecov:
	bas	%r14,.Lsense		# do the sensing
	bct	%r6,.Lssch		# dec. retry count & branch
	b	.Llderr
#
# Sense subroutine
#
.Lsense:
	st	%r14,.Lsnsret
	la	%r7,.Lorbsense
	ssch	0(%r7)			# start sense command
	bnz	.Llderr
	bas	%r14,.Lwait4io
	l	%r14,.Lsnsret
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Llderr
	br	%r14
#
# Wait for interrupt subroutine
#
.Lwait4io:
	lpsw	.Lwaitpsw
.Lioint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwait4io
	tsch	0(%r5)
	slr	%r0,%r0
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Lwtexit
	tm	8(%r5),0x04		# got device end ?
	bz	.Lwait4io
.Lwtexit:
	br	%r14
.Llderr:
	lpsw	.Lcrash

	.align	8
.Lorbread:
	.long	0x00000000,0x0080ff00,.Lccwread
	.align	8
.Lorbsense:
	.long	0x00000000,0x0080ff00,.Lccwsense
	.align	8
.Lccwread:
	.long	0x02200000+IPL_BS,0x00000000
.Lccwsense:
	.long	0x04200001,0x00000000
.Lwaitpsw:
	.long	0x020a0000,0x80000000+.Lioint

.Lirb:	.long	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.Lcr6:	.long	0xff000000
	.align	8
.Lcrash:.long	0x000a0000,0x00000000
.Lldret:.long	0
.Lsnsret: .long 0
#endif	/* CONFIG_IPL_TAPE */

#ifdef CONFIG_IPL_VM
#define IPL_BS	0x730
	.org	0
	.long	0x00080000,0x80000000+iplstart	# The first 24 bytes are loaded
	.long	0x02000018,0x60000050		# by ipl to addresses 0-23.
	.long	0x02000068,0x60000050		# (a PSW and two CCWs).
	.fill	80-24,1,0x40			# bytes 24-79 are discarded !!
	.long	0x020000f0,0x60000050		# The next 160 byte are loaded
	.long	0x02000140,0x60000050		# to addresses 0x18-0xb7
	.long	0x02000190,0x60000050		# They form the continuation
	.long	0x020001e0,0x60000050		# of the CCW program started
	.long	0x02000230,0x60000050		# by ipl and load the range
	.long	0x02000280,0x60000050		# 0x0f0-0x730 from the image
	.long	0x020002d0,0x60000050		# to the range 0x0f0-0x730
	.long	0x02000320,0x60000050		# in memory. At the end of
	.long	0x02000370,0x60000050		# the channel program the PSW
	.long	0x020003c0,0x60000050		# at location 0 is loaded.
	.long	0x02000410,0x60000050		# Initial processing starts
	.long	0x02000460,0x60000050		# at 0xf0 = iplstart.
	.long	0x020004b0,0x60000050
	.long	0x02000500,0x60000050
	.long	0x02000550,0x60000050
	.long	0x020005a0,0x60000050
	.long	0x020005f0,0x60000050
	.long	0x02000640,0x60000050
	.long	0x02000690,0x60000050
	.long	0x020006e0,0x20000050

	.org	0xf0
#
# subroutine for loading cards from the reader
#
.Lloader:
	la	%r3,.Lorb		# r2 = address of orb into r2
	la	%r5,.Lirb		# r4 = address of irb
	la	%r6,.Lccws
	la	%r7,20
.Linit:
	st	%r2,4(%r6)		# initialize CCW data addresses
	la	%r2,0x50(%r2)
	la	%r6,8(%r6)
	bct	7,.Linit

	lctl	%c6,%c6,.Lcr6		# set IO subclass mask
	slr	%r2,%r2
.Lldlp:
	ssch	0(%r3)			# load chunk of 1600 bytes
	bnz	.Llderr
.Lwait4irq:
	mvc	0x78(8),.Lnewpsw	# set up IO interrupt psw
	lpsw	.Lwaitpsw
.Lioint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwait4irq
	tsch	0(%r5)

	slr	%r0,%r0
	ic	%r0,8(%r5)		# get device status
	chi	%r0,8			# channel end ?
	be	.Lcont
	chi	%r0,12			# channel end + device end ?
	be	.Lcont

	l	%r0,4(%r5)
	s	%r0,8(%r3)		# r0/8 = number of ccws executed
	mhi	%r0,10			# *10 = number of bytes in ccws
	lh	%r3,10(%r5)		# get residual count
	sr	%r0,%r3 		# #ccws*80-residual=#bytes read
	ar	%r2,%r0

	br	%r14			# r2 contains the total size

.Lcont:
	ahi	%r2,0x640		# add 0x640 to total size
	la	%r6,.Lccws
	la	%r7,20
.Lincr:
	l	%r0,4(%r6)		# update CCW data addresses
	ahi	%r0,0x640
	st	%r0,4(%r6)
	ahi	%r6,8
	bct	7,.Lincr

	b	.Lldlp
.Llderr:
	lpsw	.Lcrash

	.align	8
.Lorb:	.long	0x00000000,0x0080ff00,.Lccws
.Lirb:	.long	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.Lcr6:	.long	0xff000000
.Lloadp:.long	0,0
	.align	8
.Lcrash:.long	0x000a0000,0x00000000
.Lnewpsw:
	.long	0x00080000,0x80000000+.Lioint
.Lwaitpsw:
	.long	0x020a0000,0x80000000+.Lioint

	.align	8
.Lccws: .rept	19
	.long	0x02600050,0x00000000
	.endr
	.long	0x02200050,0x00000000
#endif	/* CONFIG_IPL_VM */

iplstart:
	lh	%r1,0xb8		# test if subchannel number
	bct	%r1,.Lnoload		#  is valid
	l	%r1,0xb8		# load ipl subchannel number
	la	%r2,IPL_BS		# load start address
	bas	%r14,.Lloader		# load rest of ipl image
	l	%r12,.Lparm		# pointer to parameter area
	st	%r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number

#
# load parameter file from ipl device
#
.Lagain1:
	l	%r2,.Linitrd		# ramdisk loc. is temp
	bas	%r14,.Lloader		# load parameter file
	ltr	%r2,%r2 		# got anything ?
	bz	.Lnopf
	chi	%r2,895
	bnh	.Lnotrunc
	la	%r2,895
.Lnotrunc:
	l	%r4,.Linitrd
	clc	0(3,%r4),.L_hdr		# if it is HDRx
	bz	.Lagain1		# skip dataset header
	clc	0(3,%r4),.L_eof		# if it is EOFx
	bz	.Lagain1		# skip dateset trailer
	la	%r5,0(%r4,%r2)
	lr	%r3,%r2
	la	%r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
	mvc	0(256,%r3),0(%r4)
	mvc	256(256,%r3),256(%r4)
	mvc	512(256,%r3),512(%r4)
	mvc	768(122,%r3),768(%r4)
	slr	%r0,%r0
	b	.Lcntlp
.Ldelspc:
	ic	%r0,0(%r2,%r3)
	chi	%r0,0x20		# is it a space ?
	be	.Lcntlp
	ahi	%r2,1
	b	.Leolp
.Lcntlp:
	brct	%r2,.Ldelspc
.Leolp:
	slr	%r0,%r0
	stc	%r0,0(%r2,%r3)		# terminate buffer
.Lnopf:

#
# load ramdisk from ipl device
#
.Lagain2:
	l	%r2,.Linitrd		# addr of ramdisk
	st	%r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
	bas	%r14,.Lloader		# load ramdisk
	st	%r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of rd
	ltr	%r2,%r2
	bnz	.Lrdcont
	st	%r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
.Lrdcont:
	l	%r2,.Linitrd

	clc	0(3,%r2),.L_hdr		# skip HDRx and EOFx
	bz	.Lagain2
	clc	0(3,%r2),.L_eof
	bz	.Lagain2

#ifdef CONFIG_IPL_VM
#
# reset files in VM reader
#
	stidp	__LC_CPUID		# store cpuid
	tm	__LC_CPUID,0xff 	# running VM ?
	bno	.Lnoreset
	la	%r2,.Lreset
	lhi	%r3,26
	diag	%r2,%r3,8
	la	%r5,.Lirb
	stsch	0(%r5)			# check if irq is pending
	tm	30(%r5),0x0f		# by verifying if any of the
	bnz	.Lwaitforirq		# activity or status control
	tm	31(%r5),0xff		# bits is set in the schib
	bz	.Lnoreset
.Lwaitforirq:
	mvc	0x78(8),.Lrdrnewpsw	# set up IO interrupt psw
.Lwaitrdrirq:
	lpsw	.Lrdrwaitpsw
.Lrdrint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwaitrdrirq
	la	%r5,.Lirb
	tsch	0(%r5)
.Lnoreset:
	b	.Lnoload

	.align	8
.Lrdrnewpsw:
	.long	0x00080000,0x80000000+.Lrdrint
.Lrdrwaitpsw:
	.long	0x020a0000,0x80000000+.Lrdrint
#endif

#
# everything loaded, go for it
#
.Lnoload:
	l	%r1,.Lstartup
	br	%r1

.Linitrd:.long _end + 0x400000		# default address of initrd
.Lparm:	.long  PARMAREA
.Lstartup: .long startup
.Lreset:.byte	0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
	.byte	0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
	.byte	0xc8,0xd6,0xd3,0xc4	# "change rdr all keep nohold"
.L_eof: .long	0xc5d6c600	 /* C'EOF' */
.L_hdr: .long	0xc8c4d900	 /* C'HDR' */

#endif	/* CONFIG_IPL */

#
# SALIPL loader support. Based on a patch by Rob van der Heij.
# This entry point is called directly from the SALIPL loader and
# doesn't need a builtin ipl record.
#
	.org	0x800
	.globl	start
start:
	stm	%r0,%r15,0x07b0		# store registers
	basr	%r12,%r0
.base:
	l	%r11,.parm
	l	%r8,.cmd		# pointer to command buffer

	ltr	%r9,%r9			# do we have SALIPL parameters?
	bp	.sk8x8

	mvc	0(64,%r8),0x00b0	# copy saved registers
	xc	64(240-64,%r8),0(%r8)	# remainder of buffer
	tr	0(64,%r8),.lowcase
	b	.gotr
.sk8x8:
	mvc	0(240,%r8),0(%r9)	# copy iplparms into buffer
.gotr:
	slr	%r0,%r0
	st	%r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
	st	%r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
	j	startup 		# continue with startup
.cmd:	.long	COMMAND_LINE		# address of command line buffer
.parm:	.long	PARMAREA
.lowcase:
	.byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
	.byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
	.byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
	.byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
	.byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
	.byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
	.byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
	.byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
	.byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
	.byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
	.byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
	.byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
	.byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
	.byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
	.byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
	.byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f

	.byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
	.byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
	.byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
	.byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
	.byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
	.byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
	.byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
	.byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
	.byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87	# .abcdefg
	.byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf	# hi
	.byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97	# .jklmnop
	.byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf	# qr
	.byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7	# ..stuvwx
	.byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef	# yz
	.byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
	.byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff

#
# startup-code at 0x10000, running in absolute addressing mode
# this is called either by the ipl loader or directly by PSW restart
# or linload or SALIPL
#
	.org	0x10000
	.globl	startup
startup:
	basr	%r13,0			# get base
.LPG0:
	xc	0x200(256),0x200	# partially clear lowcore
	xc	0x300(256),0x300
	stck	__LC_LAST_UPDATE_CLOCK
	spt	5f-.LPG0(%r13)
	mvc	__LC_LAST_UPDATE_TIMER(8),5f-.LPG0(%r13)
#ifndef CONFIG_MARCH_G5
	# check capabilities against MARCH_{G5,Z900,Z990,Z9_109,Z10}
	xc	__LC_STFL_FAC_LIST(8),__LC_STFL_FAC_LIST
	stfl	__LC_STFL_FAC_LIST	# store facility list
	tm	__LC_STFL_FAC_LIST,0x01	# stfle available ?
	jz	0f
	la	%r0,0
	.insn	s,0xb2b00000,__LC_STFL_FAC_LIST	# store facility list extended
0:	l	%r0,__LC_STFL_FAC_LIST
	n	%r0,2f+8-.LPG0(%r13)
	cl	%r0,2f+8-.LPG0(%r13)
	jne	1f
	l	%r0,__LC_STFL_FAC_LIST+4
	n	%r0,2f+12-.LPG0(%r13)
	cl	%r0,2f+12-.LPG0(%r13)
	je	3f
1:	l	%r15,.Lstack-.LPG0(%r13)
	ahi	%r15,-96
	la	%r2,.Lals_string-.LPG0(%r13)
	l	%r3,.Lsclp_print-.LPG0(%r13)
	basr	%r14,%r3
	lpsw	2f-.LPG0(%r13)		# machine type not good enough, crash
.Lals_string:
	.asciz	"The Linux kernel requires more recent processor hardware"
.Lsclp_print:
	.long	_sclp_print_early
.Lstack:
	.long	0x8000 + (1<<(PAGE_SHIFT+THREAD_ORDER))
	.align 16
2:	.long	0x000a0000,0x8badcccc
#if defined(CONFIG_64BIT)
#if defined(CONFIG_MARCH_Z10)
	.long 0xc100efe3, 0xf0680000
#elif defined(CONFIG_MARCH_Z9_109)
	.long 0xc100efc3, 0x00000000
#elif defined(CONFIG_MARCH_Z990)
	.long 0xc0002000, 0x00000000
#elif defined(CONFIG_MARCH_Z900)
	.long 0xc0000000, 0x00000000
#endif
#else
#if defined(CONFIG_MARCH_Z10)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z9_109)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z990)
	.long 0x80002000, 0x00000000
#elif defined(CONFIG_MARCH_Z900)
	.long 0x80000000, 0x00000000
#endif
#endif
3:
#endif

#ifdef CONFIG_64BIT
	mvi	__LC_AR_MODE_ID,1	# set esame flag
	slr	%r0,%r0 		# set cpuid to zero
	lhi	%r1,2			# mode 2 = esame (dump)
	sigp	%r1,%r0,0x12		# switch to esame mode
	sam64				# switch to 64 bit mode
	jg	startup_continue
#else
	mvi	__LC_AR_MODE_ID,0	# set ESA flag (mode 0)
	l	%r13,4f-.LPG0(%r13)
	b	0(%r13)
	.align	8
4:	.long	startup_continue
#endif
	.align	8
5:	.long	0x7fffffff,0xffffffff

#
# params at 10400 (setup.h)
#
	.org	PARMAREA
	.long	0,0			# IPL_DEVICE
	.long	0,0			# INITRD_START
	.long	0,0			# INITRD_SIZE

	.org	COMMAND_LINE
	.byte	"root=/dev/ram0 ro"
	.byte	0

	.org	0x11000
Commit	Line	Data
1da177e4	1	/*
1844c9bc	2	* Copyright IBM Corp. 1999,2010
0ad775db HC	3	*
	4	* Author(s): Hartmut Penner <hp@de.ibm.com>
	5	* Martin Schwidefsky <schwidefsky@de.ibm.com>
	6	* Rob van der Heij <rvdhei@iae.nl>
	7	* Heiko Carstens <heiko.carstens@de.ibm.com>
1da177e4 LT	8	*
	9	* There are 5 different IPL methods
	10	* 1) load the image directly into ram at address 0 and do an PSW restart
	11	* 2) linload will load the image from address 0x10000 to memory 0x10000
	12	* and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
	13	* 3) generate the tape ipl header, store the generated image on a tape
	14	* and ipl from it
	15	* In case of SL tape you need to IPL 5 times to get past VOL1 etc
	16	* 4) generate the vm reader ipl header, move the generated image to the
	17	* VM reader (use option NOH!) and do a ipl from reader (VM only)
	18	* 5) direct call of start by the SALIPL loader
	19	* We use the cpuid to distinguish between VM and native ipl
	20	* params for kernel are pushed to 0x10400 (see setup.h)
0ad775db	21	*
1da177e4 LT	22	*/
1da177e4 LT	23
2133bb8d	24	#include <linux/init.h>
0013a854	25	#include <asm/asm-offsets.h>
1da177e4 LT	26	#include <asm/thread_info.h>
	27	#include <asm/page.h>
	28
347a8dc3	29	#ifdef CONFIG_64BIT
0ad775db HC	30	#define ARCH_OFFSET 4
	31	#else
	32	#define ARCH_OFFSET 0
	33	#endif
	34
2133bb8d	35	__HEAD
1da177e4	36	#ifndef CONFIG_IPL
25d83cbf HC	37	.org 0
25d83cbf HC	38	.long 0x00080000,0x80000000+startup # Just a restart PSW
1da177e4 LT	39	#else
	40	#ifdef CONFIG_IPL_TAPE
	41	#define IPL_BS 1024
25d83cbf HC	42	.org 0
	43	.long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
	44	.long 0x27000000,0x60000001 # by ipl to addresses 0-23.
	45	.long 0x02000000,0x20000000+IPL_BS # (a PSW and two CCWs).
	46	.long 0x00000000,0x00000000 # external old psw
	47	.long 0x00000000,0x00000000 # svc old psw
	48	.long 0x00000000,0x00000000 # program check old psw
	49	.long 0x00000000,0x00000000 # machine check old psw
	50	.long 0x00000000,0x00000000 # io old psw
	51	.long 0x00000000,0x00000000
	52	.long 0x00000000,0x00000000
	53	.long 0x00000000,0x00000000
	54	.long 0x000a0000,0x00000058 # external new psw
	55	.long 0x000a0000,0x00000060 # svc new psw
	56	.long 0x000a0000,0x00000068 # program check new psw
	57	.long 0x000a0000,0x00000070 # machine check new psw
	58	.long 0x00080000,0x80000000+.Lioint # io new psw
1da177e4	59
25d83cbf	60	.org 0x100
1da177e4 LT	61	#
1da177e4 LT	62	# subroutine for loading from tape
98a1708d	63	# Parameters:
1da177e4 LT	64	# R1 = device number
1da177e4 LT	65	# R2 = load address
25d83cbf HC	66	.Lloader:
	67	st %r14,.Lldret
	68	la %r3,.Lorbread # r3 = address of orb
	69	la %r5,.Lirb # r5 = address of irb
	70	st %r2,.Lccwread+4 # initialize CCW data addresses
	71	lctl %c6,%c6,.Lcr6
	72	slr %r2,%r2
1da177e4	73	.Lldlp:
25d83cbf	74	la %r6,3 # 3 retries
1da177e4	75	.Lssch:
25d83cbf HC	76	ssch 0(%r3) # load chunk of IPL_BS bytes
25d83cbf HC	77	bnz .Llderr
1da177e4	78	.Lw4end:
25d83cbf HC	79	bas %r14,.Lwait4io
	80	tm 8(%r5),0x82 # do we have a problem ?
	81	bnz .Lrecov
	82	slr %r7,%r7
	83	icm %r7,3,10(%r5) # get residual count
	84	lcr %r7,%r7
	85	la %r7,IPL_BS(%r7) # IPL_BS-residual=#bytes read
	86	ar %r2,%r7 # add to total size
	87	tm 8(%r5),0x01 # found a tape mark ?
	88	bnz .Ldone
	89	l %r0,.Lccwread+4 # update CCW data addresses
	90	ar %r0,%r7
	91	st %r0,.Lccwread+4
	92	b .Lldlp
1da177e4	93	.Ldone:
25d83cbf HC	94	l %r14,.Lldret
25d83cbf HC	95	br %r14 # r2 contains the total size
1da177e4	96	.Lrecov:
25d83cbf HC	97	bas %r14,.Lsense # do the sensing
	98	bct %r6,.Lssch # dec. retry count & branch
	99	b .Llderr
1da177e4 LT	100	#
	101	# Sense subroutine
	102	#
	103	.Lsense:
25d83cbf HC	104	st %r14,.Lsnsret
	105	la %r7,.Lorbsense
	106	ssch 0(%r7) # start sense command
	107	bnz .Llderr
	108	bas %r14,.Lwait4io
	109	l %r14,.Lsnsret
	110	tm 8(%r5),0x82 # do we have a problem ?
	111	bnz .Llderr
	112	br %r14
1da177e4 LT	113	#
	114	# Wait for interrupt subroutine
	115	#
	116	.Lwait4io:
25d83cbf	117	lpsw .Lwaitpsw
1da177e4	118	.Lioint:
25d83cbf HC	119	c %r1,0xb8 # compare subchannel number
	120	bne .Lwait4io
	121	tsch 0(%r5)
	122	slr %r0,%r0
	123	tm 8(%r5),0x82 # do we have a problem ?
	124	bnz .Lwtexit
	125	tm 8(%r5),0x04 # got device end ?
	126	bz .Lwait4io
1da177e4	127	.Lwtexit:
25d83cbf	128	br %r14
1da177e4	129	.Llderr:
25d83cbf	130	lpsw .Lcrash
1da177e4	131
25d83cbf	132	.align 8
1da177e4	133	.Lorbread:
25d83cbf HC	134	.long 0x00000000,0x0080ff00,.Lccwread
25d83cbf HC	135	.align 8
1da177e4	136	.Lorbsense:
25d83cbf HC	137	.long 0x00000000,0x0080ff00,.Lccwsense
25d83cbf HC	138	.align 8
1da177e4	139	.Lccwread:
25d83cbf	140	.long 0x02200000+IPL_BS,0x00000000
1da177e4	141	.Lccwsense:
25d83cbf	142	.long 0x04200001,0x00000000
1da177e4	143	.Lwaitpsw:
25d83cbf	144	.long 0x020a0000,0x80000000+.Lioint
1da177e4	145
25d83cbf HC	146	.Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
	147	.Lcr6: .long 0xff000000
	148	.align 8
	149	.Lcrash:.long 0x000a0000,0x00000000
	150	.Lldret:.long 0
1da177e4	151	.Lsnsret: .long 0
25d83cbf	152	#endif /* CONFIG_IPL_TAPE */
1da177e4 LT	153
1da177e4 LT	154	#ifdef CONFIG_IPL_VM
25d83cbf HC	155	#define IPL_BS 0x730
	156	.org 0
	157	.long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
	158	.long 0x02000018,0x60000050 # by ipl to addresses 0-23.
	159	.long 0x02000068,0x60000050 # (a PSW and two CCWs).
	160	.fill 80-24,1,0x40 # bytes 24-79 are discarded !!
	161	.long 0x020000f0,0x60000050 # The next 160 byte are loaded
	162	.long 0x02000140,0x60000050 # to addresses 0x18-0xb7
	163	.long 0x02000190,0x60000050 # They form the continuation
	164	.long 0x020001e0,0x60000050 # of the CCW program started
	165	.long 0x02000230,0x60000050 # by ipl and load the range
	166	.long 0x02000280,0x60000050 # 0x0f0-0x730 from the image
	167	.long 0x020002d0,0x60000050 # to the range 0x0f0-0x730
	168	.long 0x02000320,0x60000050 # in memory. At the end of
	169	.long 0x02000370,0x60000050 # the channel program the PSW
	170	.long 0x020003c0,0x60000050 # at location 0 is loaded.
	171	.long 0x02000410,0x60000050 # Initial processing starts
	172	.long 0x02000460,0x60000050 # at 0xf0 = iplstart.
	173	.long 0x020004b0,0x60000050
	174	.long 0x02000500,0x60000050
	175	.long 0x02000550,0x60000050
	176	.long 0x020005a0,0x60000050
	177	.long 0x020005f0,0x60000050
	178	.long 0x02000640,0x60000050
	179	.long 0x02000690,0x60000050
	180	.long 0x020006e0,0x20000050
1da177e4	181
25d83cbf	182	.org 0xf0
1da177e4 LT	183	#
	184	# subroutine for loading cards from the reader
	185	#
25d83cbf HC	186	.Lloader:
	187	la %r3,.Lorb # r2 = address of orb into r2
	188	la %r5,.Lirb # r4 = address of irb
	189	la %r6,.Lccws
	190	la %r7,20
1da177e4	191	.Linit:
25d83cbf HC	192	st %r2,4(%r6) # initialize CCW data addresses
	193	la %r2,0x50(%r2)
	194	la %r6,8(%r6)
	195	bct 7,.Linit
1da177e4	196
25d83cbf HC	197	lctl %c6,%c6,.Lcr6 # set IO subclass mask
25d83cbf HC	198	slr %r2,%r2
1da177e4	199	.Lldlp:
25d83cbf HC	200	ssch 0(%r3) # load chunk of 1600 bytes
25d83cbf HC	201	bnz .Llderr
1da177e4	202	.Lwait4irq:
25d83cbf HC	203	mvc 0x78(8),.Lnewpsw # set up IO interrupt psw
25d83cbf HC	204	lpsw .Lwaitpsw
1da177e4	205	.Lioint:
25d83cbf HC	206	c %r1,0xb8 # compare subchannel number
	207	bne .Lwait4irq
	208	tsch 0(%r5)
1da177e4	209
25d83cbf HC	210	slr %r0,%r0
	211	ic %r0,8(%r5) # get device status
	212	chi %r0,8 # channel end ?
	213	be .Lcont
	214	chi %r0,12 # channel end + device end ?
	215	be .Lcont
1da177e4	216
25d83cbf HC	217	l %r0,4(%r5)
	218	s %r0,8(%r3) # r0/8 = number of ccws executed
	219	mhi %r0,10 # *10 = number of bytes in ccws
	220	lh %r3,10(%r5) # get residual count
	221	sr %r0,%r3 # #ccws*80-residual=#bytes read
	222	ar %r2,%r0
	223
	224	br %r14 # r2 contains the total size
1da177e4 LT	225
1da177e4 LT	226	.Lcont:
25d83cbf HC	227	ahi %r2,0x640 # add 0x640 to total size
	228	la %r6,.Lccws
	229	la %r7,20
1da177e4	230	.Lincr:
25d83cbf HC	231	l %r0,4(%r6) # update CCW data addresses
	232	ahi %r0,0x640
	233	st %r0,4(%r6)
	234	ahi %r6,8
	235	bct 7,.Lincr
1da177e4	236
25d83cbf	237	b .Lldlp
1da177e4	238	.Llderr:
25d83cbf	239	lpsw .Lcrash
1da177e4	240
25d83cbf HC	241	.align 8
	242	.Lorb: .long 0x00000000,0x0080ff00,.Lccws
	243	.Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
	244	.Lcr6: .long 0xff000000
	245	.Lloadp:.long 0,0
	246	.align 8
	247	.Lcrash:.long 0x000a0000,0x00000000
1da177e4	248	.Lnewpsw:
25d83cbf	249	.long 0x00080000,0x80000000+.Lioint
1da177e4	250	.Lwaitpsw:
25d83cbf	251	.long 0x020a0000,0x80000000+.Lioint
1da177e4	252
25d83cbf HC	253	.align 8
	254	.Lccws: .rept 19
	255	.long 0x02600050,0x00000000
	256	.endr
	257	.long 0x02200050,0x00000000
	258	#endif /* CONFIG_IPL_VM */
1da177e4 LT	259
1da177e4 LT	260	iplstart:
25d83cbf HC	261	lh %r1,0xb8 # test if subchannel number
	262	bct %r1,.Lnoload # is valid
	263	l %r1,0xb8 # load ipl subchannel number
	264	la %r2,IPL_BS # load start address
	265	bas %r14,.Lloader # load rest of ipl image
	266	l %r12,.Lparm # pointer to parameter area
	267	st %r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number
1da177e4 LT	268
	269	#
	270	# load parameter file from ipl device
	271	#
	272	.Lagain1:
25d83cbf HC	273	l %r2,.Linitrd # ramdisk loc. is temp
	274	bas %r14,.Lloader # load parameter file
	275	ltr %r2,%r2 # got anything ?
	276	bz .Lnopf
	277	chi %r2,895
	278	bnh .Lnotrunc
	279	la %r2,895
1da177e4	280	.Lnotrunc:
25d83cbf HC	281	l %r4,.Linitrd
	282	clc 0(3,%r4),.L_hdr # if it is HDRx
	283	bz .Lagain1 # skip dataset header
	284	clc 0(3,%r4),.L_eof # if it is EOFx
	285	bz .Lagain1 # skip dateset trailer
	286	la %r5,0(%r4,%r2)
	287	lr %r3,%r2
61fd330d	288	la %r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
25d83cbf HC	289	mvc 0(256,%r3),0(%r4)
	290	mvc 256(256,%r3),256(%r4)
	291	mvc 512(256,%r3),512(%r4)
	292	mvc 768(122,%r3),768(%r4)
	293	slr %r0,%r0
	294	b .Lcntlp
1da177e4	295	.Ldelspc:
25d83cbf HC	296	ic %r0,0(%r2,%r3)
	297	chi %r0,0x20 # is it a space ?
	298	be .Lcntlp
	299	ahi %r2,1
	300	b .Leolp
1da177e4	301	.Lcntlp:
25d83cbf	302	brct %r2,.Ldelspc
1da177e4	303	.Leolp:
25d83cbf HC	304	slr %r0,%r0
25d83cbf HC	305	stc %r0,0(%r2,%r3) # terminate buffer
1da177e4 LT	306	.Lnopf:
	307
	308	#
	309	# load ramdisk from ipl device
25d83cbf	310	#
1da177e4	311	.Lagain2:
25d83cbf HC	312	l %r2,.Linitrd # addr of ramdisk
	313	st %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
	314	bas %r14,.Lloader # load ramdisk
	315	st %r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of rd
	316	ltr %r2,%r2
	317	bnz .Lrdcont
	318	st %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
1da177e4	319	.Lrdcont:
25d83cbf	320	l %r2,.Linitrd
1da177e4	321
25d83cbf HC	322	clc 0(3,%r2),.L_hdr # skip HDRx and EOFx
	323	bz .Lagain2
	324	clc 0(3,%r2),.L_eof
	325	bz .Lagain2
1da177e4 LT	326
	327	#ifdef CONFIG_IPL_VM
	328	#
	329	# reset files in VM reader
	330	#
25d83cbf HC	331	stidp __LC_CPUID # store cpuid
	332	tm __LC_CPUID,0xff # running VM ?
	333	bno .Lnoreset
	334	la %r2,.Lreset
	335	lhi %r3,26
	336	diag %r2,%r3,8
	337	la %r5,.Lirb
	338	stsch 0(%r5) # check if irq is pending
	339	tm 30(%r5),0x0f # by verifying if any of the
	340	bnz .Lwaitforirq # activity or status control
	341	tm 31(%r5),0xff # bits is set in the schib
	342	bz .Lnoreset
350e3ade	343	.Lwaitforirq:
25d83cbf	344	mvc 0x78(8),.Lrdrnewpsw # set up IO interrupt psw
2b071886	345	.Lwaitrdrirq:
25d83cbf	346	lpsw .Lrdrwaitpsw
2b071886	347	.Lrdrint:
25d83cbf HC	348	c %r1,0xb8 # compare subchannel number
	349	bne .Lwaitrdrirq
	350	la %r5,.Lirb
	351	tsch 0(%r5)
1da177e4	352	.Lnoreset:
25d83cbf	353	b .Lnoload
2b071886	354
25d83cbf	355	.align 8
2b071886	356	.Lrdrnewpsw:
25d83cbf	357	.long 0x00080000,0x80000000+.Lrdrint
2b071886	358	.Lrdrwaitpsw:
25d83cbf	359	.long 0x020a0000,0x80000000+.Lrdrint
1da177e4	360	#endif
2b071886	361
1da177e4 LT	362	#
	363	# everything loaded, go for it
	364	#
	365	.Lnoload:
25d83cbf HC	366	l %r1,.Lstartup
25d83cbf HC	367	br %r1
1da177e4	368
25d83cbf	369	.Linitrd:.long _end + 0x400000 # default address of initrd
1da177e4 LT	370	.Lparm: .long PARMAREA
1da177e4 LT	371	.Lstartup: .long startup
25d83cbf HC	372	.Lreset:.byte 0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
	373	.byte 0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
	374	.byte 0xc8,0xd6,0xd3,0xc4 # "change rdr all keep nohold"
	375	.L_eof: .long 0xc5d6c600 /* C'EOF' */
	376	.L_hdr: .long 0xc8c4d900 /* C'HDR' */
1da177e4	377
25d83cbf	378	#endif /* CONFIG_IPL */
1da177e4 LT	379
	380	#
	381	# SALIPL loader support. Based on a patch by Rob van der Heij.
	382	# This entry point is called directly from the SALIPL loader and
	383	# doesn't need a builtin ipl record.
	384	#
25d83cbf HC	385	.org 0x800
25d83cbf HC	386	.globl start
1da177e4	387	start:
25d83cbf HC	388	stm %r0,%r15,0x07b0 # store registers
25d83cbf HC	389	basr %r12,%r0
1da177e4	390	.base:
25d83cbf HC	391	l %r11,.parm
25d83cbf HC	392	l %r8,.cmd # pointer to command buffer
1da177e4	393
25d83cbf HC	394	ltr %r9,%r9 # do we have SALIPL parameters?
25d83cbf HC	395	bp .sk8x8
1da177e4	396
25d83cbf HC	397	mvc 0(64,%r8),0x00b0 # copy saved registers
	398	xc 64(240-64,%r8),0(%r8) # remainder of buffer
	399	tr 0(64,%r8),.lowcase
	400	b .gotr
1da177e4	401	.sk8x8:
25d83cbf	402	mvc 0(240,%r8),0(%r9) # copy iplparms into buffer
1da177e4	403	.gotr:
25d83cbf HC	404	slr %r0,%r0
	405	st %r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
	406	st %r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
	407	j startup # continue with startup
25d83cbf HC	408	.cmd: .long COMMAND_LINE # address of command line buffer
25d83cbf HC	409	.parm: .long PARMAREA
1da177e4	410	.lowcase:
25d83cbf	411	.byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
1da177e4	412	.byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
25d83cbf	413	.byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
1da177e4	414	.byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
25d83cbf	415	.byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
1da177e4	416	.byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
25d83cbf	417	.byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
1da177e4	418	.byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
25d83cbf	419	.byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
1da177e4	420	.byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
25d83cbf	421	.byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
1da177e4	422	.byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
25d83cbf	423	.byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
1da177e4	424	.byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
25d83cbf	425	.byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
1da177e4 LT	426	.byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f
1da177e4 LT	427
25d83cbf	428	.byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
1da177e4	429	.byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
25d83cbf	430	.byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
1da177e4	431	.byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
25d83cbf	432	.byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
1da177e4	433	.byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
25d83cbf	434	.byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
1da177e4	435	.byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
25d83cbf	436	.byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87 # .abcdefg
1da177e4	437	.byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf # hi
25d83cbf	438	.byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97 # .jklmnop
1da177e4 LT	439	.byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf # qr
	440	.byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7 # ..stuvwx
	441	.byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef # yz
25d83cbf	442	.byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
1da177e4 LT	443	.byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff
1da177e4 LT	444
e37f50e1 MS	445	#
	446	# startup-code at 0x10000, running in absolute addressing mode
	447	# this is called either by the ipl loader or directly by PSW restart
	448	# or linload or SALIPL
	449	#
	450	.org 0x10000
1844c9bc MS	451	.globl startup
	452	startup:
	453	basr %r13,0 # get base
e37f50e1	454	.LPG0:
866ba284 MS	455	xc 0x200(256),0x200 # partially clear lowcore
866ba284 MS	456	xc 0x300(256),0x300
1844c9bc MS	457	stck __LC_LAST_UPDATE_CLOCK
	458	spt 5f-.LPG0(%r13)
	459	mvc __LC_LAST_UPDATE_TIMER(8),5f-.LPG0(%r13)
e37f50e1	460	#ifndef CONFIG_MARCH_G5
8c4caa4f MS	461	# check capabilities against MARCH_{G5,Z900,Z990,Z9_109,Z10}
	462	xc __LC_STFL_FAC_LIST(8),__LC_STFL_FAC_LIST
	463	stfl __LC_STFL_FAC_LIST # store facility list
	464	tm __LC_STFL_FAC_LIST,0x01 # stfle available ?
	465	jz 0f
	466	la %r0,0
	467	.insn s,0xb2b00000,__LC_STFL_FAC_LIST # store facility list extended
	468	0: l %r0,__LC_STFL_FAC_LIST
	469	n %r0,2f+8-.LPG0(%r13)
	470	cl %r0,2f+8-.LPG0(%r13)
	471	jne 1f
	472	l %r0,__LC_STFL_FAC_LIST+4
	473	n %r0,2f+12-.LPG0(%r13)
	474	cl %r0,2f+12-.LPG0(%r13)
	475	je 3f
d90cbd46	476	1: l %r15,.Lstack-.LPG0(%r13)
d90cbd46 HC	477	ahi %r15,-96
	478	la %r2,.Lals_string-.LPG0(%r13)
	479	l %r3,.Lsclp_print-.LPG0(%r13)
	480	basr %r14,%r3
	481	lpsw 2f-.LPG0(%r13) # machine type not good enough, crash
	482	.Lals_string:
	483	.asciz "The Linux kernel requires more recent processor hardware"
	484	.Lsclp_print:
	485	.long _sclp_print_early
	486	.Lstack:
1844c9bc	487	.long 0x8000 + (1<<(PAGE_SHIFT+THREAD_ORDER))
e37f50e1	488	.align 16
8c4caa4f MS	489	2: .long 0x000a0000,0x8badcccc
	490	#if defined(CONFIG_64BIT)
	491	#if defined(CONFIG_MARCH_Z10)
	492	.long 0xc100efe3, 0xf0680000
	493	#elif defined(CONFIG_MARCH_Z9_109)
	494	.long 0xc100efc3, 0x00000000
	495	#elif defined(CONFIG_MARCH_Z990)
	496	.long 0xc0002000, 0x00000000
	497	#elif defined(CONFIG_MARCH_Z900)
	498	.long 0xc0000000, 0x00000000
	499	#endif
	500	#else
e37f50e1	501	#if defined(CONFIG_MARCH_Z10)
8c4caa4f	502	.long 0x8100c880, 0x00000000
e37f50e1	503	#elif defined(CONFIG_MARCH_Z9_109)
8c4caa4f	504	.long 0x8100c880, 0x00000000
e37f50e1	505	#elif defined(CONFIG_MARCH_Z990)
8c4caa4f	506	.long 0x80002000, 0x00000000
e37f50e1	507	#elif defined(CONFIG_MARCH_Z900)
8c4caa4f MS	508	.long 0x80000000, 0x00000000
8c4caa4f MS	509	#endif
e37f50e1	510	#endif
8c4caa4f	511	3:
e37f50e1 MS	512	#endif
e37f50e1 MS	513
1844c9bc MS	514	#ifdef CONFIG_64BIT
	515	mvi __LC_AR_MODE_ID,1 # set esame flag
	516	slr %r0,%r0 # set cpuid to zero
	517	lhi %r1,2 # mode 2 = esame (dump)
	518	sigp %r1,%r0,0x12 # switch to esame mode
	519	sam64 # switch to 64 bit mode
	520	jg startup_continue
	521	#else
	522	mvi __LC_AR_MODE_ID,0 # set ESA flag (mode 0)
b6112ccb	523	l %r13,4f-.LPG0(%r13)
e37f50e1	524	b 0(%r13)
1844c9bc	525	.align 8
b6112ccb	526	4: .long startup_continue
1844c9bc	527	#endif
ab96e798	528	.align 8
1844c9bc	529	5: .long 0x7fffffff,0xffffffff
e37f50e1 MS	530
	531	#
	532	# params at 10400 (setup.h)
	533	#
	534	.org PARMAREA
	535	.long 0,0 # IPL_DEVICE
	536	.long 0,0 # INITRD_START
	537	.long 0,0 # INITRD_SIZE
	538
	539	.org COMMAND_LINE
	540	.byte "root=/dev/ram0 ro"
	541	.byte 0
	542
1844c9bc	543	.org 0x11000