[net-next-2.6.git] / arch / ia64 / kernel / gate.lds.S

/*
 * Linker script for gate DSO.  The gate pages are an ELF shared object
 * prelinked to its virtual address, with only one read-only segment and
 * one execute-only segment (both fit in one page).  This script controls
 * its layout.
 */


#include <asm/system.h>
#include "paravirt_patchlist.h"

SECTIONS
{
	. = GATE_ADDR + SIZEOF_HEADERS;

	.hash			: { *(.hash) }		:readable
	.gnu.hash		: { *(.gnu.hash) }
	.dynsym			: { *(.dynsym) }
	.dynstr			: { *(.dynstr) }
	.gnu.version		: { *(.gnu.version) }
	.gnu.version_d		: { *(.gnu.version_d) }
	.gnu.version_r		: { *(.gnu.version_r) }

	.note			: { *(.note*) }		:readable	:note

	.dynamic		: { *(.dynamic) }	:readable	:dynamic

	/*
	 * This linker script is used both with -r and with -shared.  For
	 * the layouts to match, we need to skip more than enough space for
	 * the dynamic symbol table et al.  If this amount is insufficient,
	 * ld -shared will barf.  Just increase it here.
	 */
	. = GATE_ADDR + 0x600;

	.data..patch		: {
		__paravirt_start_gate_mckinley_e9_patchlist = .;
		*(.data..patch.mckinley_e9)
		__paravirt_end_gate_mckinley_e9_patchlist = .;

		__paravirt_start_gate_vtop_patchlist = .;
		*(.data..patch.vtop)
		__paravirt_end_gate_vtop_patchlist = .;

		__paravirt_start_gate_fsyscall_patchlist = .;
		*(.data..patch.fsyscall_table)
		__paravirt_end_gate_fsyscall_patchlist = .;

		__paravirt_start_gate_brl_fsys_bubble_down_patchlist = .;
		*(.data..patch.brl_fsys_bubble_down)
		__paravirt_end_gate_brl_fsys_bubble_down_patchlist = .;
	}						:readable

	.IA_64.unwind_info	: { *(.IA_64.unwind_info*) }
	.IA_64.unwind		: { *(.IA_64.unwind*) }	:readable	:unwind
#ifdef HAVE_BUGGY_SEGREL
	.text (GATE_ADDR + PAGE_SIZE) : { *(.text) *(.text.*) }	:readable
#else
	. = ALIGN(PERCPU_PAGE_SIZE) + (. & (PERCPU_PAGE_SIZE - 1));
	.text			: { *(.text) *(.text.*) }	:epc
#endif

	/DISCARD/		: {
		*(.got.plt) *(.got)
		*(.data .data.* .gnu.linkonce.d.*)
		*(.dynbss)
		*(.bss .bss.* .gnu.linkonce.b.*)
		*(__ex_table)
		*(__mca_table)
	}
}

/*
 * ld does not recognize this name token; use the constant.
 */
#define	PT_IA_64_UNWIND	0x70000001

/*
 * We must supply the ELF program headers explicitly to get just one
 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 */
PHDRS
{
	readable	PT_LOAD	FILEHDR	PHDRS	FLAGS(4);	/* PF_R */
#ifndef HAVE_BUGGY_SEGREL
	epc		PT_LOAD	FILEHDR PHDRS	FLAGS(1);	/* PF_X */
#endif
	dynamic		PT_DYNAMIC		FLAGS(4);	/* PF_R */
	note		PT_NOTE			FLAGS(4);	/* PF_R */
	unwind		PT_IA_64_UNWIND;
}

/*
 * This controls what symbols we export from the DSO.
 */
VERSION
{
	LINUX_2.5 {
	global:
		__kernel_syscall_via_break;
		__kernel_syscall_via_epc;
		__kernel_sigtramp;

	local: *;
	};
}

/* The ELF entry point can be used to set the AT_SYSINFO value.  */
ENTRY(__kernel_syscall_via_epc)
Commit	Line	Data
1da177e4	1	/*
1a43be74 RM	2	* Linker script for gate DSO. The gate pages are an ELF shared object
	3	* prelinked to its virtual address, with only one read-only segment and
	4	* one execute-only segment (both fit in one page). This script controls
	5	* its layout.
1da177e4 LT	6	*/
1da177e4 LT	7
1da177e4 LT	8
1da177e4 LT	9	#include <asm/system.h>
e4ff5b8f	10	#include "paravirt_patchlist.h"
1da177e4 LT	11
	12	SECTIONS
	13	{
1a43be74 RM	14	. = GATE_ADDR + SIZEOF_HEADERS;
	15
	16	.hash : { *(.hash) } :readable
	17	.gnu.hash : { *(.gnu.hash) }
	18	.dynsym : { *(.dynsym) }
	19	.dynstr : { *(.dynstr) }
	20	.gnu.version : { *(.gnu.version) }
	21	.gnu.version_d : { *(.gnu.version_d) }
	22	.gnu.version_r : { *(.gnu.version_r) }
	23
172c5106 RM	24	.note : { (.note) } :readable :note
172c5106 RM	25
1a43be74 RM	26	.dynamic : { *(.dynamic) } :readable :dynamic
	27
	28	/*
	29	* This linker script is used both with -r and with -shared. For
	30	* the layouts to match, we need to skip more than enough space for
	31	* the dynamic symbol table et al. If this amount is insufficient,
	32	* ld -shared will barf. Just increase it here.
	33	*/
1f0abae8	34	. = GATE_ADDR + 0x600;
1a43be74	35
dafb9320	36	.data..patch : {
e4ff5b8f	37	__paravirt_start_gate_mckinley_e9_patchlist = .;
dafb9320	38	*(.data..patch.mckinley_e9)
e4ff5b8f	39	__paravirt_end_gate_mckinley_e9_patchlist = .;
1a43be74	40
e4ff5b8f	41	__paravirt_start_gate_vtop_patchlist = .;
dafb9320	42	*(.data..patch.vtop)
e4ff5b8f	43	__paravirt_end_gate_vtop_patchlist = .;
1a43be74	44
e4ff5b8f	45	__paravirt_start_gate_fsyscall_patchlist = .;
dafb9320	46	*(.data..patch.fsyscall_table)
e4ff5b8f	47	__paravirt_end_gate_fsyscall_patchlist = .;
1a43be74	48
e4ff5b8f	49	__paravirt_start_gate_brl_fsys_bubble_down_patchlist = .;
dafb9320	50	*(.data..patch.brl_fsys_bubble_down)
e4ff5b8f	51	__paravirt_end_gate_brl_fsys_bubble_down_patchlist = .;
1a43be74 RM	52	} :readable
	53
	54	.IA_64.unwind_info : { (.IA_64.unwind_info) }
	55	.IA_64.unwind : { (.IA_64.unwind) } :readable :unwind
1da177e4	56	#ifdef HAVE_BUGGY_SEGREL
1a43be74	57	.text (GATE_ADDR + PAGE_SIZE) : { (.text) (.text.*) } :readable
1da177e4	58	#else
1a43be74 RM	59	. = ALIGN(PERCPU_PAGE_SIZE) + (. & (PERCPU_PAGE_SIZE - 1));
1a43be74 RM	60	.text : { (.text) (.text.*) } :epc
1da177e4 LT	61	#endif
1da177e4 LT	62
1a43be74 RM	63	/DISCARD/ : {
	64	(.got.plt) (.got)
	65	(.data .data. .gnu.linkonce.d.*)
	66	*(.dynbss)
	67	(.bss .bss. .gnu.linkonce.b.*)
	68	*(__ex_table)
	69	*(__mca_table)
	70	}
1da177e4 LT	71	}
1da177e4 LT	72
1a43be74 RM	73	/*
	74	* ld does not recognize this name token; use the constant.
	75	*/
	76	#define PT_IA_64_UNWIND 0x70000001
	77
1da177e4 LT	78	/*
	79	* We must supply the ELF program headers explicitly to get just one
	80	* PT_LOAD segment, and set the flags explicitly to make segments read-only.
	81	*/
	82	PHDRS
	83	{
1a43be74	84	readable PT_LOAD FILEHDR PHDRS FLAGS(4); /* PF_R */
1da177e4	85	#ifndef HAVE_BUGGY_SEGREL
1a43be74	86	epc PT_LOAD FILEHDR PHDRS FLAGS(1); /* PF_X */
1da177e4	87	#endif
1a43be74	88	dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
172c5106	89	note PT_NOTE FLAGS(4); /* PF_R */
1a43be74	90	unwind PT_IA_64_UNWIND;
1da177e4 LT	91	}
	92
	93	/*
	94	* This controls what symbols we export from the DSO.
	95	*/
	96	VERSION
	97	{
1a43be74 RM	98	LINUX_2.5 {
	99	global:
	100	__kernel_syscall_via_break;
	101	__kernel_syscall_via_epc;
	102	__kernel_sigtramp;
	103
	104	local: *;
	105	};
1da177e4 LT	106	}
	107
	108	/* The ELF entry point can be used to set the AT_SYSINFO value. */
	109	ENTRY(__kernel_syscall_via_epc)