[net-next-2.6.git] / arch / cris / arch-v32 / boot / compressed / head.S

/*
 *  Code that sets up the DRAM registers, calls the
 *  decompressor to unpack the piggybacked kernel, and jumps.
 *
 *  Copyright (C) 1999 - 2006, Axis Communications AB
 */

#define ASSEMBLER_MACROS_ONLY
#include <hwregs/asm/reg_map_asm.h>
#include <mach/startup.inc>

#define RAM_INIT_MAGIC 0x56902387
#define COMMAND_LINE_MAGIC 0x87109563

	;; Exported symbols

	.globl	input_data

	.text
_start:
	di

	;; Start clocks for used blocks.
	START_CLOCKS

	;; Initialize the DRAM registers.
	cmp.d	RAM_INIT_MAGIC, $r8	; Already initialized?
	beq	dram_init_finished
	nop

#include "../../mach/dram_init.S"

dram_init_finished:

	GIO_INIT
	;; Setup the stack to a suitably high address.
	;; We assume 8 MB is the minimum DRAM and put
	;; the SP at the top for now.

	move.d	0x40800000, $sp

	;; Figure out where the compressed piggyback image is.
	;; It is either in [NOR] flash (we don't want to copy it
	;; to DRAM before unpacking), or copied to DRAM
	;; by the [NAND] flash boot loader.
	;; The piggyback image is at _edata, but relative to where the
	;; image is actually located in memory, not where it is linked
	;; (the decompressor is linked at 0x40700000+ and runs there).
	;; Use (_edata - herami) as offset to the current PC.

hereami:
	lapcq	., $r5		; get PC
	and.d	0x7fffffff, $r5	; strip any non-cache bit
	move.d	$r5, $r0	; source address of 'herami'
	add.d	_edata, $r5
	sub.d	hereami, $r5	; r5 = flash address of '_edata'
	move.d	hereami, $r1	; destination

	;; Copy text+data to DRAM

	move.d	_edata, $r2	; end destination
1:	move.w	[$r0+], $r3	; from herami+ source
	move.w	$r3, [$r1+]	; to hereami+ destination (linked address)
	cmp.d	$r2, $r1	; finish when destination == _edata
	bcs	1b
	nop
	move.d	input_data, $r0 ; for the decompressor
	move.d	$r5, [$r0]	; for the decompressor

	;; Clear the decompressors BSS (between _edata and _end)

	moveq	0, $r0
	move.d	_edata, $r1
	move.d	_end, $r2
1:	move.w	$r0, [$r1+]
	cmp.d	$r2, $r1
	bcs	1b
	nop

	;;  Save command line magic and address.
	move.d	_cmd_line_magic, $r0
	move.d  $r10, [$r0]
	move.d	_cmd_line_addr, $r0
	move.d  $r11, [$r0]

	;;  Save boot source indicator
	move.d	_boot_source, $r0
	move.d	$r12, [$r0]

	;; Do the decompression and save compressed size in _inptr

	jsr	decompress_kernel
	nop

	;; Restore boot source indicator
	move.d	_boot_source, $r12
	move.d	[$r12], $r12

	;; Restore command line magic and address.
	move.d  _cmd_line_magic, $r10
	move.d  [$r10], $r10
	move.d  _cmd_line_addr, $r11
	move.d  [$r11], $r11

	;; Put start address of root partition in r9 so the kernel can use it
	;; when mounting from flash
	move.d  input_data, $r0
	move.d	[$r0], $r9		; flash address of compressed kernel
	move.d  inptr, $r0
	add.d	[$r0], $r9		; size of compressed kernel
	cmp.d   0x40000000, $r9		; image in DRAM ?
	blo	enter_kernel		; no, must be [NOR] flash, jump
	nop				; delay slot
	and.d   0x001fffff, $r9		; assume compressed kernel was < 2M

enter_kernel:
	;; Enter the decompressed kernel
	move.d	RAM_INIT_MAGIC, $r8	; Tell kernel that DRAM is initialized
	jump	0x40004000	; kernel is linked to this address
	nop

	.data

input_data:
	.dword	0		; used by the decompressor
_cmd_line_magic:
	.dword 0
_cmd_line_addr:
	.dword 0
_boot_source:
	.dword 0

#include "../../mach/hw_settings.S"
Commit	Line	Data
51533b61 MS	1	/*
	2	* Code that sets up the DRAM registers, calls the
	3	* decompressor to unpack the piggybacked kernel, and jumps.
	4	*
247c3c95	5	* Copyright (C) 1999 - 2006, Axis Communications AB
51533b61 MS	6	*/
51533b61 MS	7
51533b61	8	#define ASSEMBLER_MACROS_ONLY
247c3c95	9	#include <hwregs/asm/reg_map_asm.h>
556dcee7	10	#include <mach/startup.inc>
51533b61 MS	11
	12	#define RAM_INIT_MAGIC 0x56902387
	13	#define COMMAND_LINE_MAGIC 0x87109563
	14
	15	;; Exported symbols
	16
	17	.globl input_data
	18
	19	.text
556dcee7	20	_start:
51533b61 MS	21	di
	22
	23	;; Start clocks for used blocks.
247c3c95 JN	24	START_CLOCKS
	25
	26	;; Initialize the DRAM registers.
51533b61 MS	27	cmp.d RAM_INIT_MAGIC, $r8 ; Already initialized?
	28	beq dram_init_finished
	29	nop
	30
247c3c95	31	#include "../../mach/dram_init.S"
51533b61 MS	32
51533b61 MS	33	dram_init_finished:
51533b61	34
247c3c95	35	GIO_INIT
51533b61 MS	36	;; Setup the stack to a suitably high address.
	37	;; We assume 8 MB is the minimum DRAM and put
	38	;; the SP at the top for now.
	39
	40	move.d 0x40800000, $sp
	41
247c3c95 JN	42	;; Figure out where the compressed piggyback image is.
	43	;; It is either in [NOR] flash (we don't want to copy it
	44	;; to DRAM before unpacking), or copied to DRAM
	45	;; by the [NAND] flash boot loader.
	46	;; The piggyback image is at _edata, but relative to where the
	47	;; image is actually located in memory, not where it is linked
	48	;; (the decompressor is linked at 0x40700000+ and runs there).
51533b61 MS	49	;; Use (_edata - herami) as offset to the current PC.
51533b61 MS	50
51533b61 MS	51	hereami:
	52	lapcq ., $r5 ; get PC
	53	and.d 0x7fffffff, $r5 ; strip any non-cache bit
247c3c95	54	move.d $r5, $r0 ; source address of 'herami'
51533b61 MS	55	add.d _edata, $r5
	56	sub.d hereami, $r5 ; r5 = flash address of '_edata'
	57	move.d hereami, $r1 ; destination
247c3c95	58
51533b61 MS	59	;; Copy text+data to DRAM
	60
	61	move.d _edata, $r2 ; end destination
247c3c95 JN	62	1: move.w [$r0+], $r3 ; from herami+ source
	63	move.w $r3, [$r1+] ; to hereami+ destination (linked address)
	64	cmp.d $r2, $r1 ; finish when destination == _edata
51533b61 MS	65	bcs 1b
51533b61 MS	66	nop
51533b61 MS	67	move.d input_data, $r0 ; for the decompressor
	68	move.d $r5, [$r0] ; for the decompressor
	69
	70	;; Clear the decompressors BSS (between _edata and _end)
	71
	72	moveq 0, $r0
	73	move.d _edata, $r1
	74	move.d _end, $r2
	75	1: move.w $r0, [$r1+]
	76	cmp.d $r2, $r1
	77	bcs 1b
	78	nop
	79
	80	;; Save command line magic and address.
247c3c95 JN	81	move.d _cmd_line_magic, $r0
	82	move.d $r10, [$r0]
	83	move.d _cmd_line_addr, $r0
	84	move.d $r11, [$r0]
	85
	86	;; Save boot source indicator
	87	move.d _boot_source, $r0
	88	move.d $r12, [$r0]
51533b61 MS	89
	90	;; Do the decompression and save compressed size in _inptr
	91
	92	jsr decompress_kernel
	93	nop
	94
247c3c95 JN	95	;; Restore boot source indicator
	96	move.d _boot_source, $r12
	97	move.d [$r12], $r12
	98
51533b61 MS	99	;; Restore command line magic and address.
	100	move.d _cmd_line_magic, $r10
	101	move.d [$r10], $r10
	102	move.d _cmd_line_addr, $r11
	103	move.d [$r11], $r11
	104
	105	;; Put start address of root partition in r9 so the kernel can use it
	106	;; when mounting from flash
	107	move.d input_data, $r0
	108	move.d [$r0], $r9 ; flash address of compressed kernel
	109	move.d inptr, $r0
	110	add.d [$r0], $r9 ; size of compressed kernel
247c3c95 JN	111	cmp.d 0x40000000, $r9 ; image in DRAM ?
	112	blo enter_kernel ; no, must be [NOR] flash, jump
	113	nop ; delay slot
	114	and.d 0x001fffff, $r9 ; assume compressed kernel was < 2M
51533b61 MS	115
	116	enter_kernel:
	117	;; Enter the decompressed kernel
	118	move.d RAM_INIT_MAGIC, $r8 ; Tell kernel that DRAM is initialized
	119	jump 0x40004000 ; kernel is linked to this address
	120	nop
	121
	122	.data
	123
	124	input_data:
	125	.dword 0 ; used by the decompressor
	126	_cmd_line_magic:
	127	.dword 0
	128	_cmd_line_addr:
	129	.dword 0
247c3c95 JN	130	_boot_source:
247c3c95 JN	131	.dword 0
51533b61	132
247c3c95	133	#include "../../mach/hw_settings.S"