[net-next-2.6.git] / arch / arm / kernel / relocate_kernel.S

/*
 * relocate_kernel.S - put the kernel image in place to boot
 */

#include <asm/kexec.h>

	.globl relocate_new_kernel
relocate_new_kernel:

	ldr	r0,kexec_indirection_page
	ldr	r1,kexec_start_address

	/*
	 * If there is no indirection page (we are doing crashdumps)
	 * skip any relocation.
	 */
	cmp	r0, #0
	beq	2f

0:	/* top, read another word for the indirection page */
	ldr	r3, [r0],#4

	/* Is it a destination page. Put destination address to r4 */
	tst	r3,#1,0
	beq	1f
	bic	r4,r3,#1
	b	0b
1:
	/* Is it an indirection page */
	tst	r3,#2,0
	beq	1f
	bic	r0,r3,#2
	b	0b
1:

	/* are we done ? */
	tst	r3,#4,0
	beq	1f
	b	2f

1:
	/* is it source ? */
	tst	r3,#8,0
	beq	0b
	bic r3,r3,#8
	mov r6,#1024
9:
	ldr r5,[r3],#4
	str r5,[r4],#4
	subs r6,r6,#1
	bne 9b
	b 0b

2:
	/* Jump to relocated kernel */
	mov lr,r1
	mov r0,#0
	ldr r1,kexec_mach_type
	ldr r2,kexec_boot_atags
	mov pc,lr

	.globl kexec_start_address
kexec_start_address:
	.long	0x0

	.globl kexec_indirection_page
kexec_indirection_page:
	.long	0x0

	.globl kexec_mach_type
kexec_mach_type:
	.long	0x0

	/* phy addr of the atags for the new kernel */
	.globl kexec_boot_atags
kexec_boot_atags:
	.long	0x0

relocate_new_kernel_end:

	.globl relocate_new_kernel_size
relocate_new_kernel_size:
	.long relocate_new_kernel_end - relocate_new_kernel
Commit	Line	Data
c587e4a6 RP	1	/*
	2	* relocate_kernel.S - put the kernel image in place to boot
	3	*/
	4
	5	#include <asm/kexec.h>
	6
	7	.globl relocate_new_kernel
	8	relocate_new_kernel:
	9
	10	ldr r0,kexec_indirection_page
	11	ldr r1,kexec_start_address
	12
8594a0c3 MW	13	/*
	14	* If there is no indirection page (we are doing crashdumps)
	15	* skip any relocation.
	16	*/
	17	cmp r0, #0
	18	beq 2f
c587e4a6 RP	19
	20	0: /* top, read another word for the indirection page */
	21	ldr r3, [r0],#4
	22
	23	/* Is it a destination page. Put destination address to r4 */
	24	tst r3,#1,0
	25	beq 1f
	26	bic r4,r3,#1
	27	b 0b
	28	1:
	29	/* Is it an indirection page */
	30	tst r3,#2,0
	31	beq 1f
	32	bic r0,r3,#2
	33	b 0b
	34	1:
	35
	36	/* are we done ? */
	37	tst r3,#4,0
	38	beq 1f
	39	b 2f
	40
	41	1:
	42	/* is it source ? */
	43	tst r3,#8,0
	44	beq 0b
	45	bic r3,r3,#8
	46	mov r6,#1024
	47	9:
	48	ldr r5,[r3],#4
	49	str r5,[r4],#4
	50	subs r6,r6,#1
	51	bne 9b
	52	b 0b
	53
	54	2:
	55	/* Jump to relocated kernel */
	56	mov lr,r1
	57	mov r0,#0
	58	ldr r1,kexec_mach_type
4cd9d6f7	59	ldr r2,kexec_boot_atags
c587e4a6 RP	60	mov pc,lr
	61
	62	.globl kexec_start_address
	63	kexec_start_address:
	64	.long 0x0
	65
	66	.globl kexec_indirection_page
	67	kexec_indirection_page:
	68	.long 0x0
	69
	70	.globl kexec_mach_type
	71	kexec_mach_type:
	72	.long 0x0
	73
4cd9d6f7 RP	74	/* phy addr of the atags for the new kernel */
	75	.globl kexec_boot_atags
	76	kexec_boot_atags:
033b8ffe MW	77	.long 0x0
033b8ffe MW	78
c587e4a6 RP	79	relocate_new_kernel_end:
	80
	81	.globl relocate_new_kernel_size
	82	relocate_new_kernel_size:
	83	.long relocate_new_kernel_end - relocate_new_kernel
	84
	85